sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007,
   3 dnl 2008 Free Software Foundation, Inc.
   4
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl Additional permission under GNU GPL version 3 section 7
  19
  20 dnl If you modify this program, or any covered work, by linking or
  21 dnl combining it with the OpenSSL project's OpenSSL library (or a
  22 dnl modified version of that library), containing parts covered by the
  23 dnl terms of the OpenSSL or SSLeay licenses, the Free Software Foundation
  24 dnl grants you additional permission to convey the resulting work.
  25 dnl Corresponding Source for a non-source form of such a combination
  26 dnl shall include the source code for the parts of OpenSSL used as well
  27 dnl as that of the covered work.
  28
  29 dnl
  30 dnl Process this file with autoconf to produce a configure script.
  31 dnl
  32
  33 AC_INIT([wget],
  34         [1.12-devel],
  35         [bug-wget@gnu.org])
  36 AC_PREREQ(2.61)
  37
  38 dnl
  39 dnl What version of Wget are we building?
  40 dnl
  41 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  42
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_AUX_DIR([.])
  45
  46 dnl
  47 dnl Automake setup
  48 dnl
  49 AM_INIT_AUTOMAKE(1.9)
  50
  51 dnl
  52 dnl Gettext
  53 dnl
  54 AM_GNU_GETTEXT([external],[need-ngettext])
  55 AM_GNU_GETTEXT_VERSION([0.16.1])
  56
  57 dnl
  58 dnl Get cannonical host
  59 dnl
  60 AC_CANONICAL_HOST
  61 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  62                    [Define to be the name of the operating system.])
  63
  64 dnl
  65 dnl Process features.
  66 dnl
  67
  68 AC_ARG_WITH(ssl,
  69 [[  --without-ssl           disable SSL autodetection]])
  70
  71 AC_ARG_ENABLE(opie,
  72 [  --disable-opie          disable support for opie or s/key FTP login],
  73 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  74 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  75    [Define if you want the Opie support for FTP compiled in.])
  76
  77 AC_ARG_ENABLE(digest,
  78 [  --disable-digest        disable support for HTTP digest authorization],
  79 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  80 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  81    [Define if you want the HTTP Digest Authorization compiled in.])
  82
  83 AC_ARG_ENABLE(ntlm,
  84 [  --disable-ntlm          disable support for NTLM authorization],
  85 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  86
  87 AC_ARG_ENABLE(debug,
  88 [  --disable-debug         disable support for debugging output],
  89 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  90 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  91    [Define if you want the debug output support compiled in.])
  92
  93 wget_need_md5=no
  94
  95 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  96 *yes*)
  97         wget_need_md5=yes
  98 esac
  99
 100 dnl
 101 dnl Find the compiler
 102 dnl
 103
 104 dnl We want these before the checks, so the checks can modify their values.
 105 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 106 test -z "$CC" && cc_specified=yes
 107
 108 AC_PROG_CC
 109 AM_PROG_CC_C_O
 110 AC_AIX
 111 gl_EARLY
 112 md5_EARLY
 113
 114 AC_PROG_RANLIB
 115
 116 dnl Turn on optimization by default.  Specifically:
 117 dnl
 118 dnl if the user hasn't specified CFLAGS, then
 119 dnl   if compiler is gcc, then
 120 dnl     use -O2 and some warning flags
 121 dnl   else
 122 dnl     use os-specific flags or -O
 123 if test -n "$auto_cflags"; then
 124   if test -n "$GCC"; then
 125     CFLAGS="$CFLAGS -O2 -Wall"
 126   else
 127     case "$host_os" in
 128       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 129       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 130       *)       CFLAGS="$CFLAGS -O" ;;
 131     esac
 132   fi
 133 fi
 134
 135 dnl
 136 dnl Checks for basic compiler characteristics.
 137 dnl
 138 AC_C_CONST
 139 AC_C_INLINE
 140 AC_C_VOLATILE
 141
 142 dnl Check for basic headers, even though we expect them to exist and
 143 dnl #include them unconditionally in the code.  Their detection is
 144 dnl still needed because test programs used by Autoconf macros check
 145 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 146 dnl Without the checks they will fail to be included in test programs,
 147 dnl which will subsequently fail.
 148 AC_HEADER_STDC
 149
 150 dnl Check for large file support.  This check needs to come fairly
 151 dnl early because it could (in principle) affect whether functions and
 152 dnl headers are available, whether they work, etc.
 153 AC_SYS_LARGEFILE
 154 AC_CHECK_SIZEOF(off_t)
 155
 156 dnl
 157 dnl Checks for system header files that might be missing.
 158 dnl
 159 AC_HEADER_STDBOOL
 160 AC_CHECK_HEADERS(unistd.h sys/time.h)
 161 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 162 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h wchar.h)
 163
 164 dnl
 165 dnl Check sizes of integer types.  These are used to find n-bit
 166 dnl integral types on older systems that fail to provide intN_t and
 167 dnl uintN_t typedefs.
 168 dnl
 169 AC_CHECK_SIZEOF(short)
 170 AC_CHECK_SIZEOF(int)
 171 AC_CHECK_SIZEOF(long)
 172 AC_CHECK_SIZEOF(long long)
 173 AC_CHECK_SIZEOF(void *)
 174
 175 dnl
 176 dnl Checks for non-universal or system-specific types.
 177 dnl
 178 AC_TYPE_SIZE_T
 179 AC_TYPE_PID_T
 180 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 181 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 182 #include <stdio.h>
 183 #include <sys/types.h>
 184 #if HAVE_INTTYPES_H
 185 # include <inttypes.h>
 186 #endif
 187 #include <signal.h>
 188 ])
 189
 190 # gnulib
 191 gl_INIT
 192
 193 dnl
 194 dnl Checks for library functions.
 195 dnl
 196 AC_FUNC_MMAP
 197 AC_FUNC_FSEEKO
 198 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 199 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr wcwidth mbtowc)
 200
 201 if test x"$ENABLE_OPIE" = xyes; then
 202   AC_LIBOBJ([ftp-opie])
 203 fi
 204
 205 dnl We expect to have these functions on Unix-like systems configure
 206 dnl runs on.  The defines are provided to get them in config.h.in so
 207 dnl Wget can still be ported to non-Unix systems (such as Windows)
 208 dnl that lack some of these functions.
 209 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 210 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 211 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 212 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 213 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 214
 215 dnl
 216 dnl Call Wget-specific macros defined in aclocal.
 217 dnl
 218 WGET_STRUCT_UTIMBUF
 219 WGET_SOCKLEN_T
 220 WGET_FNMATCH
 221 WGET_NANOSLEEP
 222 WGET_POSIX_CLOCK
 223 WGET_NSL_SOCKET
 224
 225 dnl
 226 dnl Checks for libraries.
 227 dnl
 228
 229 AS_IF([test x"$with_ssl" = xgnutls], [
 230   dnl Now actually check for -lssl
 231   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 232 #include <gnutls/gnutls.h>
 233   ], [gnutls_global_init()])
 234   if test x"$LIBGNUTLS" != x
 235   then
 236     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 237     AC_LIBOBJ([gnutls])
 238   else
 239     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 240   fi
 241 ], [
 242   # --with-ssl is not gnutls: check if it's no
 243   AS_IF([test x"$with_ssl" != xno], [
 244     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 245     dnl doesn't record its dependency on libdl, so we need to make sure
 246     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 247     dnl dlopen(), but HP-UX uses shl_load().
 248     AC_CHECK_LIB(dl, dlopen, [], [
 249       AC_CHECK_LIB(dl, shl_load)
 250     ])
 251
 252     dnl Now actually check for -lssl
 253     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 254   #include <openssl/ssl.h>
 255   #include <openssl/x509.h>
 256   #include <openssl/err.h>
 257   #include <openssl/rand.h>
 258   #include <openssl/des.h>
 259   #include <openssl/md4.h>
 260   #include <openssl/md5.h>
 261     ], [SSL_library_init ()])
 262     if test x"$LIBSSL" != x
 263     then
 264       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 265       AC_LIBOBJ([openssl])
 266     elif test x"$with_ssl" != x
 267     then
 268       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 269     fi
 270   ]) # endif: --with-ssl == no?
 271 ]) # endif: --with-ssl == gnutls?
 272
 273
 274 dnl Enable NTLM if requested and if SSL is available.
 275 if test x"$LIBSSL" != x
 276 then
 277   if test x"$ENABLE_NTLM" != xno
 278   then
 279     AC_DEFINE([ENABLE_NTLM], 1,
 280      [Define if you want the NTLM authorization support compiled in.])
 281     AC_LIBOBJ([http-ntlm])
 282   fi
 283 else
 284   dnl If SSL is unavailable and the user explicitly requested NTLM,
 285   dnl abort.
 286   if test x"$ENABLE_NTLM" = xyes
 287   then
 288     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 289   fi
 290 fi
 291
 292 dnl
 293 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 294 dnl to use an existing library implementation to save on code size.
 295 dnl
 296
 297 if test x"$wget_need_md5" = xyes
 298 then
 299   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 300   dnl manipulate MD5_OBJ from the defun.
 301
 302   AC_LIBOBJ([gen-md5])
 303   found_md5=no
 304
 305   dnl Check for the system MD5 library on Solaris.  We don't check for
 306   dnl something simple like "MD5Update" because there are a number of
 307   dnl MD5 implementations that use that name, but have an otherwise
 308   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 309   dnl Solaris MD5 library.
 310   if test x"$found_md5" = xno; then
 311     AC_CHECK_LIB(md5, md5_calc, [
 312       dnl Some installations have bogus <md5.h> in the compiler's
 313       dnl include path, making the system md5 library useless.
 314       AC_MSG_CHECKING([for working md5.h])
 315       AC_COMPILE_IFELSE([#include <md5.h>
 316                         ], [
 317         AC_MSG_RESULT(yes)
 318         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 319         LIBS="-lmd5 $LIBS"
 320         found_md5=yes
 321         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 322       ], [AC_MSG_RESULT(no)])
 323     ])
 324   fi
 325
 326   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 327   dnl implementation.
 328   if test x"$found_md5" = xno; then
 329     if test x"$LIBSSL" != x; then
 330       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 331       found_md5=yes
 332       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 333     fi
 334   fi
 335
 336   dnl If none of the above worked, use the one we ship with Wget.
 337   if test x"$found_md5" = xno; then
 338     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 339     found_md5=yes
 340     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 341     AC_C_BIGENDIAN
 342
 343     AC_SUBST(MD5_CPPFLAGS, '-I $(top_srcdir)/md5')
 344     AC_SUBST(MD5_LDADD, '../md5/libmd5.a')
 345     AC_SUBST(MD5_SUBDIR, md5)
 346     md5_INIT
 347   fi
 348   AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 349 fi
 350
 351 dnl **********************************************************************
 352 dnl Checks for IPv6
 353 dnl **********************************************************************
 354
 355 dnl
 356 dnl We test for IPv6 by checking, in turn, for availability of
 357 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 358 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 359 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 360 dnl
 361 dnl If --enable-ipv6 is explicitly specified on the configure command
 362 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 363 dnl is specified, we disable IPv6 and don't check for it.  The default
 364 dnl is to autodetect IPv6 and use it where available.
 365 dnl
 366
 367 AC_ARG_ENABLE(ipv6,
 368   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 369   [case "${enable_ipv6}" in
 370     no)
 371       AC_MSG_NOTICE([disabling IPv6 at user request])
 372       dnl Disable IPv6 checking
 373       ipv6=no
 374       ;;
 375     yes)
 376       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 377       ipv6=yes
 378       force_ipv6=yes
 379       ;;
 380     auto)
 381       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 382       ipv6=yes
 383       ;;
 384     *)
 385       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 386       ;;
 387     esac
 388   ], [
 389     dnl If nothing is specified, assume auto-detection.
 390     ipv6=yes
 391   ]
 392 )
 393
 394 if test "X$ipv6" = "Xyes"; then
 395   AC_CHECK_FUNCS(getaddrinfo, [], [
 396     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 397     ipv6=no
 398   ])
 399 fi
 400
 401 if test "X$ipv6" = "Xyes"; then
 402   PROTO_INET6([], [
 403     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 404     ipv6=no
 405   ])
 406 fi
 407
 408 if test "X$ipv6" = "Xyes"; then
 409   TYPE_STRUCT_SOCKADDR_IN6([],[
 410     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 411     ipv6=no
 412   ])
 413   if test "X$ipv6" = "Xyes"; then
 414     WGET_STRUCT_SOCKADDR_STORAGE
 415     MEMBER_SIN6_SCOPE_ID
 416   fi
 417 fi
 418
 419 if test "X$ipv6" = "Xyes"; then
 420   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 421   AC_MSG_NOTICE([Enabling support for IPv6.])
 422 elif test "x$force_ipv6" = "xyes"; then
 423   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 424 fi
 425
 426
 427 dnl
 428 dnl Set of available languages.
 429 dnl
 430 dnl Originally this used to be static, looking like this:
 431 dnl     ALL_LINGUAS="cs de hr it ..."
 432 dnl The downside was that configure needed to be rebuilt whenever a
 433 dnl new language was added.
 434 dnl
 435 ALL_LINGUAS="en@quot en@boldquot en_US $(cd ${srcdir}/po && ls *.po | grep -v 'en@.*quot' | grep -v 'en_US\.po' | sed -e 's/\.po$//' | tr '\012' ' ')"
 436
 437 dnl
 438 dnl Find makeinfo.  We used to provide support for Emacs processing
 439 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 440 dnl unavailable, but that broke with the addition of makeinfo-specific
 441 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 442 dnl build the Info documentation.
 443 dnl
 444
 445 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 446
 447 dnl
 448 dnl Find perl and pod2man
 449 dnl
 450
 451 AC_PATH_PROGS(PERL, [perl5 perl], no)
 452 AC_PATH_PROG(POD2MAN, pod2man, no)
 453
 454 if test "x${POD2MAN}" = xno; then
 455   COMMENT_IF_NO_POD2MAN="# "
 456 else
 457   COMMENT_IF_NO_POD2MAN=
 458 fi
 459 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 460
 461 dnl
 462 dnl Create output
 463 dnl
 464 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 465                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 466                  lib/Makefile md5/Makefile windows/Makefile])
 467 AC_CONFIG_HEADERS([src/config.h])
 468 AC_OUTPUT