sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007, 2008, 2009 Free Software
   3 dnl Foundation, Inc.
   4
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl Additional permission under GNU GPL version 3 section 7
  19
  20 dnl If you modify this program, or any covered work, by linking or
  21 dnl combining it with the OpenSSL project's OpenSSL library (or a
  22 dnl modified version of that library), containing parts covered by the
  23 dnl terms of the OpenSSL or SSLeay licenses, the Free Software Foundation
  24 dnl grants you additional permission to convey the resulting work.
  25 dnl Corresponding Source for a non-source form of such a combination
  26 dnl shall include the source code for the parts of OpenSSL used as well
  27 dnl as that of the covered work.
  28
  29 dnl
  30 dnl Process this file with autoconf to produce a configure script.
  31 dnl
  32
  33 AC_INIT([wget],
  34         [1.12.1-devel],
  35         [bug-wget@gnu.org])
  36 AC_PREREQ(2.61)
  37
  38 dnl
  39 dnl What version of Wget are we building?
  40 dnl
  41 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  42
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_AUX_DIR([build-aux])
  45
  46 AC_CONFIG_SRCDIR([src/wget.h])
  47
  48 dnl
  49 dnl Automake setup
  50 dnl
  51 AM_INIT_AUTOMAKE(dist-bzip2 dist-lzma 1.9)
  52
  53 dnl
  54 dnl Get cannonical host
  55 dnl
  56 AC_CANONICAL_HOST
  57 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  58                    [Define to be the name of the operating system.])
  59
  60 dnl
  61 dnl Process features.
  62 dnl
  63
  64 AC_ARG_WITH(ssl,
  65 [[  --without-ssl           disable SSL autodetection]])
  66
  67 AC_ARG_ENABLE(opie,
  68 [  --disable-opie          disable support for opie or s/key FTP login],
  69 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  70 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  71    [Define if you want the Opie support for FTP compiled in.])
  72
  73 AC_ARG_ENABLE(digest,
  74 [  --disable-digest        disable support for HTTP digest authorization],
  75 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  76 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  77    [Define if you want the HTTP Digest Authorization compiled in.])
  78
  79 AC_ARG_ENABLE(ntlm,
  80 [  --disable-ntlm          disable support for NTLM authorization],
  81 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  82
  83 AC_ARG_ENABLE(debug,
  84 [  --disable-debug         disable support for debugging output],
  85 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  86 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  87    [Define if you want the debug output support compiled in.])
  88
  89 wget_need_md5=no
  90
  91 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  92 *yes*)
  93         wget_need_md5=yes
  94 esac
  95
  96 dnl
  97 dnl Find the compiler
  98 dnl
  99
 100 dnl We want these before the checks, so the checks can modify their values.
 101 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 102 test -z "$CC" && cc_specified=yes
 103
 104 AC_PROG_CC
 105 AM_PROG_CC_C_O
 106 AC_AIX
 107
 108 gl_EARLY
 109 md5_EARLY
 110
 111 dnl
 112 dnl Gettext
 113 dnl
 114 AM_GNU_GETTEXT([external],[need-ngettext])
 115 AM_GNU_GETTEXT_VERSION([0.17])
 116
 117 AC_PROG_RANLIB
 118
 119 AC_PROG_LEX
 120
 121 dnl Turn on optimization by default.  Specifically:
 122 dnl
 123 dnl if the user hasn't specified CFLAGS, then
 124 dnl   if compiler is gcc, then
 125 dnl     use -O2 and some warning flags
 126 dnl   else
 127 dnl     use os-specific flags or -O
 128 if test -n "$auto_cflags"; then
 129   if test -n "$GCC"; then
 130     CFLAGS="$CFLAGS -O2 -Wall"
 131   else
 132     case "$host_os" in
 133       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 134       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 135       *)       CFLAGS="$CFLAGS -O" ;;
 136     esac
 137   fi
 138 fi
 139
 140 dnl
 141 dnl Checks for basic compiler characteristics.
 142 dnl
 143 AC_C_CONST
 144 AC_C_INLINE
 145 AC_C_VOLATILE
 146
 147 dnl Check for basic headers, even though we expect them to exist and
 148 dnl #include them unconditionally in the code.  Their detection is
 149 dnl still needed because test programs used by Autoconf macros check
 150 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 151 dnl Without the checks they will fail to be included in test programs,
 152 dnl which will subsequently fail.
 153 AC_HEADER_STDC
 154
 155 dnl Check for large file support.  This check needs to come fairly
 156 dnl early because it could (in principle) affect whether functions and
 157 dnl headers are available, whether they work, etc.
 158 AC_SYS_LARGEFILE
 159 AC_CHECK_SIZEOF(off_t)
 160
 161 dnl
 162 dnl Checks for system header files that might be missing.
 163 dnl
 164 AC_HEADER_STDBOOL
 165 AC_CHECK_HEADERS(unistd.h sys/time.h)
 166 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 167 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h wchar.h)
 168
 169 AC_CHECK_DECLS(h_errno,,,[#include <netdb.h>])
 170
 171 dnl
 172 dnl Check sizes of integer types.  These are used to find n-bit
 173 dnl integral types on older systems that fail to provide intN_t and
 174 dnl uintN_t typedefs.
 175 dnl
 176 AC_CHECK_SIZEOF(short)
 177 AC_CHECK_SIZEOF(int)
 178 AC_CHECK_SIZEOF(long)
 179 AC_CHECK_SIZEOF(long long)
 180 AC_CHECK_SIZEOF(void *)
 181
 182 dnl
 183 dnl Checks for non-universal or system-specific types.
 184 dnl
 185 AC_TYPE_SIZE_T
 186 AC_TYPE_PID_T
 187 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 188 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 189 #include <stdio.h>
 190 #include <sys/types.h>
 191 #if HAVE_INTTYPES_H
 192 # include <inttypes.h>
 193 #endif
 194 #include <signal.h>
 195 ])
 196
 197 # gnulib
 198 gl_INIT
 199
 200 dnl
 201 dnl Checks for library functions.
 202 dnl
 203 AC_FUNC_MMAP
 204 AC_FUNC_FSEEKO
 205 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 206 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr wcwidth mbtowc)
 207 AC_CHECK_FUNCS(sleep symlink)
 208
 209 if test x"$ENABLE_OPIE" = xyes; then
 210   AC_LIBOBJ([ftp-opie])
 211 fi
 212
 213 dnl We expect to have these functions on Unix-like systems configure
 214 dnl runs on.  The defines are provided to get them in config.h.in so
 215 dnl Wget can still be ported to non-Unix systems (such as Windows)
 216 dnl that lack some of these functions.
 217 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 218 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 219 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 220 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 221
 222 dnl
 223 dnl Call Wget-specific macros defined in aclocal.
 224 dnl
 225 WGET_STRUCT_UTIMBUF
 226 WGET_SOCKLEN_T
 227 WGET_FNMATCH
 228 WGET_NANOSLEEP
 229 WGET_POSIX_CLOCK
 230 WGET_NSL_SOCKET
 231
 232 dnl Deal with specific hosts
 233 case $host_os in
 234   *mingw32* )
 235     AC_SUBST(W32LIBS, '-lwsock32')
 236     AC_LIBOBJ([mswindows])
 237     ;;
 238 esac
 239
 240 dnl
 241 dnl Checks for libraries.
 242 dnl
 243
 244 AS_IF([test x"$with_ssl" = xgnutls], [
 245   dnl Now actually check for -lssl
 246   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 247 #include <gnutls/gnutls.h>
 248   ], [gnutls_global_init()])
 249   if test x"$LIBGNUTLS" != x
 250   then
 251     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 252     AC_LIBOBJ([gnutls])
 253   else
 254     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 255   fi
 256 ], [
 257   # --with-ssl is not gnutls: check if it's no
 258   AS_IF([test x"$with_ssl" != xno], [
 259     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 260     dnl doesn't record its dependency on libdl, so we need to make sure
 261     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 262     dnl dlopen(), but HP-UX uses shl_load().
 263     AC_CHECK_LIB(dl, dlopen, [], [
 264       AC_CHECK_LIB(dl, shl_load)
 265     ])
 266
 267     dnl Now actually check for -lssl
 268     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 269   #include <openssl/ssl.h>
 270   #include <openssl/x509.h>
 271   #include <openssl/err.h>
 272   #include <openssl/rand.h>
 273   #include <openssl/des.h>
 274   #include <openssl/md4.h>
 275   #include <openssl/md5.h>
 276     ], [SSL_library_init ()])
 277     if test x"$LIBSSL" != x
 278     then
 279       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 280       AC_LIBOBJ([openssl])
 281     elif test x"$with_ssl" != x
 282     then
 283       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 284     fi
 285   ]) # endif: --with-ssl == no?
 286 ]) # endif: --with-ssl == gnutls?
 287
 288
 289 dnl Enable NTLM if requested and if SSL is available.
 290 if test x"$LIBSSL" != x
 291 then
 292   if test x"$ENABLE_NTLM" != xno
 293   then
 294     AC_DEFINE([ENABLE_NTLM], 1,
 295      [Define if you want the NTLM authorization support compiled in.])
 296     AC_LIBOBJ([http-ntlm])
 297   fi
 298 else
 299   dnl If SSL is unavailable and the user explicitly requested NTLM,
 300   dnl abort.
 301   if test x"$ENABLE_NTLM" = xyes
 302   then
 303     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 304   fi
 305 fi
 306
 307 dnl
 308 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 309 dnl to use an existing library implementation to save on code size.
 310 dnl
 311
 312 if test x"$wget_need_md5" = xyes
 313 then
 314   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 315   dnl manipulate MD5_OBJ from the defun.
 316
 317   AC_LIBOBJ([gen-md5])
 318   found_md5=no
 319
 320   dnl Check for the system MD5 library on Solaris.  We don't check for
 321   dnl something simple like "MD5Update" because there are a number of
 322   dnl MD5 implementations that use that name, but have an otherwise
 323   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 324   dnl Solaris MD5 library.
 325   if test x"$found_md5" = xno; then
 326     AC_CHECK_LIB(md5, md5_calc, [
 327       dnl Some installations have bogus <md5.h> in the compiler's
 328       dnl include path, making the system md5 library useless.
 329       AC_MSG_CHECKING([for working md5.h])
 330       AC_COMPILE_IFELSE([#include <md5.h>
 331                         ], [
 332         AC_MSG_RESULT(yes)
 333         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 334         LIBS="-lmd5 $LIBS"
 335         found_md5=yes
 336         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 337       ], [AC_MSG_RESULT(no)])
 338     ])
 339   fi
 340
 341   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 342   dnl implementation.
 343   if test x"$found_md5" = xno; then
 344     if test x"$LIBSSL" != x; then
 345       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 346       found_md5=yes
 347       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 348     fi
 349   fi
 350
 351   dnl If none of the above worked, use the one we ship with Wget.
 352   if test x"$found_md5" = xno; then
 353     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 354     found_md5=yes
 355     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 356     AC_C_BIGENDIAN
 357
 358     AC_SUBST(MD5_CPPFLAGS, '-I $(top_srcdir)/md5')
 359     AC_SUBST(MD5_LDADD, '../md5/libmd5.a')
 360     AC_SUBST(MD5_SUBDIR, md5)
 361     md5_INIT
 362   fi
 363   AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 364 fi
 365
 366 dnl **********************************************************************
 367 dnl Checks for IPv6
 368 dnl **********************************************************************
 369
 370 dnl
 371 dnl We test for IPv6 by checking, in turn, for availability of
 372 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 373 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 374 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 375 dnl
 376 dnl If --enable-ipv6 is explicitly specified on the configure command
 377 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 378 dnl is specified, we disable IPv6 and don't check for it.  The default
 379 dnl is to autodetect IPv6 and use it where available.
 380 dnl
 381
 382 AC_ARG_ENABLE(ipv6,
 383   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 384   [case "${enable_ipv6}" in
 385     no)
 386       AC_MSG_NOTICE([disabling IPv6 at user request])
 387       dnl Disable IPv6 checking
 388       ipv6=no
 389       ;;
 390     yes)
 391       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 392       ipv6=yes
 393       force_ipv6=yes
 394       ;;
 395     auto)
 396       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 397       ipv6=yes
 398       ;;
 399     *)
 400       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 401       ;;
 402     esac
 403   ], [
 404     dnl If nothing is specified, assume auto-detection.
 405     ipv6=yes
 406   ]
 407 )
 408
 409 if test "X$ipv6" = "Xyes"; then
 410   AC_CHECK_FUNCS(getaddrinfo, [], [
 411     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 412     ipv6=no
 413   ])
 414 fi
 415
 416 if test "X$ipv6" = "Xyes"; then
 417   PROTO_INET6([], [
 418     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 419     ipv6=no
 420   ])
 421 fi
 422
 423 if test "X$ipv6" = "Xyes"; then
 424   TYPE_STRUCT_SOCKADDR_IN6([],[
 425     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 426     ipv6=no
 427   ])
 428   if test "X$ipv6" = "Xyes"; then
 429     WGET_STRUCT_SOCKADDR_STORAGE
 430     MEMBER_SIN6_SCOPE_ID
 431   fi
 432 fi
 433
 434 if test "X$ipv6" = "Xyes"; then
 435   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 436   AC_MSG_NOTICE([Enabling support for IPv6.])
 437 elif test "x$force_ipv6" = "xyes"; then
 438   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 439 fi
 440
 441 dnl
 442 dnl Find makeinfo.  We used to provide support for Emacs processing
 443 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 444 dnl unavailable, but that broke with the addition of makeinfo-specific
 445 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 446 dnl build the Info documentation.
 447 dnl
 448
 449 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 450
 451 dnl
 452 dnl Find perl and pod2man
 453 dnl
 454
 455 AC_PATH_PROGS(PERL, [perl5 perl], no)
 456 AC_PATH_PROG(POD2MAN, pod2man, no)
 457
 458 if test "x${POD2MAN}" = xno; then
 459   COMMENT_IF_NO_POD2MAN="# "
 460 else
 461   COMMENT_IF_NO_POD2MAN=
 462 fi
 463 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 464
 465
 466 dnl
 467 dnl Check for IDN/IRIs
 468 dnl
 469
 470 AC_ARG_ENABLE(iri,
 471   AC_HELP_STRING([--disable-iri],[disable IDN/IRIs support]),
 472   [case "${enable_iri}" in
 473     no)
 474       dnl Disable IRIs checking
 475       AC_MSG_NOTICE([disabling IRIs at user request])
 476       iri=no
 477       ;;
 478     yes)
 479       dnl IRIs explicitly enabled
 480       iri=yes
 481       force_iri=yes
 482       ;;
 483     auto)
 484       dnl Auto-detect IRI
 485       iri=yes
 486       ;;
 487     *)
 488       AC_MSG_ERROR([Invalid --enable-iri argument \`$enable_iri'])
 489       ;;
 490     esac
 491   ], [
 492     dnl If nothing is specified, assume auto-detection
 493     iri=yes
 494   ]
 495 )
 496
 497 AC_ARG_WITH(libidn, AC_HELP_STRING([--with-libidn=[DIR]],
 498                                    [Support IDN/IRIs (needs GNU Libidn)]),
 499                                    libidn=$withval, libidn="")
 500 AS_IF([test "X$iri" != "Xno"],[
 501   AM_ICONV
 502
 503   if test "X$am_cv_func_iconv" != "Xyes"; then
 504     iri=no
 505     if test "X$force_iri" = "Xyes"; then
 506       AC_MSG_ERROR([Libiconv is required for IRIs support])
 507     else
 508       AC_MSG_NOTICE([disabling IRIs because libiconv wasn't found])
 509     fi
 510   fi
 511 ],[  # else
 512   # For some reason, this seems to be set even when we don't check.
 513   # Explicitly unset.
 514   LIBICONV=
 515 ])
 516
 517 if test "X$iri" != "Xno"; then
 518   if test "$libidn" != ""; then
 519     LDFLAGS="${LDFLAGS} -L$libidn/lib"
 520     CPPFLAGS="${CPPFLAGS} -I$libidn/include"
 521   fi
 522
 523   # If idna.h can't be found, check to see if it was installed under
 524   # /usr/include/idn (OpenSolaris, at least, places it there).
 525   # Check for idn-int.h in that case, because idna.h won't find
 526   # idn-int.h until we've decided to add -I/usr/include/idn.
 527   AC_CHECK_HEADER(idna.h, ,
 528     [AC_CHECK_HEADER(idn/idn-int.h,
 529                     [CPPFLAGS="${CPPFLAGS} -I/usr/include/idn"],
 530                     [iri=no])]
 531   )
 532
 533   if test "X$iri" != "Xno"; then
 534     AC_CHECK_LIB(idn, stringprep_check_version,
 535       [iri=yes LIBS="${LIBS} -lidn"], iri=no)
 536   fi
 537
 538   if test "X$iri" != "Xno" ; then
 539     AC_DEFINE([ENABLE_IRI], 1, [Define if IRI support is enabled.])
 540     AC_MSG_NOTICE([Enabling support for IRI.])
 541   else
 542     AC_MSG_WARN([Libidn not found])
 543   fi
 544 fi
 545
 546
 547 dnl Needed by src/Makefile.am
 548 AM_CONDITIONAL([IRI_IS_ENABLED], [test "X$iri" != "Xno"])
 549
 550
 551 dnl
 552 dnl Create output
 553 dnl
 554 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 555                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 556                  lib/Makefile md5/Makefile windows/Makefile])
 557 AC_CONFIG_HEADERS([src/config.h])
 558 AC_OUTPUT