sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 3 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 dnl In addition, as a special exception, the Free Software Foundation
  18 dnl gives permission to link the code of its release of Wget with the
  19 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  20 dnl that use the same license as the "OpenSSL" library), and distribute
  21 dnl the linked executables.  You must obey the GNU General Public License
  22 dnl in all respects for all of the code used other than "OpenSSL".  If you
  23 dnl modify this file, you may extend this exception to your version of the
  24 dnl file, but you are not obligated to do so.  If you do not wish to do
  25 dnl so, delete this exception statement from your version.
  26
  27 dnl
  28 dnl Process this file with autoconf to produce a configure script.
  29 dnl
  30
  31 AC_INIT([wget],
  32         [m4_normalize(esyscmd([sed -e 's/^.*"\(.*\)";$/\1/' src/version.c]))],
  33         [bug-wget@gnu.org])
  34 AC_PREREQ(2.61)
  35
  36 # Make configure depend on the VERSION file, since it's used in AC_INIT
  37 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/src/version.c'])
  38
  39 dnl
  40 dnl What version of Wget are we building?
  41 dnl
  42 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  43
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CONFIG_AUX_DIR([.])
  46
  47 dnl
  48 dnl Automake setup
  49 dnl
  50 AM_INIT_AUTOMAKE(1.9)
  51
  52 dnl
  53 dnl Gettext
  54 dnl
  55 AM_GNU_GETTEXT([external],[need-ngettext])
  56 AM_GNU_GETTEXT_VERSION([0.16.1])
  57
  58 dnl
  59 dnl Get cannonical host
  60 dnl
  61 AC_CANONICAL_HOST
  62 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  63                    [Define to be the name of the operating system.])
  64
  65 dnl
  66 dnl Process features.
  67 dnl
  68
  69 AC_ARG_WITH(ssl,
  70 [[  --without-ssl           disable SSL autodetection]])
  71
  72 AC_ARG_ENABLE(opie,
  73 [  --disable-opie          disable support for opie or s/key FTP login],
  74 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  75 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  76    [Define if you want the Opie support for FTP compiled in.])
  77
  78 AC_ARG_ENABLE(digest,
  79 [  --disable-digest        disable support for HTTP digest authorization],
  80 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  81 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  82    [Define if you want the HTTP Digest Authorization compiled in.])
  83
  84 AC_ARG_ENABLE(ntlm,
  85 [  --disable-ntlm          disable support for NTLM authorization],
  86 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  87
  88 AC_ARG_ENABLE(debug,
  89 [  --disable-debug         disable support for debugging output],
  90 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  91 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  92    [Define if you want the debug output support compiled in.])
  93
  94 wget_need_md5=no
  95
  96 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  97 *yes*)
  98         wget_need_md5=yes
  99 esac
 100
 101 dnl
 102 dnl Find the compiler
 103 dnl
 104
 105 dnl We want these before the checks, so the checks can modify their values.
 106 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 107 test -z "$CC" && cc_specified=yes
 108
 109 AC_PROG_CC
 110 AM_PROG_CC_C_O
 111 AC_AIX
 112
 113 AC_PROG_RANLIB
 114
 115 dnl Turn on optimization by default.  Specifically:
 116 dnl
 117 dnl if the user hasn't specified CFLAGS, then
 118 dnl   if compiler is gcc, then
 119 dnl     use -O2 and some warning flags
 120 dnl   else
 121 dnl     use os-specific flags or -O
 122 if test -n "$auto_cflags"; then
 123   if test -n "$GCC"; then
 124     CFLAGS="$CFLAGS -O2 -Wall"
 125   else
 126     case "$host_os" in
 127       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 128       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 129       *)       CFLAGS="$CFLAGS -O" ;;
 130     esac
 131   fi
 132 fi
 133
 134 dnl
 135 dnl Checks for basic compiler characteristics.
 136 dnl
 137 AC_C_CONST
 138 AC_C_INLINE
 139 AC_C_VOLATILE
 140
 141 dnl Check for basic headers, even though we expect them to exist and
 142 dnl #include them unconditionally in the code.  Their detection is
 143 dnl still needed because test programs used by Autoconf macros check
 144 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 145 dnl Without the checks they will fail to be included in test programs,
 146 dnl which will subsequently fail.
 147 AC_HEADER_STDC
 148
 149 dnl Check for large file support.  This check needs to come fairly
 150 dnl early because it could (in principle) affect whether functions and
 151 dnl headers are available, whether they work, etc.
 152 AC_SYS_LARGEFILE
 153 AC_CHECK_SIZEOF(off_t)
 154
 155 dnl
 156 dnl Checks for system header files that might be missing.
 157 dnl
 158 AC_HEADER_STDBOOL
 159 AC_CHECK_HEADERS(unistd.h sys/time.h)
 160 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 161 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h)
 162
 163 dnl
 164 dnl Check sizes of integer types.  These are used to find n-bit
 165 dnl integral types on older systems that fail to provide intN_t and
 166 dnl uintN_t typedefs.
 167 dnl
 168 AC_CHECK_SIZEOF(short)
 169 AC_CHECK_SIZEOF(int)
 170 AC_CHECK_SIZEOF(long)
 171 AC_CHECK_SIZEOF(long long)
 172 AC_CHECK_SIZEOF(void *)
 173
 174 dnl
 175 dnl Checks for non-universal or system-specific types.
 176 dnl
 177 AC_TYPE_SIZE_T
 178 AC_TYPE_PID_T
 179 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 180 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 181 #include <stdio.h>
 182 #include <sys/types.h>
 183 #if HAVE_INTTYPES_H
 184 # include <inttypes.h>
 185 #endif
 186 #include <signal.h>
 187 ])
 188
 189 dnl
 190 dnl Checks for library functions.
 191 dnl
 192 AC_FUNC_ALLOCA
 193 AC_FUNC_MMAP
 194 AC_FUNC_FSEEKO
 195 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 196 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr)
 197
 198 if test x"$ENABLE_OPIE" = xyes; then
 199   AC_LIBOBJ([ftp-opie])
 200 fi
 201
 202 dnl We expect to have these functions on Unix-like systems configure
 203 dnl runs on.  The defines are provided to get them in config.h.in so
 204 dnl Wget can still be ported to non-Unix systems (such as Windows)
 205 dnl that lack some of these functions.
 206 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 207 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 208 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 209 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 210 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 211
 212 dnl
 213 dnl Call Wget-specific macros defined in aclocal.
 214 dnl
 215 WGET_STRUCT_UTIMBUF
 216 WGET_SOCKLEN_T
 217 WGET_FNMATCH
 218 WGET_NANOSLEEP
 219 WGET_POSIX_CLOCK
 220 WGET_NSL_SOCKET
 221
 222 dnl
 223 dnl Check if we need to compile in getopt.c.
 224 dnl
 225 AC_CHECK_FUNC(getopt_long, [], [
 226   AC_LIBOBJ([getopt])
 227 ])
 228
 229 dnl
 230 dnl Checks for libraries.
 231 dnl
 232
 233 AS_IF([test x"$with_ssl" = xgnutls], [
 234   dnl Now actually check for -lssl
 235   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 236 #include <gnutls/gnutls.h>
 237   ], [gnutls_global_init()])
 238   if test x"$LIBGNUTLS" != x
 239   then
 240     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 241     AC_LIBOBJ([gnutls])
 242   else
 243     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 244   fi
 245 ], [
 246   # --with-ssl is not gnutls: check if it's no
 247   AS_IF([test x"$with_ssl" != xno], [
 248     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 249     dnl doesn't record its dependency on libdl, so we need to make sure
 250     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 251     dnl dlopen(), but HP-UX uses shl_load().
 252     AC_CHECK_LIB(dl, dlopen, [], [
 253       AC_CHECK_LIB(dl, shl_load)
 254     ])
 255
 256     dnl Now actually check for -lssl
 257     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 258   #include <openssl/ssl.h>
 259   #include <openssl/x509.h>
 260   #include <openssl/err.h>
 261   #include <openssl/rand.h>
 262   #include <openssl/des.h>
 263   #include <openssl/md4.h>
 264   #include <openssl/md5.h>
 265     ], [SSL_library_init ()])
 266     if test x"$LIBSSL" != x
 267     then
 268       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 269       AC_LIBOBJ([openssl])
 270     elif test x"$with_ssl" != x
 271     then
 272       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 273     fi
 274   ]) # endif: --with-ssl == no?
 275 ]) # endif: --with-ssl == gnutls?
 276
 277
 278 dnl Enable NTLM if requested and if SSL is available.
 279 if test x"$LIBSSL" != x
 280 then
 281   if test x"$ENABLE_NTLM" != xno
 282   then
 283     AC_DEFINE([ENABLE_NTLM], 1,
 284      [Define if you want the NTLM authorization support compiled in.])
 285     AC_LIBOBJ([http-ntlm])
 286   fi
 287 else
 288   dnl If SSL is unavailable and the user explicitly requested NTLM,
 289   dnl abort.
 290   if test x"$ENABLE_NTLM" = xyes
 291   then
 292     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 293   fi
 294 fi
 295
 296 dnl
 297 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 298 dnl to use an existing library implementation to save on code size.
 299 dnl
 300
 301 if test x"$wget_need_md5" = xyes
 302 then
 303   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 304   dnl manipulate MD5_OBJ from the defun.
 305
 306   AC_LIBOBJ([gen-md5])
 307   found_md5=no
 308
 309   dnl Check for the system MD5 library on Solaris.  We don't check for
 310   dnl something simple like "MD5Update" because there are a number of
 311   dnl MD5 implementations that use that name, but have an otherwise
 312   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 313   dnl Solaris MD5 library.
 314   if test x"$found_md5" = xno; then
 315     AC_CHECK_LIB(md5, md5_calc, [
 316       dnl Some installations have bogus <md5.h> in the compiler's
 317       dnl include path, making the system md5 library useless.
 318       AC_MSG_CHECKING([for working md5.h])
 319       AC_COMPILE_IFELSE([#include <md5.h>
 320                         ], [
 321         AC_MSG_RESULT(yes)
 322         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 323         LIBS="-lmd5 $LIBS"
 324         found_md5=yes
 325         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 326       ], [AC_MSG_RESULT(no)])
 327     ])
 328   fi
 329
 330   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 331   dnl implementation.
 332   if test x"$found_md5" = xno; then
 333     if test x"$LIBSSL" != x; then
 334       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 335       found_md5=yes
 336       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 337     fi
 338   fi
 339
 340   dnl If none of the above worked, use the one we ship with Wget.
 341   if test x"$found_md5" = xno; then
 342     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 343     AC_LIBOBJ([gnu-md5])
 344     found_md5=yes
 345     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 346     AC_C_BIGENDIAN
 347   fi
 348 fi
 349 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 350
 351 dnl **********************************************************************
 352 dnl Checks for IPv6
 353 dnl **********************************************************************
 354
 355 dnl
 356 dnl We test for IPv6 by checking, in turn, for availability of
 357 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 358 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 359 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 360 dnl
 361 dnl If --enable-ipv6 is explicitly specified on the configure command
 362 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 363 dnl is specified, we disable IPv6 and don't check for it.  The default
 364 dnl is to autodetect IPv6 and use it where available.
 365 dnl
 366
 367 AC_ARG_ENABLE(ipv6,
 368   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 369   [case "${enable_ipv6}" in
 370     no)
 371       AC_MSG_NOTICE([disabling IPv6 at user request])
 372       dnl Disable IPv6 checking
 373       ipv6=no
 374       ;;
 375     yes)
 376       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 377       ipv6=yes
 378       force_ipv6=yes
 379       ;;
 380     auto)
 381       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 382       ipv6=yes
 383       ;;
 384     *)
 385       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 386       ;;
 387     esac
 388   ], [
 389     dnl If nothing is specified, assume auto-detection.
 390     ipv6=yes
 391   ]
 392 )
 393
 394 if test "X$ipv6" = "Xyes"; then
 395   AC_CHECK_FUNCS(getaddrinfo, [], [
 396     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 397     ipv6=no
 398   ])
 399 fi
 400
 401 if test "X$ipv6" = "Xyes"; then
 402   PROTO_INET6([], [
 403     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 404     ipv6=no
 405   ])
 406 fi
 407
 408 if test "X$ipv6" = "Xyes"; then
 409   TYPE_STRUCT_SOCKADDR_IN6([],[
 410     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 411     ipv6=no
 412   ])
 413   if test "X$ipv6" = "Xyes"; then
 414     WGET_STRUCT_SOCKADDR_STORAGE
 415     MEMBER_SIN6_SCOPE_ID
 416   fi
 417 fi
 418
 419 if test "X$ipv6" = "Xyes"; then
 420   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 421   AC_MSG_NOTICE([Enabling support for IPv6.])
 422 elif test "x$force_ipv6" = "xyes"; then
 423   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 424 fi
 425
 426
 427 dnl
 428 dnl Set of available languages.
 429 dnl
 430 dnl Originally this used to be static, looking like this:
 431 dnl     ALL_LINGUAS="cs de hr it ..."
 432 dnl The downside was that configure needed to be rebuilt whenever a
 433 dnl new language was added.
 434 dnl
 435 dnl ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 436
 437 dnl
 438 dnl Find makeinfo.  We used to provide support for Emacs processing
 439 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 440 dnl unavailable, but that broke with the addition of makeinfo-specific
 441 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 442 dnl build the Info documentation.
 443 dnl
 444
 445 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 446
 447 dnl
 448 dnl Find perl and pod2man
 449 dnl
 450
 451 AC_PATH_PROGS(PERL, [perl5 perl], no)
 452 AC_PATH_PROG(POD2MAN, pod2man, no)
 453
 454 if test "x${POD2MAN}" = xno; then
 455   COMMENT_IF_NO_POD2MAN="# "
 456 else
 457   COMMENT_IF_NO_POD2MAN=
 458 fi
 459 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 460
 461 dnl
 462 dnl Create output
 463 dnl
 464 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 465                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 466                  windows/Makefile])
 467 AC_CONFIG_HEADERS([src/config.h])
 468 AH_BOTTOM([
 469 #include "config-post.h"
 470 ])
 471 AC_OUTPUT