sjero.net Git - wget/blob - aclocal.m4

   1 dnl
   2 dnl Check for `struct utimbuf'.
   3 dnl
   4
   5 AC_DEFUN([WGET_STRUCT_UTIMBUF], [
   6   AC_CHECK_TYPES([struct utimbuf], [], [], [
   7 #include <stdio.h>
   8 #if HAVE_SYS_TYPES_H
   9 # include <sys/types.h>
  10 #endif
  11 #if HAVE_UTIME_H
  12 # include <utime.h>
  13 #endif
  14   ])
  15 ])
  16
  17
  18 dnl Check for socklen_t.  The third argument of accept, getsockname,
  19 dnl etc. is int * on some systems, but size_t * on others.  POSIX
  20 dnl finally standardized on socklen_t, but older systems don't have
  21 dnl it.  If socklen_t exists, we use it, else if accept() accepts
  22 dnl size_t *, we use that, else we use int.
  23
  24 AC_DEFUN([WGET_SOCKLEN_T], [
  25   AC_MSG_CHECKING(for socklen_t)
  26   AC_COMPILE_IFELSE([
  27 #include <sys/types.h>
  28 #include <sys/socket.h>
  29 socklen_t x;
  30   ], [AC_MSG_RESULT(socklen_t)], [
  31     AC_COMPILE_IFELSE([
  32 #include <sys/types.h>
  33 #include <sys/socket.h>
  34 int accept (int, struct sockaddr *, size_t *);
  35     ], [
  36       AC_MSG_RESULT(size_t)
  37       AC_DEFINE([socklen_t], [size_t],
  38                 [Define to int or size_t on systems without socklen_t.])
  39     ], [
  40       AC_MSG_RESULT(int)
  41       AC_DEFINE([socklen_t], [int],
  42                 [Define to int or size_t on systems without socklen_t.])
  43     ])
  44   ])
  45 ])
  46
  47 dnl Check whether fnmatch.h can be included.  This doesn't use
  48 dnl AC_FUNC_FNMATCH because Wget is already careful to only use
  49 dnl fnmatch on certain OS'es.  However, fnmatch.h is sometimes broken
  50 dnl even on those because Apache installs its own fnmatch.h to
  51 dnl /usr/local/include (!), which GCC uses before /usr/include.
  52
  53 AC_DEFUN([WGET_FNMATCH], [
  54   AC_MSG_CHECKING([for working fnmatch.h])
  55   AC_COMPILE_IFELSE([#include <fnmatch.h>
  56                     ], [
  57     AC_MSG_RESULT(yes)
  58     AC_DEFINE([HAVE_WORKING_FNMATCH_H], 1,
  59               [Define if fnmatch.h can be included.])
  60   ], [
  61     AC_MSG_RESULT(no)
  62   ])
  63 ])
  64
  65 dnl Check for nanosleep.  For nanosleep to work on Solaris, we must
  66 dnl link with -lt (recently) or with -lposix (older releases).
  67
  68 AC_DEFUN([WGET_NANOSLEEP], [
  69   AC_CHECK_FUNCS(nanosleep, [], [
  70     AC_CHECK_LIB(rt, nanosleep, [
  71       AC_DEFINE([HAVE_NANOSLEEP], 1,
  72                 [Define if you have the nanosleep function.])
  73       LIBS="-lrt $LIBS"
  74     ], [
  75       AC_CHECK_LIB(posix4, nanosleep, [
  76         AC_DEFINE([HAVE_NANOSLEEP], 1,
  77                   [Define if you have the nanosleep function.])
  78         LIBS="-lposix4 $LIBS"
  79       ])
  80     ])
  81   ])
  82 ])
  83
  84 dnl Check whether we need to link with -lnsl and -lsocket, as is the
  85 dnl case on e.g. Solaris.
  86
  87 AC_DEFUN([WGET_NSL_SOCKET], [
  88   dnl On Solaris, -lnsl is needed to use gethostbyname.  But checking
  89   dnl for gethostbyname is not enough because on "NCR MP-RAS 3.0"
  90   dnl gethostbyname is in libc, but -lnsl is still needed to use
  91   dnl -lsocket, as well as for functions such as inet_ntoa.  We look
  92   dnl for such known offenders and if one of them is not found, we
  93   dnl check if -lnsl is needed.
  94   wget_check_in_nsl=NONE
  95   AC_CHECK_FUNCS(gethostbyname, [], [
  96     wget_check_in_nsl=gethostbyname
  97   ])
  98   AC_CHECK_FUNCS(inet_ntoa, [], [
  99     wget_check_in_nsl=inet_ntoa
 100   ])
 101   if test $wget_check_in_nsl != NONE; then
 102     AC_CHECK_LIB(nsl, $wget_check_in_nsl)
 103   fi
 104   AC_CHECK_LIB(socket, socket)
 105 ])
 106
 107
 108 # serial 1
 109
 110 # @defmac AC_PROG_CC_STDC
 111 # @maindex PROG_CC_STDC
 112 # @ovindex CC
 113 # If the C compiler in not in ANSI C mode by default, try to add an option
 114 # to output variable @code{CC} to make it so.  This macro tries various
 115 # options that select ANSI C on some system or another.  It considers the
 116 # compiler to be in ANSI C mode if it defines @code{__STDC__} to 1 and
 117 # handles function prototypes correctly.
 118 #
 119 # If you use this macro, you should check after calling it whether the C
 120 # compiler has been set to accept ANSI C; if not, the shell variable
 121 # @code{am_cv_prog_cc_stdc} is set to @samp{no}.  If you wrote your source
 122 # code in ANSI C, you can make an un-ANSIfied copy of it by using the
 123 # program @code{ansi2knr}, which comes with Ghostscript.
 124 # @end defmac
 125
 126 AC_DEFUN(AM_PROG_CC_STDC,
 127 [AC_REQUIRE([AC_PROG_CC])
 128 AC_MSG_CHECKING([for ${CC-cc} option to accept ANSI C])
 129 AC_CACHE_VAL(am_cv_prog_cc_stdc,
 130 [am_cv_prog_cc_stdc=no
 131 ac_save_CC="$CC"
 132 # Don't try gcc -ansi; that turns off useful extensions and
 133 # breaks some systems' header files.
 134 # AIX                   -qlanglvl=ansi
 135 # Ultrix and OSF/1      -std1
 136 # HP-UX                 -Aa -D_HPUX_SOURCE
 137 for ac_arg in "" -qlanglvl=ansi -std1 "-Aa -D_HPUX_SOURCE"
 138 do
 139   CC="$ac_save_CC $ac_arg"
 140   AC_TRY_COMPILE(
 141 [#if !defined(__STDC__)
 142 choke me
 143 #endif
 144 /* DYNIX/ptx V4.1.3 can't compile sys/stat.h with -Xc -D__EXTENSIONS__. */
 145 #ifdef _SEQUENT_
 146 # include <sys/types.h>
 147 # include <sys/stat.h>
 148 #endif
 149 ], [
 150 int test (int i, double x);
 151 struct s1 {int (*f) (int a);};
 152 struct s2 {int (*f) (double a);};],
 153 [am_cv_prog_cc_stdc="$ac_arg"; break])
 154 done
 155 CC="$ac_save_CC"
 156 ])
 157 AC_MSG_RESULT($am_cv_prog_cc_stdc)
 158 case "x$am_cv_prog_cc_stdc" in
 159   x|xno) ;;
 160   *) CC="$CC $am_cv_prog_cc_stdc" ;;
 161 esac
 162 ])
 163
 164
 165 dnl ************************************************************
 166 dnl START OF IPv6 AUTOCONFIGURATION SUPPORT MACROS
 167 dnl ************************************************************
 168
 169 AC_DEFUN([TYPE_STRUCT_SOCKADDR_IN6],[
 170   wget_have_sockaddr_in6=
 171   AC_CHECK_TYPES([struct sockaddr_in6],[
 172     wget_have_sockaddr_in6=yes
 173   ],[
 174     wget_have_sockaddr_in6=no
 175   ],[
 176 #include <sys/types.h>
 177 #include <sys/socket.h>
 178 #include <netinet/in.h>
 179   ])
 180
 181   if test "X$wget_have_sockaddr_in6" = "Xyes"; then :
 182     $1
 183   else :
 184     $2
 185   fi
 186 ])
 187
 188
 189 AC_DEFUN([MEMBER_SIN6_SCOPE_ID],[
 190   AC_REQUIRE([TYPE_STRUCT_SOCKADDR_IN6])
 191
 192   wget_member_sin6_scope_id=
 193   if test "X$wget_have_sockaddr_in6" = "Xyes"; then
 194     AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],[
 195       wget_member_sin6_scope_id=yes
 196     ],[
 197       wget_member_sin6_scope_id=no
 198     ],[
 199 #include <sys/types.h>
 200 #include <sys/socket.h>
 201 #include <netinet/in.h>
 202     ])
 203   fi
 204
 205   if test "X$wget_member_sin6_scope_id" = "Xyes"; then
 206     AC_DEFINE([HAVE_SOCKADDR_IN6_SCOPE_ID], 1,
 207       [Define if struct sockaddr_in6 has the sin6_scope_id member])
 208     $1
 209   else :
 210     $2
 211   fi
 212 ])
 213
 214
 215 AC_DEFUN([PROTO_INET6],[
 216   AC_CACHE_CHECK([for INET6 protocol support], [wget_cv_proto_inet6],[
 217     AC_TRY_CPP([
 218 #include <sys/types.h>
 219 #include <sys/socket.h>
 220
 221 #ifndef PF_INET6
 222 #error Missing PF_INET6
 223 #endif
 224 #ifndef AF_INET6
 225 #error Mlssing AF_INET6
 226 #endif
 227     ],[
 228       wget_cv_proto_inet6=yes
 229     ],[
 230       wget_cv_proto_inet6=no
 231     ])
 232   ])
 233
 234   if test "X$wget_cv_proto_inet6" = "Xyes"; then :
 235     $1
 236   else :
 237     $2
 238   fi
 239 ])
 240
 241
 242 AC_DEFUN([WGET_STRUCT_SOCKADDR_STORAGE],[
 243   AC_CHECK_TYPES([struct sockaddr_storage],[], [], [
 244 #include <sys/types.h>
 245 #include <sys/socket.h>
 246   ])
 247 ])
 248
 249 dnl ************************************************************
 250 dnl END OF IPv6 AUTOCONFIGURATION SUPPORT MACROS
 251 dnl ************************************************************
 252 \f
 253 # This code originates from Ulrich Drepper's AM_WITH_NLS.
 254
 255 AC_DEFUN([WGET_WITH_NLS],
 256   [AC_MSG_CHECKING([whether NLS is requested])
 257     dnl Default is enabled NLS
 258     AC_ARG_ENABLE(nls,
 259       [  --disable-nls           do not use Native Language Support],
 260       HAVE_NLS=$enableval, HAVE_NLS=yes)
 261     AC_MSG_RESULT($HAVE_NLS)
 262
 263     dnl If something goes wrong, we may still decide not to use NLS.
 264     dnl For this reason, defer AC_SUBST'ing HAVE_NLS until the very
 265     dnl last moment.
 266
 267     if test x"$HAVE_NLS" = xyes; then
 268       dnl If LINGUAS is specified, use only those languages.  In fact,
 269       dnl compute an intersection of languages in LINGUAS and
 270       dnl ALL_LINGUAS, and use that.
 271       if test x"$LINGUAS" != x; then
 272         new_linguas=
 273         for lang1 in $ALL_LINGUAS; do
 274           for lang2 in $LINGUAS; do
 275             if test "$lang1" = "$lang2"; then
 276               new_linguas="$new_linguas $lang1"
 277             fi
 278           done
 279         done
 280         ALL_LINGUAS=$new_linguas
 281       fi
 282       AC_MSG_NOTICE([language catalogs: $ALL_LINGUAS])
 283       AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
 284         [test -z "`$ac_dir/$ac_word -h 2>&1 | grep 'dv '`"], msgfmt)
 285       AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
 286           [test -z "`$ac_dir/$ac_word -h 2>&1 | grep '(HELP)'`"], :)
 287       AC_SUBST(MSGFMT)
 288       AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
 289       CATOBJEXT=.gmo
 290       INSTOBJEXT=.mo
 291       DATADIRNAME=share
 292
 293       dnl Test whether we really found GNU xgettext.
 294       if test "$XGETTEXT" != ":"; then
 295         dnl If it is no GNU xgettext we define it as : so that the
 296         dnl Makefiles still can work.
 297         if $XGETTEXT --omit-header /dev/null 2> /dev/null; then
 298           : ;
 299         else
 300           AC_MSG_RESULT(
 301             [found xgettext programs is not GNU xgettext; ignore it])
 302           XGETTEXT=":"
 303         fi
 304       fi
 305
 306       AC_CHECK_HEADERS(locale.h libintl.h)
 307
 308       dnl Prefer gettext found in -lintl to the one in libc.
 309       dnl Otherwise it can happen that we include libintl.h from
 310       dnl /usr/local/lib, but fail to specify -lintl, which results in
 311       dnl link or run-time failures.  (Symptom: libintl_bindtextdomain
 312       dnl not found at link-time.)
 313
 314       AC_CHECK_LIB(intl, gettext, [
 315         dnl gettext is in libintl; announce the fact manually.
 316         LIBS="-lintl $LIBS"
 317         AC_DEFINE([HAVE_GETTEXT], 1,
 318                   [Define if you have the gettext function.])
 319       ], [
 320         AC_CHECK_FUNCS(gettext, [], [
 321           AC_MSG_RESULT([gettext not found; disabling NLS])
 322           HAVE_NLS=no
 323         ])
 324       ])
 325
 326       for lang in $ALL_LINGUAS; do
 327         GMOFILES="$GMOFILES $lang.gmo"
 328         POFILES="$POFILES $lang.po"
 329       done
 330       dnl Construct list of names of catalog files to be constructed.
 331       for lang in $ALL_LINGUAS; do
 332         CATALOGS="$CATALOGS ${lang}${CATOBJEXT}"
 333       done
 334
 335       dnl Make all variables we use known to autoconf.
 336       AC_SUBST(CATALOGS)
 337       AC_SUBST(CATOBJEXT)
 338       AC_SUBST(DATADIRNAME)
 339       AC_SUBST(GMOFILES)
 340       AC_SUBST(INSTOBJEXT)
 341       AC_SUBST(INTLLIBS)
 342       AC_SUBST(POFILES)
 343     fi
 344     AC_SUBST(HAVE_NLS)
 345     dnl Some independently maintained files, such as po/Makefile.in,
 346     dnl use `USE_NLS', so support it.
 347     USE_NLS=$HAVE_NLS
 348     AC_SUBST(USE_NLS)
 349     if test "x$HAVE_NLS" = xyes; then
 350       AC_DEFINE([HAVE_NLS], 1, [Define this if you want the NLS support.])
 351     fi
 352   ])
 353
 354 dnl Generate list of files to be processed by xgettext which will
 355 dnl be included in po/Makefile.
 356 dnl
 357 dnl This is not strictly an Autoconf macro, because it is run from
 358 dnl within `config.status' rather than from within configure.  This
 359 dnl is why special rules must be applied for it.
 360 AC_DEFUN(WGET_PROCESS_PO,
 361   [
 362    dnl I wonder what the following several lines do...
 363    if test "x$srcdir" != "x."; then
 364      if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 365        posrcprefix="$srcdir/"
 366      else
 367        posrcprefix="../$srcdir/"
 368      fi
 369    else
 370      posrcprefix="../"
 371    fi
 372    rm -f po/POTFILES
 373    dnl Use `echo' rather than AC_MSG_RESULT, because this is run from
 374    dnl `config.status'.
 375    echo "generating po/POTFILES from $srcdir/po/POTFILES.in"
 376    sed -e "/^#/d" -e "/^\$/d" -e "s,.*, $posrcprefix& \\\\,"  \
 377        -e "\$s/\(.*\) \\\\/\1/" \
 378         < $srcdir/po/POTFILES.in > po/POTFILES
 379    echo "creating po/Makefile"
 380    sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile
 381   ])
 382
 383 # Search path for a program which passes the given test.
 384 # Ulrich Drepper <drepper@cygnus.com>, 1996.
 385 #
 386 # This file may be copied and used freely without restrictions.  It
 387 # can be used in projects which are not available under the GNU Public
 388 # License but which still want to provide support for the GNU gettext
 389 # functionality.  Please note that the actual code is *not* freely
 390 # available.
 391
 392 # serial 1
 393
 394 dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
 395 dnl   TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
 396 AC_DEFUN(AM_PATH_PROG_WITH_TEST,
 397 [# Extract the first word of "$2", so it can be a program name with args.
 398 set dummy $2; ac_word=[$]2
 399 AC_MSG_CHECKING([for $ac_word])
 400 AC_CACHE_VAL(ac_cv_path_$1,
 401 [case "[$]$1" in
 402   /*)
 403   ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
 404   ;;
 405   *)
 406   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 407   for ac_dir in ifelse([$5], , $PATH, [$5]); do
 408     test -z "$ac_dir" && ac_dir=.
 409     if test -f $ac_dir/$ac_word; then
 410       if [$3]; then
 411         ac_cv_path_$1="$ac_dir/$ac_word"
 412         break
 413       fi
 414     fi
 415   done
 416   IFS="$ac_save_ifs"
 417 dnl If no 4th arg is given, leave the cache variable unset,
 418 dnl so AC_PATH_PROGS will keep looking.
 419 ifelse([$4], , , [  test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
 420 ])dnl
 421   ;;
 422 esac])dnl
 423 $1="$ac_cv_path_$1"
 424 if test -n "[$]$1"; then
 425   AC_MSG_RESULT([$]$1)
 426 else
 427   AC_MSG_RESULT(no)
 428 fi
 429 AC_SUBST($1)dnl
 430 ])
 431
 432 # Include libtool code.
 433
 434 builtin(include, libtool.m4)dnl