sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007,
   3 dnl 2008 Free Software Foundation, Inc.
   4
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl Additional permission under GNU GPL version 3 section 7
  19
  20 dnl If you modify this program, or any covered work, by linking or
  21 dnl combining it with the OpenSSL project's OpenSSL library (or a
  22 dnl modified version of that library), containing parts covered by the
  23 dnl terms of the OpenSSL or SSLeay licenses, the Free Software Foundation
  24 dnl grants you additional permission to convey the resulting work.
  25 dnl Corresponding Source for a non-source form of such a combination
  26 dnl shall include the source code for the parts of OpenSSL used as well
  27 dnl as that of the covered work.
  28
  29 dnl
  30 dnl Process this file with autoconf to produce a configure script.
  31 dnl
  32
  33 AC_INIT([wget],
  34         [1.12-devel],
  35         [bug-wget@gnu.org])
  36 AC_PREREQ(2.61)
  37
  38 dnl
  39 dnl What version of Wget are we building?
  40 dnl
  41 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  42
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_AUX_DIR([.])
  45
  46 dnl
  47 dnl Automake setup
  48 dnl
  49 AM_INIT_AUTOMAKE(1.9)
  50
  51 dnl
  52 dnl Gettext
  53 dnl
  54 AM_GNU_GETTEXT([external],[need-ngettext])
  55 AM_GNU_GETTEXT_VERSION([0.16.1])
  56
  57 dnl
  58 dnl Get cannonical host
  59 dnl
  60 AC_CANONICAL_HOST
  61 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  62                    [Define to be the name of the operating system.])
  63
  64 dnl
  65 dnl Process features.
  66 dnl
  67
  68 AC_ARG_WITH(ssl,
  69 [[  --without-ssl           disable SSL autodetection]])
  70
  71 AC_ARG_ENABLE(opie,
  72 [  --disable-opie          disable support for opie or s/key FTP login],
  73 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  74 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  75    [Define if you want the Opie support for FTP compiled in.])
  76
  77 AC_ARG_ENABLE(digest,
  78 [  --disable-digest        disable support for HTTP digest authorization],
  79 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  80 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  81    [Define if you want the HTTP Digest Authorization compiled in.])
  82
  83 AC_ARG_ENABLE(ntlm,
  84 [  --disable-ntlm          disable support for NTLM authorization],
  85 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  86
  87 AC_ARG_ENABLE(debug,
  88 [  --disable-debug         disable support for debugging output],
  89 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  90 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  91    [Define if you want the debug output support compiled in.])
  92
  93 wget_need_md5=no
  94
  95 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  96 *yes*)
  97         wget_need_md5=yes
  98 esac
  99
 100 dnl
 101 dnl Find the compiler
 102 dnl
 103
 104 dnl We want these before the checks, so the checks can modify their values.
 105 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 106 test -z "$CC" && cc_specified=yes
 107
 108 AC_PROG_CC
 109 AM_PROG_CC_C_O
 110 AC_AIX
 111 gl_EARLY
 112 md5_EARLY
 113
 114 AC_PROG_RANLIB
 115
 116 AC_PROG_LEX
 117
 118 dnl Turn on optimization by default.  Specifically:
 119 dnl
 120 dnl if the user hasn't specified CFLAGS, then
 121 dnl   if compiler is gcc, then
 122 dnl     use -O2 and some warning flags
 123 dnl   else
 124 dnl     use os-specific flags or -O
 125 if test -n "$auto_cflags"; then
 126   if test -n "$GCC"; then
 127     CFLAGS="$CFLAGS -O2 -Wall"
 128   else
 129     case "$host_os" in
 130       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 131       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 132       *)       CFLAGS="$CFLAGS -O" ;;
 133     esac
 134   fi
 135 fi
 136
 137 dnl
 138 dnl Checks for basic compiler characteristics.
 139 dnl
 140 AC_C_CONST
 141 AC_C_INLINE
 142 AC_C_VOLATILE
 143
 144 dnl Check for basic headers, even though we expect them to exist and
 145 dnl #include them unconditionally in the code.  Their detection is
 146 dnl still needed because test programs used by Autoconf macros check
 147 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 148 dnl Without the checks they will fail to be included in test programs,
 149 dnl which will subsequently fail.
 150 AC_HEADER_STDC
 151
 152 dnl Check for large file support.  This check needs to come fairly
 153 dnl early because it could (in principle) affect whether functions and
 154 dnl headers are available, whether they work, etc.
 155 AC_SYS_LARGEFILE
 156 AC_CHECK_SIZEOF(off_t)
 157
 158 dnl
 159 dnl Checks for system header files that might be missing.
 160 dnl
 161 AC_HEADER_STDBOOL
 162 AC_CHECK_HEADERS(unistd.h sys/time.h)
 163 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 164 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h wchar.h)
 165
 166 dnl
 167 dnl Check sizes of integer types.  These are used to find n-bit
 168 dnl integral types on older systems that fail to provide intN_t and
 169 dnl uintN_t typedefs.
 170 dnl
 171 AC_CHECK_SIZEOF(short)
 172 AC_CHECK_SIZEOF(int)
 173 AC_CHECK_SIZEOF(long)
 174 AC_CHECK_SIZEOF(long long)
 175 AC_CHECK_SIZEOF(void *)
 176
 177 dnl
 178 dnl Checks for non-universal or system-specific types.
 179 dnl
 180 AC_TYPE_SIZE_T
 181 AC_TYPE_PID_T
 182 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 183 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 184 #include <stdio.h>
 185 #include <sys/types.h>
 186 #if HAVE_INTTYPES_H
 187 # include <inttypes.h>
 188 #endif
 189 #include <signal.h>
 190 ])
 191
 192 # gnulib
 193 gl_INIT
 194
 195 dnl
 196 dnl Checks for library functions.
 197 dnl
 198 AC_FUNC_ALLOCA
 199 AC_FUNC_MMAP
 200 AC_FUNC_FSEEKO
 201 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 202 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr wcwidth mbtowc)
 203
 204 if test x"$ENABLE_OPIE" = xyes; then
 205   AC_LIBOBJ([ftp-opie])
 206 fi
 207
 208 dnl We expect to have these functions on Unix-like systems configure
 209 dnl runs on.  The defines are provided to get them in config.h.in so
 210 dnl Wget can still be ported to non-Unix systems (such as Windows)
 211 dnl that lack some of these functions.
 212 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 213 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 214 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 215 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 216 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 217
 218 dnl
 219 dnl Call Wget-specific macros defined in aclocal.
 220 dnl
 221 WGET_STRUCT_UTIMBUF
 222 WGET_SOCKLEN_T
 223 WGET_FNMATCH
 224 WGET_NANOSLEEP
 225 WGET_POSIX_CLOCK
 226 WGET_NSL_SOCKET
 227
 228 dnl
 229 dnl Checks for libraries.
 230 dnl
 231
 232 AS_IF([test x"$with_ssl" = xgnutls], [
 233   dnl Now actually check for -lssl
 234   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 235 #include <gnutls/gnutls.h>
 236   ], [gnutls_global_init()])
 237   if test x"$LIBGNUTLS" != x
 238   then
 239     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 240     AC_LIBOBJ([gnutls])
 241   else
 242     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 243   fi
 244 ], [
 245   # --with-ssl is not gnutls: check if it's no
 246   AS_IF([test x"$with_ssl" != xno], [
 247     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 248     dnl doesn't record its dependency on libdl, so we need to make sure
 249     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 250     dnl dlopen(), but HP-UX uses shl_load().
 251     AC_CHECK_LIB(dl, dlopen, [], [
 252       AC_CHECK_LIB(dl, shl_load)
 253     ])
 254
 255     dnl Now actually check for -lssl
 256     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 257   #include <openssl/ssl.h>
 258   #include <openssl/x509.h>
 259   #include <openssl/err.h>
 260   #include <openssl/rand.h>
 261   #include <openssl/des.h>
 262   #include <openssl/md4.h>
 263   #include <openssl/md5.h>
 264     ], [SSL_library_init ()])
 265     if test x"$LIBSSL" != x
 266     then
 267       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 268       AC_LIBOBJ([openssl])
 269     elif test x"$with_ssl" != x
 270     then
 271       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 272     fi
 273   ]) # endif: --with-ssl == no?
 274 ]) # endif: --with-ssl == gnutls?
 275
 276
 277 dnl Enable NTLM if requested and if SSL is available.
 278 if test x"$LIBSSL" != x
 279 then
 280   if test x"$ENABLE_NTLM" != xno
 281   then
 282     AC_DEFINE([ENABLE_NTLM], 1,
 283      [Define if you want the NTLM authorization support compiled in.])
 284     AC_LIBOBJ([http-ntlm])
 285   fi
 286 else
 287   dnl If SSL is unavailable and the user explicitly requested NTLM,
 288   dnl abort.
 289   if test x"$ENABLE_NTLM" = xyes
 290   then
 291     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 292   fi
 293 fi
 294
 295 dnl
 296 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 297 dnl to use an existing library implementation to save on code size.
 298 dnl
 299
 300 if test x"$wget_need_md5" = xyes
 301 then
 302   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 303   dnl manipulate MD5_OBJ from the defun.
 304
 305   AC_LIBOBJ([gen-md5])
 306   found_md5=no
 307
 308   dnl Check for the system MD5 library on Solaris.  We don't check for
 309   dnl something simple like "MD5Update" because there are a number of
 310   dnl MD5 implementations that use that name, but have an otherwise
 311   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 312   dnl Solaris MD5 library.
 313   if test x"$found_md5" = xno; then
 314     AC_CHECK_LIB(md5, md5_calc, [
 315       dnl Some installations have bogus <md5.h> in the compiler's
 316       dnl include path, making the system md5 library useless.
 317       AC_MSG_CHECKING([for working md5.h])
 318       AC_COMPILE_IFELSE([#include <md5.h>
 319                         ], [
 320         AC_MSG_RESULT(yes)
 321         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 322         LIBS="-lmd5 $LIBS"
 323         found_md5=yes
 324         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 325       ], [AC_MSG_RESULT(no)])
 326     ])
 327   fi
 328
 329   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 330   dnl implementation.
 331   if test x"$found_md5" = xno; then
 332     if test x"$LIBSSL" != x; then
 333       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 334       found_md5=yes
 335       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 336     fi
 337   fi
 338
 339   dnl If none of the above worked, use the one we ship with Wget.
 340   if test x"$found_md5" = xno; then
 341     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 342     found_md5=yes
 343     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 344     AC_C_BIGENDIAN
 345
 346     AC_SUBST(MD5_CPPFLAGS, '-I $(top_srcdir)/md5')
 347     AC_SUBST(MD5_LDADD, '../md5/libmd5.a')
 348     AC_SUBST(MD5_SUBDIR, md5)
 349     md5_INIT
 350   fi
 351   AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 352 fi
 353
 354 dnl **********************************************************************
 355 dnl Checks for IPv6
 356 dnl **********************************************************************
 357
 358 dnl
 359 dnl We test for IPv6 by checking, in turn, for availability of
 360 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 361 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 362 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 363 dnl
 364 dnl If --enable-ipv6 is explicitly specified on the configure command
 365 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 366 dnl is specified, we disable IPv6 and don't check for it.  The default
 367 dnl is to autodetect IPv6 and use it where available.
 368 dnl
 369
 370 AC_ARG_ENABLE(ipv6,
 371   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 372   [case "${enable_ipv6}" in
 373     no)
 374       AC_MSG_NOTICE([disabling IPv6 at user request])
 375       dnl Disable IPv6 checking
 376       ipv6=no
 377       ;;
 378     yes)
 379       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 380       ipv6=yes
 381       force_ipv6=yes
 382       ;;
 383     auto)
 384       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 385       ipv6=yes
 386       ;;
 387     *)
 388       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 389       ;;
 390     esac
 391   ], [
 392     dnl If nothing is specified, assume auto-detection.
 393     ipv6=yes
 394   ]
 395 )
 396
 397 if test "X$ipv6" = "Xyes"; then
 398   AC_CHECK_FUNCS(getaddrinfo, [], [
 399     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 400     ipv6=no
 401   ])
 402 fi
 403
 404 if test "X$ipv6" = "Xyes"; then
 405   PROTO_INET6([], [
 406     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 407     ipv6=no
 408   ])
 409 fi
 410
 411 if test "X$ipv6" = "Xyes"; then
 412   TYPE_STRUCT_SOCKADDR_IN6([],[
 413     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 414     ipv6=no
 415   ])
 416   if test "X$ipv6" = "Xyes"; then
 417     WGET_STRUCT_SOCKADDR_STORAGE
 418     MEMBER_SIN6_SCOPE_ID
 419   fi
 420 fi
 421
 422 if test "X$ipv6" = "Xyes"; then
 423   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 424   AC_MSG_NOTICE([Enabling support for IPv6.])
 425 elif test "x$force_ipv6" = "xyes"; then
 426   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 427 fi
 428
 429
 430 dnl
 431 dnl Set of available languages.
 432 dnl
 433 dnl Originally this used to be static, looking like this:
 434 dnl     ALL_LINGUAS="cs de hr it ..."
 435 dnl The downside was that configure needed to be rebuilt whenever a
 436 dnl new language was added.
 437 dnl
 438 ALL_LINGUAS="en@quot en@boldquot en_US $(cd ${srcdir}/po && ls *.po | grep -v 'en@.*quot' | grep -v 'en_US\.po' | sed -e 's/\.po$//' | tr '\012' ' ')"
 439
 440 dnl
 441 dnl Find makeinfo.  We used to provide support for Emacs processing
 442 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 443 dnl unavailable, but that broke with the addition of makeinfo-specific
 444 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 445 dnl build the Info documentation.
 446 dnl
 447
 448 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 449
 450 dnl
 451 dnl Find perl and pod2man
 452 dnl
 453
 454 AC_PATH_PROGS(PERL, [perl5 perl], no)
 455 AC_PATH_PROG(POD2MAN, pod2man, no)
 456
 457 if test "x${POD2MAN}" = xno; then
 458   COMMENT_IF_NO_POD2MAN="# "
 459 else
 460   COMMENT_IF_NO_POD2MAN=
 461 fi
 462 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 463
 464 dnl
 465 dnl Create output
 466 dnl
 467 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 468                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 469                  lib/Makefile md5/Makefile windows/Makefile])
 470 AC_CONFIG_HEADERS([src/config.h])
 471 AC_OUTPUT