sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007, 2008, 2009, 2010, 2011
   3 dnl Free Software Foundation, Inc.
   4
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl Additional permission under GNU GPL version 3 section 7
  19
  20 dnl If you modify this program, or any covered work, by linking or
  21 dnl combining it with the OpenSSL project's OpenSSL library (or a
  22 dnl modified version of that library), containing parts covered by the
  23 dnl terms of the OpenSSL or SSLeay licenses, the Free Software Foundation
  24 dnl grants you additional permission to convey the resulting work.
  25 dnl Corresponding Source for a non-source form of such a combination
  26 dnl shall include the source code for the parts of OpenSSL used as well
  27 dnl as that of the covered work.
  28
  29 dnl
  30 dnl Process this file with autoconf to produce a configure script.
  31 dnl
  32
  33 AC_INIT([wget],
  34   [m4_esyscmd([build-aux/bzr-version-gen])],
  35         [bug-wget@gnu.org])
  36 AC_PREREQ(2.61)
  37
  38 dnl
  39 dnl What version of Wget are we building?
  40 dnl
  41 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  42
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_AUX_DIR([build-aux])
  45
  46 AC_CONFIG_SRCDIR([src/wget.h])
  47
  48 dnl
  49 dnl Automake setup
  50 dnl
  51 AM_INIT_AUTOMAKE([1.9])
  52
  53 dnl
  54 dnl Get cannonical host
  55 dnl
  56 AC_CANONICAL_HOST
  57 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  58                    [Define to be the name of the operating system.])
  59
  60 dnl
  61 dnl Process features.
  62 dnl
  63
  64 AC_ARG_WITH(ssl,
  65 [[  --without-ssl           disable SSL autodetection
  66   --with-ssl={gnutls,openssl} specify the SSL backend.  GNU TLS is the default.]])
  67
  68 AC_ARG_ENABLE(opie,
  69 [  --disable-opie          disable support for opie or s/key FTP login],
  70 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  71 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  72    [Define if you want the Opie support for FTP compiled in.])
  73
  74 AC_ARG_ENABLE(digest,
  75 [  --disable-digest        disable support for HTTP digest authorization],
  76 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  77 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  78    [Define if you want the HTTP Digest Authorization compiled in.])
  79
  80 AC_ARG_ENABLE(ntlm,
  81 [  --disable-ntlm          disable support for NTLM authorization],
  82 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  83
  84 AC_ARG_ENABLE(debug,
  85 [  --disable-debug         disable support for debugging output],
  86 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  87 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  88    [Define if you want the debug output support compiled in.])
  89
  90 dnl
  91 dnl Find the compiler
  92 dnl
  93
  94 dnl We want these before the checks, so the checks can modify their values.
  95 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
  96 test -z "$CC" && cc_specified=yes
  97
  98 AC_PROG_CC
  99 AM_PROG_CC_C_O
 100 AC_AIX
 101
 102 gl_EARLY
 103
 104 dnl
 105 dnl Gettext
 106 dnl
 107 AM_GNU_GETTEXT([external],[need-ngettext])
 108 AM_GNU_GETTEXT_VERSION([0.17])
 109
 110 AC_PROG_RANLIB
 111
 112 AC_PROG_LEX
 113
 114 dnl Turn on optimization by default.  Specifically:
 115 dnl
 116 dnl if the user hasn't specified CFLAGS, then
 117 dnl   if compiler is gcc, then
 118 dnl     use -O2 and some warning flags
 119 dnl   else
 120 dnl     use os-specific flags or -O
 121 if test -n "$auto_cflags"; then
 122   if test -n "$GCC"; then
 123     CFLAGS="$CFLAGS -O2 -Wall"
 124   else
 125     case "$host_os" in
 126       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 127       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 128       *)       CFLAGS="$CFLAGS -O" ;;
 129     esac
 130   fi
 131 fi
 132
 133 dnl
 134 dnl Checks for basic compiler characteristics.
 135 dnl
 136 AC_C_CONST
 137 AC_C_INLINE
 138 AC_C_VOLATILE
 139
 140 dnl Check for basic headers, even though we expect them to exist and
 141 dnl #include them unconditionally in the code.  Their detection is
 142 dnl still needed because test programs used by Autoconf macros check
 143 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 144 dnl Without the checks they will fail to be included in test programs,
 145 dnl which will subsequently fail.
 146 AC_HEADER_STDC
 147
 148 dnl Check for large file support.  This check needs to come fairly
 149 dnl early because it could (in principle) affect whether functions and
 150 dnl headers are available, whether they work, etc.
 151 AC_SYS_LARGEFILE
 152 AC_CHECK_SIZEOF(off_t)
 153
 154 dnl
 155 dnl Checks for system header files that might be missing.
 156 dnl
 157 AC_HEADER_STDBOOL
 158 AC_CHECK_HEADERS(unistd.h sys/time.h)
 159 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 160 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h wchar.h)
 161
 162 AC_CHECK_DECLS(h_errno,,,[#include <netdb.h>])
 163
 164 dnl
 165 dnl Check sizes of integer types.  These are used to find n-bit
 166 dnl integral types on older systems that fail to provide intN_t and
 167 dnl uintN_t typedefs.
 168 dnl
 169 AC_CHECK_SIZEOF([short])
 170 AC_CHECK_SIZEOF([int])
 171 AC_CHECK_SIZEOF([long])
 172 AC_CHECK_SIZEOF([long long])
 173 AC_CHECK_SIZEOF([void *])
 174
 175 dnl
 176 dnl Checks for non-universal or system-specific types.
 177 dnl
 178 AC_TYPE_SIZE_T
 179 AC_TYPE_PID_T
 180 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 181 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 182 #include <stdio.h>
 183 #include <sys/types.h>
 184 #if HAVE_INTTYPES_H
 185 # include <inttypes.h>
 186 #endif
 187 #include <signal.h>
 188 ])
 189
 190 # gnulib
 191 gl_INIT
 192
 193 dnl
 194 dnl Checks for library functions.
 195 dnl
 196 AC_FUNC_MMAP
 197 AC_FUNC_FSEEKO
 198 AC_CHECK_FUNCS(strptime timegm vsnprintf vasprintf drand48)
 199 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr wcwidth mbtowc)
 200 AC_CHECK_FUNCS(sleep symlink utime)
 201
 202 if test x"$ENABLE_OPIE" = xyes; then
 203   AC_LIBOBJ([ftp-opie])
 204 fi
 205
 206 dnl We expect to have these functions on Unix-like systems configure
 207 dnl runs on.  The defines are provided to get them in config.h.in so
 208 dnl Wget can still be ported to non-Unix systems (such as Windows)
 209 dnl that lack some of these functions.
 210 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 211 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 212 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 213 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 214
 215 dnl
 216 dnl Call Wget-specific macros defined in aclocal.
 217 dnl
 218 WGET_STRUCT_UTIMBUF
 219 WGET_FNMATCH
 220 WGET_NANOSLEEP
 221 WGET_POSIX_CLOCK
 222 WGET_NSL_SOCKET
 223
 224 dnl Deal with specific hosts
 225 case $host_os in
 226   *mingw32* )
 227     LIBS+=' -lws2_32'
 228     AC_LIBOBJ([mswindows])
 229     ;;
 230 esac
 231
 232
 233 dnl
 234 dnl Checks for libraries.
 235 dnl
 236
 237 AS_IF([test x"$with_ssl" = xopenssl], [
 238     dnl some versions of openssl use zlib compression
 239     AC_CHECK_LIB(z, compress)
 240
 241     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 242     dnl doesn't record its dependency on libdl, so we need to make sure
 243     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 244     dnl dlopen(), but HP-UX uses shl_load().
 245     AC_CHECK_LIB(dl, dlopen, [], [
 246       AC_CHECK_LIB(dl, shl_load)
 247     ])
 248
 249     ssl_found=no
 250     case $host_os in
 251       *mingw32* )
 252         dnl prefer link to openssl dlls if possible. if not then fallback on static libs. if not then error
 253
 254         AC_CHECK_LIB(eay32, EVP_MD_CTX_init)
 255         if test x"$ac_cv_lib_eay32_EVP_MD_CTX_init" != xno
 256         then
 257           AC_CHECK_LIB(ssl32, SSL_connect, [
 258             ssl_found=yes
 259             AC_MSG_NOTICE([Enabling support for SSL via OpenSSL (shared)])
 260           ],
 261           AC_MSG_ERROR([openssl not found: shared lib eay32 found but ssl32 not found]))
 262
 263         else
 264           LIBS+=' -lgdi32'
 265           dnl fallback and test static libs
 266         fi
 267         dnl add zdll lib as dep for above tests?
 268       ;;
 269     esac
 270
 271 AS_IF([test x$ssl_found != xyes],
 272 [
 273   dnl Now actually check for -lssl if it wasn't already found
 274     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 275   #include <openssl/ssl.h>
 276   #include <openssl/x509.h>
 277   #include <openssl/err.h>
 278   #include <openssl/rand.h>
 279   #include <openssl/des.h>
 280   #include <openssl/md4.h>
 281   #include <openssl/md5.h>
 282     ], [SSL_library_init ()])
 283     if test x"$LIBSSL" != x
 284     then
 285       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 286       AC_LIBOBJ([openssl])
 287       LIBS="$LIBSSL $LIBS"
 288     elif test x"$with_ssl" != x
 289     then
 290       AC_MSG_ERROR([--with-ssl=openssl was given, but SSL is not available.])
 291     fi
 292
 293     AC_LIBOBJ([openssl])
 294
 295 ])
 296
 297 ], [
 298   # --with-ssl is not gnutls: check if it's no
 299   AS_IF([test x"$with_ssl" != xno], [
 300     dnl Now actually check for -lssl
 301
 302     AC_CHECK_LIB(z, compress)
 303     AC_CHECK_LIB(gpg-error, gpg_err_init)
 304     AC_CHECK_LIB(gcrypt, gcry_control)
 305
 306   dnl Now actually check for -lssl
 307   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 308 #include <gnutls/gnutls.h>
 309   ], [gnutls_global_init()])
 310   if test x"$LIBGNUTLS" != x
 311   then
 312     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 313     AC_LIBOBJ([gnutls])
 314     LIBS="$LIBGNUTLS $LIBS"
 315   else
 316     AC_MSG_ERROR([--with-ssl was given, but GNUTLS is not available.])
 317   fi
 318
 319   AC_CHECK_FUNCS(gnutls_priority_set_direct)
 320   ]) # endif: --with-ssl == no?
 321 ]) # endif: --with-ssl == openssl?
 322
 323 dnl Enable NTLM if requested and if SSL is available.
 324 if test x"$LIBSSL" != x
 325 then
 326   if test x"$ENABLE_NTLM" != xno
 327   then
 328     AC_DEFINE([ENABLE_NTLM], 1,
 329      [Define if you want the NTLM authorization support compiled in.])
 330     AC_LIBOBJ([http-ntlm])
 331   fi
 332 else
 333   dnl If SSL is unavailable and the user explicitly requested NTLM,
 334   dnl abort.
 335   if test x"$ENABLE_NTLM" = xyes
 336   then
 337     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 338   fi
 339 fi
 340
 341 dnl **********************************************************************
 342 dnl Checks for IPv6
 343 dnl **********************************************************************
 344
 345 dnl
 346 dnl We test for IPv6 by checking, in turn, for availability of
 347 dnl presence of the INET6 address/protocol family and the existence of
 348 dnl struct sockaddr_in6.  If any of them is missing, IPv6 is disabled,
 349 dnl and the code reverts to old-style gethostbyname.
 350 dnl
 351 dnl If --enable-ipv6 is explicitly specified on the configure command
 352 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 353 dnl is specified, we disable IPv6 and don't check for it.  The default
 354 dnl is to autodetect IPv6 and use it where available.
 355 dnl
 356
 357 AC_ARG_ENABLE(ipv6,
 358   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 359   [case "${enable_ipv6}" in
 360     no)
 361       AC_MSG_NOTICE([disabling IPv6 at user request])
 362       dnl Disable IPv6 checking
 363       ipv6=no
 364       ;;
 365     yes)
 366       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 367       ipv6=yes
 368       force_ipv6=yes
 369       ;;
 370     auto)
 371       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 372       ipv6=yes
 373       ;;
 374     *)
 375       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 376       ;;
 377     esac
 378   ], [
 379     dnl If nothing is specified, assume auto-detection.
 380     ipv6=yes
 381   ]
 382 )
 383
 384 if test "X$ipv6" = "Xyes"; then
 385   PROTO_INET6([], [
 386     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 387     ipv6=no
 388   ])
 389 fi
 390
 391 if test "X$ipv6" = "Xyes"; then
 392   TYPE_STRUCT_SOCKADDR_IN6([],[
 393     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 394     ipv6=no
 395   ])
 396   if test "X$ipv6" = "Xyes"; then
 397     WGET_STRUCT_SOCKADDR_STORAGE
 398     MEMBER_SIN6_SCOPE_ID
 399   fi
 400 fi
 401
 402 if test "X$ipv6" = "Xyes"; then
 403   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 404   AC_MSG_NOTICE([Enabling support for IPv6.])
 405 elif test "x$force_ipv6" = "xyes"; then
 406   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 407 fi
 408
 409 dnl
 410 dnl Find makeinfo.  We used to provide support for Emacs processing
 411 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 412 dnl unavailable, but that broke with the addition of makeinfo-specific
 413 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 414 dnl build the Info documentation.
 415 dnl
 416
 417 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 418
 419 dnl
 420 dnl Find perl and pod2man
 421 dnl
 422
 423 AC_PATH_PROGS(PERL, [perl5 perl], no)
 424 AC_PATH_PROG(POD2MAN, pod2man, no)
 425
 426 if test "x${POD2MAN}" = xno; then
 427   COMMENT_IF_NO_POD2MAN="# "
 428 else
 429   COMMENT_IF_NO_POD2MAN=
 430 fi
 431 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 432
 433
 434 dnl
 435 dnl Check for IDN/IRIs
 436 dnl
 437
 438 AC_ARG_ENABLE(iri,
 439   AC_HELP_STRING([--disable-iri],[disable IDN/IRIs support]),
 440   [case "${enable_iri}" in
 441     no)
 442       dnl Disable IRIs checking
 443       AC_MSG_NOTICE([disabling IRIs at user request])
 444       iri=no
 445       ;;
 446     yes)
 447       dnl IRIs explicitly enabled
 448       iri=yes
 449       force_iri=yes
 450       ;;
 451     auto)
 452       dnl Auto-detect IRI
 453       iri=yes
 454       ;;
 455     *)
 456       AC_MSG_ERROR([Invalid --enable-iri argument \`$enable_iri'])
 457       ;;
 458     esac
 459   ], [
 460     dnl If nothing is specified, assume auto-detection
 461     iri=yes
 462   ]
 463 )
 464
 465 AC_ARG_WITH(libidn, AC_HELP_STRING([--with-libidn=[DIR]],
 466                                    [Support IDN/IRIs (needs GNU Libidn)]),
 467                                    libidn=$withval, libidn="")
 468 AS_IF([test "X$iri" != "Xno"],[
 469   AM_ICONV
 470
 471   if test "X$am_cv_func_iconv" != "Xyes"; then
 472     iri=no
 473     if test "X$force_iri" = "Xyes"; then
 474       AC_MSG_ERROR([Libiconv is required for IRIs support])
 475     else
 476       AC_MSG_NOTICE([disabling IRIs because libiconv wasn't found])
 477     fi
 478   fi
 479 ],[  # else
 480   # For some reason, this seems to be set even when we don't check.
 481   # Explicitly unset.
 482   LIBICONV=
 483 ])
 484
 485 if test "X$iri" != "Xno"; then
 486   if test "$libidn" != ""; then
 487     LDFLAGS="${LDFLAGS} -L$libidn/lib"
 488     CPPFLAGS="${CPPFLAGS} -I$libidn/include"
 489   fi
 490
 491   # If idna.h can't be found, check to see if it was installed under
 492   # /usr/include/idn (OpenSolaris, at least, places it there).
 493   # Check for idn-int.h in that case, because idna.h won't find
 494   # idn-int.h until we've decided to add -I/usr/include/idn.
 495   AC_CHECK_HEADER(idna.h, ,
 496     [AC_CHECK_HEADER(idn/idn-int.h,
 497                     [CPPFLAGS="${CPPFLAGS} -I/usr/include/idn"],
 498                     [iri=no])]
 499   )
 500
 501   if test "X$iri" != "Xno"; then
 502     AC_CHECK_LIB(idn, stringprep_check_version,
 503       [iri=yes LIBS="${LIBS} -lidn"], iri=no)
 504   fi
 505
 506   if test "X$iri" != "Xno" ; then
 507     AC_DEFINE([ENABLE_IRI], 1, [Define if IRI support is enabled.])
 508     AC_MSG_NOTICE([Enabling support for IRI.])
 509   else
 510     AC_MSG_WARN([Libidn not found])
 511   fi
 512 fi
 513
 514
 515 dnl Needed by src/Makefile.am
 516 AM_CONDITIONAL([IRI_IS_ENABLED], [test "X$iri" != "Xno"])
 517
 518
 519 dnl
 520 dnl Create output
 521 dnl
 522 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 523                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 524                  lib/Makefile])
 525 AC_CONFIG_HEADERS([src/config.h])
 526 AC_OUTPUT