sjero.net Git - wget/blob - md5/m4/00gnulib.m4

   1 # 00gnulib.m4 serial 2
   2 dnl Copyright (C) 2009, 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl This file must be named something that sorts before all other
   8 dnl gnulib-provided .m4 files.  It is needed until such time as we can
   9 dnl assume Autoconf 2.64, with its improved AC_DEFUN_ONCE semantics.
  10
  11 # AC_DEFUN_ONCE([NAME], VALUE)
  12 # ----------------------------
  13 # Define NAME to expand to VALUE on the first use (whether by direct
  14 # expansion, or by AC_REQUIRE), and to nothing on all subsequent uses.
  15 # Avoid bugs in AC_REQUIRE in Autoconf 2.63 and earlier.  This
  16 # definition is slower than the version in Autoconf 2.64, because it
  17 # can only use interfaces that existed since 2.59; but it achieves the
  18 # same effect.  Quoting is necessary to avoid confusing Automake.
  19 m4_version_prereq([2.63.263], [],
  20 [m4_define([AC][_DEFUN_ONCE],
  21   [AC][_DEFUN([$1],
  22     [AC_REQUIRE([_gl_DEFUN_ONCE([$1])],
  23       [m4_indir([_gl_DEFUN_ONCE([$1])])])])]dnl
  24 [AC][_DEFUN([_gl_DEFUN_ONCE([$1])], [$2])])])
  25
  26 # gl_00GNULIB
  27 # -----------
  28 # Witness macro that this file has been included.  Needed to force
  29 # Automake to include this file prior to all other gnulib .m4 files.
  30 AC_DEFUN([gl_00GNULIB])