sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007, 2008, 2009, 2010, 2011
   3 dnl Free Software Foundation, Inc.
   4
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl Additional permission under GNU GPL version 3 section 7
  19
  20 dnl If you modify this program, or any covered work, by linking or
  21 dnl combining it with the OpenSSL project's OpenSSL library (or a
  22 dnl modified version of that library), containing parts covered by the
  23 dnl terms of the OpenSSL or SSLeay licenses, the Free Software Foundation
  24 dnl grants you additional permission to convey the resulting work.
  25 dnl Corresponding Source for a non-source form of such a combination
  26 dnl shall include the source code for the parts of OpenSSL used as well
  27 dnl as that of the covered work.
  28
  29 dnl
  30 dnl Process this file with autoconf to produce a configure script.
  31 dnl
  32
  33 AC_INIT([wget],
  34   [m4_esyscmd([build-aux/bzr-version-gen])],
  35         [bug-wget@gnu.org])
  36 AC_PREREQ(2.61)
  37
  38 dnl
  39 dnl What version of Wget are we building?
  40 dnl
  41 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  42
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_AUX_DIR([build-aux])
  45
  46 AC_CONFIG_SRCDIR([src/wget.h])
  47
  48 dnl
  49 dnl Automake setup
  50 dnl
  51 AM_INIT_AUTOMAKE([1.9])
  52
  53 dnl
  54 dnl Get cannonical host
  55 dnl
  56 AC_CANONICAL_HOST
  57 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  58                    [Define to be the name of the operating system.])
  59
  60 dnl
  61 dnl Process features.
  62 dnl
  63
  64 AC_ARG_WITH(ssl,
  65 [[  --without-ssl           disable SSL autodetection
  66   --with-ssl={gnutls,openssl} specify the SSL backend.  GNU TLS is the default.]])
  67
  68 AC_ARG_WITH(zlib,
  69 [[  --without-zlib          disable zlib ]])
  70
  71 AC_ARG_ENABLE(opie,
  72 [  --disable-opie          disable support for opie or s/key FTP login],
  73 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  74 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  75    [Define if you want the Opie support for FTP compiled in.])
  76
  77 AC_ARG_ENABLE(digest,
  78 [  --disable-digest        disable support for HTTP digest authorization],
  79 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  80 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  81    [Define if you want the HTTP Digest Authorization compiled in.])
  82
  83 AC_ARG_ENABLE(ntlm,
  84 [  --disable-ntlm          disable support for NTLM authorization],
  85 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  86
  87 AC_ARG_ENABLE(debug,
  88 [  --disable-debug         disable support for debugging output],
  89 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  90 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  91    [Define if you want the debug output support compiled in.])
  92
  93 dnl
  94 dnl Find the compiler
  95 dnl
  96
  97 dnl We want these before the checks, so the checks can modify their values.
  98 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
  99 test -z "$CC" && cc_specified=yes
 100
 101 AC_PROG_CC
 102 AM_PROG_CC_C_O
 103 AC_AIX
 104
 105 gl_EARLY
 106
 107 dnl
 108 dnl Gettext
 109 dnl
 110 AM_GNU_GETTEXT([external],[need-ngettext])
 111 AM_GNU_GETTEXT_VERSION([0.17])
 112
 113 AC_PROG_RANLIB
 114
 115 AC_PROG_LEX
 116
 117 dnl Turn on optimization by default.  Specifically:
 118 dnl
 119 dnl if the user hasn't specified CFLAGS, then
 120 dnl   if compiler is gcc, then
 121 dnl     use -O2 and some warning flags
 122 dnl   else
 123 dnl     use os-specific flags or -O
 124 if test -n "$auto_cflags"; then
 125   if test -n "$GCC"; then
 126     CFLAGS="$CFLAGS -O2 -Wall"
 127   else
 128     case "$host_os" in
 129       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 130       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 131       *)       CFLAGS="$CFLAGS -O" ;;
 132     esac
 133   fi
 134 fi
 135
 136 dnl
 137 dnl Checks for basic compiler characteristics.
 138 dnl
 139 AC_C_CONST
 140 AC_C_INLINE
 141 AC_C_VOLATILE
 142
 143 dnl Check for basic headers, even though we expect them to exist and
 144 dnl #include them unconditionally in the code.  Their detection is
 145 dnl still needed because test programs used by Autoconf macros check
 146 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 147 dnl Without the checks they will fail to be included in test programs,
 148 dnl which will subsequently fail.
 149 AC_HEADER_STDC
 150
 151 dnl Check for large file support.  This check needs to come fairly
 152 dnl early because it could (in principle) affect whether functions and
 153 dnl headers are available, whether they work, etc.
 154 AC_SYS_LARGEFILE
 155 AC_CHECK_SIZEOF(off_t)
 156
 157 dnl
 158 dnl Checks for system header files that might be missing.
 159 dnl
 160 AC_HEADER_STDBOOL
 161 AC_CHECK_HEADERS(unistd.h sys/time.h)
 162 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 163 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h wchar.h)
 164
 165 AC_CHECK_DECLS(h_errno,,,[#include <netdb.h>])
 166
 167 dnl
 168 dnl Check sizes of integer types.  These are used to find n-bit
 169 dnl integral types on older systems that fail to provide intN_t and
 170 dnl uintN_t typedefs.
 171 dnl
 172 AC_CHECK_SIZEOF([short])
 173 AC_CHECK_SIZEOF([int])
 174 AC_CHECK_SIZEOF([long])
 175 AC_CHECK_SIZEOF([long long])
 176 AC_CHECK_SIZEOF([void *])
 177
 178 dnl
 179 dnl Checks for non-universal or system-specific types.
 180 dnl
 181 AC_TYPE_SIZE_T
 182 AC_TYPE_PID_T
 183 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 184 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 185 #include <stdio.h>
 186 #include <sys/types.h>
 187 #if HAVE_INTTYPES_H
 188 # include <inttypes.h>
 189 #endif
 190 #include <signal.h>
 191 ])
 192
 193 # gnulib
 194 gl_INIT
 195
 196 dnl
 197 dnl Checks for library functions.
 198 dnl
 199 AC_FUNC_MMAP
 200 AC_FUNC_FSEEKO
 201 AC_CHECK_FUNCS(strptime timegm vsnprintf vasprintf drand48)
 202 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr wcwidth mbtowc)
 203 AC_CHECK_FUNCS(sleep symlink utime)
 204
 205 if test x"$ENABLE_OPIE" = xyes; then
 206   AC_LIBOBJ([ftp-opie])
 207 fi
 208
 209 dnl We expect to have these functions on Unix-like systems configure
 210 dnl runs on.  The defines are provided to get them in config.h.in so
 211 dnl Wget can still be ported to non-Unix systems (such as Windows)
 212 dnl that lack some of these functions.
 213 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 214 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 215 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 216 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 217
 218 dnl
 219 dnl Call Wget-specific macros defined in aclocal.
 220 dnl
 221 WGET_STRUCT_UTIMBUF
 222 WGET_FNMATCH
 223 WGET_NANOSLEEP
 224 WGET_POSIX_CLOCK
 225 WGET_NSL_SOCKET
 226
 227 dnl Deal with specific hosts
 228 case $host_os in
 229   *mingw32* )
 230     LIBS+=' -lws2_32'
 231     AC_LIBOBJ([mswindows])
 232     ;;
 233 esac
 234
 235
 236 dnl
 237 dnl Checks for libraries.
 238 dnl
 239
 240 AS_IF([test x"$with_zlib" != xno], [
 241   AC_CHECK_LIB(z, compress)
 242 ])
 243
 244 AS_IF([test x"$with_ssl" = xopenssl], [
 245     dnl some versions of openssl use zlib compression
 246     AC_CHECK_LIB(z, compress)
 247
 248     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 249     dnl doesn't record its dependency on libdl, so we need to make sure
 250     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 251     dnl dlopen(), but HP-UX uses shl_load().
 252     AC_CHECK_LIB(dl, dlopen, [], [
 253       AC_CHECK_LIB(dl, shl_load)
 254     ])
 255
 256     ssl_found=no
 257     case $host_os in
 258       *mingw32* )
 259         dnl prefer link to openssl dlls if possible. if not then fallback on static libs. if not then error
 260
 261         AC_CHECK_LIB(eay32, EVP_MD_CTX_init)
 262         if test x"$ac_cv_lib_eay32_EVP_MD_CTX_init" != xno
 263         then
 264           AC_CHECK_LIB(ssl32, SSL_connect, [
 265             ssl_found=yes
 266             AC_MSG_NOTICE([Enabling support for SSL via OpenSSL (shared)])
 267           ],
 268           AC_MSG_ERROR([openssl not found: shared lib eay32 found but ssl32 not found]))
 269
 270         else
 271           LIBS+=' -lgdi32'
 272           dnl fallback and test static libs
 273         fi
 274         dnl add zdll lib as dep for above tests?
 275       ;;
 276     esac
 277
 278 AS_IF([test x$ssl_found != xyes],
 279 [
 280   dnl Now actually check for -lssl if it wasn't already found
 281     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto z], [
 282   #include <openssl/ssl.h>
 283   #include <openssl/x509.h>
 284   #include <openssl/err.h>
 285   #include <openssl/rand.h>
 286   #include <openssl/des.h>
 287   #include <openssl/md4.h>
 288   #include <openssl/md5.h>
 289     ], [SSL_library_init ()])
 290     if test x"$LIBSSL" != x
 291     then
 292       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 293       AC_LIBOBJ([openssl])
 294       LIBS="$LIBSSL $LIBS"
 295     elif test x"$with_ssl" != x
 296     then
 297       AC_MSG_ERROR([--with-ssl=openssl was given, but SSL is not available.])
 298     fi
 299
 300     AC_LIBOBJ([openssl])
 301
 302 ])
 303
 304 ], [
 305   # --with-ssl is not gnutls: check if it's no
 306   AS_IF([test x"$with_ssl" != xno], [
 307     dnl Now actually check for -lssl
 308
 309     AC_CHECK_LIB(z, compress)
 310     AC_CHECK_LIB(gpg-error, gpg_err_init)
 311     AC_CHECK_LIB(gcrypt, gcry_control)
 312
 313   dnl Now actually check for -lssl
 314   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 315 #include <gnutls/gnutls.h>
 316   ], [gnutls_global_init()])
 317   if test x"$LIBGNUTLS" != x
 318   then
 319     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 320     AC_LIBOBJ([gnutls])
 321     LIBS="$LIBGNUTLS $LIBS"
 322   else
 323     AC_MSG_ERROR([--with-ssl was given, but GNUTLS is not available.])
 324   fi
 325
 326   AC_CHECK_FUNCS(gnutls_priority_set_direct)
 327   ]) # endif: --with-ssl == no?
 328 ]) # endif: --with-ssl == openssl?
 329
 330 dnl Enable NTLM if requested and if SSL is available.
 331 if test x"$LIBSSL" != x
 332 then
 333   if test x"$ENABLE_NTLM" != xno
 334   then
 335     AC_DEFINE([ENABLE_NTLM], 1,
 336      [Define if you want the NTLM authorization support compiled in.])
 337     AC_LIBOBJ([http-ntlm])
 338   fi
 339 else
 340   dnl If SSL is unavailable and the user explicitly requested NTLM,
 341   dnl abort.
 342   if test x"$ENABLE_NTLM" = xyes
 343   then
 344     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 345   fi
 346 fi
 347
 348 dnl **********************************************************************
 349 dnl Checks for IPv6
 350 dnl **********************************************************************
 351
 352 dnl
 353 dnl We test for IPv6 by checking, in turn, for availability of
 354 dnl presence of the INET6 address/protocol family and the existence of
 355 dnl struct sockaddr_in6.  If any of them is missing, IPv6 is disabled,
 356 dnl and the code reverts to old-style gethostbyname.
 357 dnl
 358 dnl If --enable-ipv6 is explicitly specified on the configure command
 359 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 360 dnl is specified, we disable IPv6 and don't check for it.  The default
 361 dnl is to autodetect IPv6 and use it where available.
 362 dnl
 363
 364 AC_ARG_ENABLE(ipv6,
 365   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 366   [case "${enable_ipv6}" in
 367     no)
 368       AC_MSG_NOTICE([disabling IPv6 at user request])
 369       dnl Disable IPv6 checking
 370       ipv6=no
 371       ;;
 372     yes)
 373       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 374       ipv6=yes
 375       force_ipv6=yes
 376       ;;
 377     auto)
 378       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 379       ipv6=yes
 380       ;;
 381     *)
 382       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 383       ;;
 384     esac
 385   ], [
 386     dnl If nothing is specified, assume auto-detection.
 387     ipv6=yes
 388   ]
 389 )
 390
 391 if test "X$ipv6" = "Xyes"; then
 392   PROTO_INET6([], [
 393     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 394     ipv6=no
 395   ])
 396 fi
 397
 398 if test "X$ipv6" = "Xyes"; then
 399   TYPE_STRUCT_SOCKADDR_IN6([],[
 400     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 401     ipv6=no
 402   ])
 403   if test "X$ipv6" = "Xyes"; then
 404     WGET_STRUCT_SOCKADDR_STORAGE
 405     MEMBER_SIN6_SCOPE_ID
 406   fi
 407 fi
 408
 409 if test "X$ipv6" = "Xyes"; then
 410   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 411   AC_MSG_NOTICE([Enabling support for IPv6.])
 412 elif test "x$force_ipv6" = "xyes"; then
 413   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 414 fi
 415
 416 dnl
 417 dnl Find makeinfo.  We used to provide support for Emacs processing
 418 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 419 dnl unavailable, but that broke with the addition of makeinfo-specific
 420 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 421 dnl build the Info documentation.
 422 dnl
 423
 424 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 425
 426 dnl
 427 dnl Find perl and pod2man
 428 dnl
 429
 430 AC_PATH_PROGS(PERL, [perl5 perl], no)
 431 AC_PATH_PROG(POD2MAN, pod2man, no)
 432
 433 if test "x${POD2MAN}" = xno; then
 434   COMMENT_IF_NO_POD2MAN="# "
 435 else
 436   COMMENT_IF_NO_POD2MAN=
 437 fi
 438 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 439
 440
 441 dnl
 442 dnl Check for IDN/IRIs
 443 dnl
 444
 445 AC_ARG_ENABLE(iri,
 446   AC_HELP_STRING([--disable-iri],[disable IDN/IRIs support]),
 447   [case "${enable_iri}" in
 448     no)
 449       dnl Disable IRIs checking
 450       AC_MSG_NOTICE([disabling IRIs at user request])
 451       iri=no
 452       ;;
 453     yes)
 454       dnl IRIs explicitly enabled
 455       iri=yes
 456       force_iri=yes
 457       ;;
 458     auto)
 459       dnl Auto-detect IRI
 460       iri=yes
 461       ;;
 462     *)
 463       AC_MSG_ERROR([Invalid --enable-iri argument \`$enable_iri'])
 464       ;;
 465     esac
 466   ], [
 467     dnl If nothing is specified, assume auto-detection
 468     iri=yes
 469   ]
 470 )
 471
 472 AC_ARG_WITH(libidn, AC_HELP_STRING([--with-libidn=[DIR]],
 473                                    [Support IDN/IRIs (needs GNU Libidn)]),
 474                                    libidn=$withval, libidn="")
 475 AS_IF([test "X$iri" != "Xno"],[
 476   AM_ICONV
 477
 478   if test "X$am_cv_func_iconv" != "Xyes"; then
 479     iri=no
 480     if test "X$force_iri" = "Xyes"; then
 481       AC_MSG_ERROR([Libiconv is required for IRIs support])
 482     else
 483       AC_MSG_NOTICE([disabling IRIs because libiconv wasn't found])
 484     fi
 485   fi
 486 ],[  # else
 487   # For some reason, this seems to be set even when we don't check.
 488   # Explicitly unset.
 489   LIBICONV=
 490 ])
 491
 492 if test "X$iri" != "Xno"; then
 493   if test "$libidn" != ""; then
 494     LDFLAGS="${LDFLAGS} -L$libidn/lib"
 495     CPPFLAGS="${CPPFLAGS} -I$libidn/include"
 496   fi
 497
 498   # If idna.h can't be found, check to see if it was installed under
 499   # /usr/include/idn (OpenSolaris, at least, places it there).
 500   # Check for idn-int.h in that case, because idna.h won't find
 501   # idn-int.h until we've decided to add -I/usr/include/idn.
 502   AC_CHECK_HEADER(idna.h, ,
 503     [AC_CHECK_HEADER(idn/idn-int.h,
 504                     [CPPFLAGS="${CPPFLAGS} -I/usr/include/idn"],
 505                     [iri=no])]
 506   )
 507
 508   if test "X$iri" != "Xno"; then
 509     AC_CHECK_LIB(idn, stringprep_check_version,
 510       [iri=yes LIBS="${LIBS} -lidn"], iri=no)
 511   fi
 512
 513   if test "X$iri" != "Xno" ; then
 514     AC_DEFINE([ENABLE_IRI], 1, [Define if IRI support is enabled.])
 515     AC_MSG_NOTICE([Enabling support for IRI.])
 516   else
 517     AC_MSG_WARN([Libidn not found])
 518   fi
 519 fi
 520
 521 dnl
 522 dnl Check for UUID
 523 dnl
 524
 525 AC_CHECK_HEADER(uuid/uuid.h,
 526                 AC_CHECK_LIB(uuid, uuid_generate,
 527                   [LIBS="${LIBS} -luuid"
 528                    AC_DEFINE([HAVE_LIBUUID], 1,
 529                              [Define if libuuid is available.])
 530                   ])
 531 )
 532
 533
 534 dnl Needed by src/Makefile.am
 535 AM_CONDITIONAL([IRI_IS_ENABLED], [test "X$iri" != "Xno"])
 536
 537
 538 dnl
 539 dnl Create output
 540 dnl
 541 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 542                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 543                  lib/Makefile])
 544 AC_CONFIG_HEADERS([src/config.h])
 545 AC_OUTPUT