sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007, 2008, 2009 Free Software
   3 dnl Foundation, Inc.
   4
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl Additional permission under GNU GPL version 3 section 7
  19
  20 dnl If you modify this program, or any covered work, by linking or
  21 dnl combining it with the OpenSSL project's OpenSSL library (or a
  22 dnl modified version of that library), containing parts covered by the
  23 dnl terms of the OpenSSL or SSLeay licenses, the Free Software Foundation
  24 dnl grants you additional permission to convey the resulting work.
  25 dnl Corresponding Source for a non-source form of such a combination
  26 dnl shall include the source code for the parts of OpenSSL used as well
  27 dnl as that of the covered work.
  28
  29 dnl
  30 dnl Process this file with autoconf to produce a configure script.
  31 dnl
  32
  33 AC_INIT([wget],
  34         [1.12.1-devel],
  35         [bug-wget@gnu.org])
  36 AC_PREREQ(2.61)
  37
  38 dnl
  39 dnl What version of Wget are we building?
  40 dnl
  41 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  42
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_AUX_DIR([build-aux])
  45
  46 AC_CONFIG_SRCDIR([src/wget.h])
  47
  48 dnl
  49 dnl Automake setup
  50 dnl
  51 AM_INIT_AUTOMAKE(dist-bzip2 dist-lzma 1.9)
  52
  53 dnl
  54 dnl Get cannonical host
  55 dnl
  56 AC_CANONICAL_HOST
  57 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  58                    [Define to be the name of the operating system.])
  59
  60 dnl
  61 dnl Process features.
  62 dnl
  63
  64 AC_ARG_WITH(ssl,
  65 [[  --without-ssl           disable SSL autodetection]])
  66
  67 AC_ARG_ENABLE(opie,
  68 [  --disable-opie          disable support for opie or s/key FTP login],
  69 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  70 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  71    [Define if you want the Opie support for FTP compiled in.])
  72
  73 AC_ARG_ENABLE(digest,
  74 [  --disable-digest        disable support for HTTP digest authorization],
  75 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  76 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  77    [Define if you want the HTTP Digest Authorization compiled in.])
  78
  79 AC_ARG_ENABLE(ntlm,
  80 [  --disable-ntlm          disable support for NTLM authorization],
  81 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  82
  83 AC_ARG_ENABLE(debug,
  84 [  --disable-debug         disable support for debugging output],
  85 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  86 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  87    [Define if you want the debug output support compiled in.])
  88
  89 wget_need_md5=no
  90
  91 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  92 *yes*)
  93         wget_need_md5=yes
  94 esac
  95
  96 dnl
  97 dnl Find the compiler
  98 dnl
  99
 100 dnl We want these before the checks, so the checks can modify their values.
 101 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 102 test -z "$CC" && cc_specified=yes
 103
 104 AC_PROG_CC
 105 AM_PROG_CC_C_O
 106 AC_AIX
 107
 108 gl_EARLY
 109 md5_EARLY
 110
 111 dnl
 112 dnl Gettext
 113 dnl
 114 AM_GNU_GETTEXT([external],[need-ngettext])
 115 AM_GNU_GETTEXT_VERSION([0.17])
 116
 117 AC_PROG_RANLIB
 118
 119 AC_PROG_LEX
 120
 121 dnl Turn on optimization by default.  Specifically:
 122 dnl
 123 dnl if the user hasn't specified CFLAGS, then
 124 dnl   if compiler is gcc, then
 125 dnl     use -O2 and some warning flags
 126 dnl   else
 127 dnl     use os-specific flags or -O
 128 if test -n "$auto_cflags"; then
 129   if test -n "$GCC"; then
 130     CFLAGS="$CFLAGS -O2 -Wall"
 131   else
 132     case "$host_os" in
 133       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 134       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 135       *)       CFLAGS="$CFLAGS -O" ;;
 136     esac
 137   fi
 138 fi
 139
 140 dnl
 141 dnl Checks for basic compiler characteristics.
 142 dnl
 143 AC_C_CONST
 144 AC_C_INLINE
 145 AC_C_VOLATILE
 146
 147 dnl Check for basic headers, even though we expect them to exist and
 148 dnl #include them unconditionally in the code.  Their detection is
 149 dnl still needed because test programs used by Autoconf macros check
 150 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 151 dnl Without the checks they will fail to be included in test programs,
 152 dnl which will subsequently fail.
 153 AC_HEADER_STDC
 154
 155 dnl Check for large file support.  This check needs to come fairly
 156 dnl early because it could (in principle) affect whether functions and
 157 dnl headers are available, whether they work, etc.
 158 AC_SYS_LARGEFILE
 159 AC_CHECK_SIZEOF(off_t)
 160
 161 dnl
 162 dnl Checks for system header files that might be missing.
 163 dnl
 164 AC_HEADER_STDBOOL
 165 AC_CHECK_HEADERS(unistd.h sys/time.h)
 166 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 167 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h wchar.h)
 168
 169 AC_CHECK_DECLS(h_errno,,,[#include <netdb.h>])
 170
 171 dnl
 172 dnl Check sizes of integer types.  These are used to find n-bit
 173 dnl integral types on older systems that fail to provide intN_t and
 174 dnl uintN_t typedefs.
 175 dnl
 176 AC_CHECK_SIZEOF(short)
 177 AC_CHECK_SIZEOF(int)
 178 AC_CHECK_SIZEOF(long)
 179 AC_CHECK_SIZEOF(long long)
 180 AC_CHECK_SIZEOF(void *)
 181
 182 dnl
 183 dnl Checks for non-universal or system-specific types.
 184 dnl
 185 AC_TYPE_SIZE_T
 186 AC_TYPE_PID_T
 187 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 188 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 189 #include <stdio.h>
 190 #include <sys/types.h>
 191 #if HAVE_INTTYPES_H
 192 # include <inttypes.h>
 193 #endif
 194 #include <signal.h>
 195 ])
 196
 197 # gnulib
 198 gl_INIT
 199
 200 dnl
 201 dnl Checks for library functions.
 202 dnl
 203 AC_FUNC_MMAP
 204 AC_FUNC_FSEEKO
 205 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 206 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr wcwidth mbtowc)
 207 AC_CHECK_FUNCS(sleep symlink)
 208
 209 if test x"$ENABLE_OPIE" = xyes; then
 210   AC_LIBOBJ([ftp-opie])
 211 fi
 212
 213 dnl We expect to have these functions on Unix-like systems configure
 214 dnl runs on.  The defines are provided to get them in config.h.in so
 215 dnl Wget can still be ported to non-Unix systems (such as Windows)
 216 dnl that lack some of these functions.
 217 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 218 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 219 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 220 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 221
 222 dnl
 223 dnl Call Wget-specific macros defined in aclocal.
 224 dnl
 225 WGET_STRUCT_UTIMBUF
 226 WGET_FNMATCH
 227 WGET_NANOSLEEP
 228 WGET_POSIX_CLOCK
 229 WGET_NSL_SOCKET
 230
 231 dnl Deal with specific hosts
 232 case $host_os in
 233   *mingw32* )
 234     AC_SUBST(W32LIBS, '-lwsock32 -lws2_32')
 235     AC_LIBOBJ([mswindows])
 236     ;;
 237 esac
 238
 239 dnl
 240 dnl Checks for libraries.
 241 dnl
 242
 243 AS_IF([test x"$with_ssl" = xgnutls], [
 244   dnl Now actually check for -lssl
 245   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 246 #include <gnutls/gnutls.h>
 247   ], [gnutls_global_init()])
 248   if test x"$LIBGNUTLS" != x
 249   then
 250     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 251     AC_LIBOBJ([gnutls])
 252   else
 253     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 254   fi
 255 ], [
 256   # --with-ssl is not gnutls: check if it's no
 257   AS_IF([test x"$with_ssl" != xno], [
 258     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 259     dnl doesn't record its dependency on libdl, so we need to make sure
 260     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 261     dnl dlopen(), but HP-UX uses shl_load().
 262     AC_CHECK_LIB(dl, dlopen, [], [
 263       AC_CHECK_LIB(dl, shl_load)
 264     ])
 265
 266     dnl Now actually check for -lssl
 267     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 268   #include <openssl/ssl.h>
 269   #include <openssl/x509.h>
 270   #include <openssl/err.h>
 271   #include <openssl/rand.h>
 272   #include <openssl/des.h>
 273   #include <openssl/md4.h>
 274   #include <openssl/md5.h>
 275     ], [SSL_library_init ()])
 276     if test x"$LIBSSL" != x
 277     then
 278       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 279       AC_LIBOBJ([openssl])
 280     elif test x"$with_ssl" != x
 281     then
 282       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 283     fi
 284   ]) # endif: --with-ssl == no?
 285 ]) # endif: --with-ssl == gnutls?
 286
 287
 288 dnl Enable NTLM if requested and if SSL is available.
 289 if test x"$LIBSSL" != x
 290 then
 291   if test x"$ENABLE_NTLM" != xno
 292   then
 293     AC_DEFINE([ENABLE_NTLM], 1,
 294      [Define if you want the NTLM authorization support compiled in.])
 295     AC_LIBOBJ([http-ntlm])
 296   fi
 297 else
 298   dnl If SSL is unavailable and the user explicitly requested NTLM,
 299   dnl abort.
 300   if test x"$ENABLE_NTLM" = xyes
 301   then
 302     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 303   fi
 304 fi
 305
 306 dnl
 307 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 308 dnl to use an existing library implementation to save on code size.
 309 dnl
 310
 311 if test x"$wget_need_md5" = xyes
 312 then
 313   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 314   dnl manipulate MD5_OBJ from the defun.
 315
 316   AC_LIBOBJ([gen-md5])
 317   found_md5=no
 318
 319   dnl Check for the system MD5 library on Solaris.  We don't check for
 320   dnl something simple like "MD5Update" because there are a number of
 321   dnl MD5 implementations that use that name, but have an otherwise
 322   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 323   dnl Solaris MD5 library.
 324   if test x"$found_md5" = xno; then
 325     AC_CHECK_LIB(md5, md5_calc, [
 326       dnl Some installations have bogus <md5.h> in the compiler's
 327       dnl include path, making the system md5 library useless.
 328       AC_MSG_CHECKING([for working md5.h])
 329       AC_COMPILE_IFELSE([#include <md5.h>
 330                         ], [
 331         AC_MSG_RESULT(yes)
 332         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 333         LIBS="-lmd5 $LIBS"
 334         found_md5=yes
 335         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 336       ], [AC_MSG_RESULT(no)])
 337     ])
 338   fi
 339
 340   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 341   dnl implementation.
 342   if test x"$found_md5" = xno; then
 343     if test x"$LIBSSL" != x; then
 344       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 345       found_md5=yes
 346       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 347     fi
 348   fi
 349
 350   dnl If none of the above worked, use the one we ship with Wget.
 351   if test x"$found_md5" = xno; then
 352     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 353     found_md5=yes
 354     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 355     AC_C_BIGENDIAN
 356
 357     AC_SUBST(MD5_CPPFLAGS, '-I $(top_srcdir)/md5')
 358     AC_SUBST(MD5_LDADD, '../md5/libmd5.a')
 359     AC_SUBST(MD5_SUBDIR, md5)
 360     md5_INIT
 361   fi
 362   AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 363 fi
 364
 365 dnl **********************************************************************
 366 dnl Checks for IPv6
 367 dnl **********************************************************************
 368
 369 dnl
 370 dnl We test for IPv6 by checking, in turn, for availability of
 371 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 372 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 373 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 374 dnl
 375 dnl If --enable-ipv6 is explicitly specified on the configure command
 376 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 377 dnl is specified, we disable IPv6 and don't check for it.  The default
 378 dnl is to autodetect IPv6 and use it where available.
 379 dnl
 380
 381 AC_ARG_ENABLE(ipv6,
 382   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 383   [case "${enable_ipv6}" in
 384     no)
 385       AC_MSG_NOTICE([disabling IPv6 at user request])
 386       dnl Disable IPv6 checking
 387       ipv6=no
 388       ;;
 389     yes)
 390       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 391       ipv6=yes
 392       force_ipv6=yes
 393       ;;
 394     auto)
 395       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 396       ipv6=yes
 397       ;;
 398     *)
 399       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 400       ;;
 401     esac
 402   ], [
 403     dnl If nothing is specified, assume auto-detection.
 404     ipv6=yes
 405   ]
 406 )
 407
 408 if test "X$ipv6" = "Xyes"; then
 409   AC_CHECK_FUNCS(getaddrinfo, [], [
 410     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 411     ipv6=no
 412   ])
 413 fi
 414
 415 if test "X$ipv6" = "Xyes"; then
 416   PROTO_INET6([], [
 417     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 418     ipv6=no
 419   ])
 420 fi
 421
 422 if test "X$ipv6" = "Xyes"; then
 423   TYPE_STRUCT_SOCKADDR_IN6([],[
 424     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 425     ipv6=no
 426   ])
 427   if test "X$ipv6" = "Xyes"; then
 428     WGET_STRUCT_SOCKADDR_STORAGE
 429     MEMBER_SIN6_SCOPE_ID
 430   fi
 431 fi
 432
 433 if test "X$ipv6" = "Xyes"; then
 434   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 435   AC_MSG_NOTICE([Enabling support for IPv6.])
 436 elif test "x$force_ipv6" = "xyes"; then
 437   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 438 fi
 439
 440 dnl
 441 dnl Find makeinfo.  We used to provide support for Emacs processing
 442 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 443 dnl unavailable, but that broke with the addition of makeinfo-specific
 444 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 445 dnl build the Info documentation.
 446 dnl
 447
 448 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 449
 450 dnl
 451 dnl Find perl and pod2man
 452 dnl
 453
 454 AC_PATH_PROGS(PERL, [perl5 perl], no)
 455 AC_PATH_PROG(POD2MAN, pod2man, no)
 456
 457 if test "x${POD2MAN}" = xno; then
 458   COMMENT_IF_NO_POD2MAN="# "
 459 else
 460   COMMENT_IF_NO_POD2MAN=
 461 fi
 462 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 463
 464
 465 dnl
 466 dnl Check for IDN/IRIs
 467 dnl
 468
 469 AC_ARG_ENABLE(iri,
 470   AC_HELP_STRING([--disable-iri],[disable IDN/IRIs support]),
 471   [case "${enable_iri}" in
 472     no)
 473       dnl Disable IRIs checking
 474       AC_MSG_NOTICE([disabling IRIs at user request])
 475       iri=no
 476       ;;
 477     yes)
 478       dnl IRIs explicitly enabled
 479       iri=yes
 480       force_iri=yes
 481       ;;
 482     auto)
 483       dnl Auto-detect IRI
 484       iri=yes
 485       ;;
 486     *)
 487       AC_MSG_ERROR([Invalid --enable-iri argument \`$enable_iri'])
 488       ;;
 489     esac
 490   ], [
 491     dnl If nothing is specified, assume auto-detection
 492     iri=yes
 493   ]
 494 )
 495
 496 AC_ARG_WITH(libidn, AC_HELP_STRING([--with-libidn=[DIR]],
 497                                    [Support IDN/IRIs (needs GNU Libidn)]),
 498                                    libidn=$withval, libidn="")
 499 AS_IF([test "X$iri" != "Xno"],[
 500   AM_ICONV
 501
 502   if test "X$am_cv_func_iconv" != "Xyes"; then
 503     iri=no
 504     if test "X$force_iri" = "Xyes"; then
 505       AC_MSG_ERROR([Libiconv is required for IRIs support])
 506     else
 507       AC_MSG_NOTICE([disabling IRIs because libiconv wasn't found])
 508     fi
 509   fi
 510 ],[  # else
 511   # For some reason, this seems to be set even when we don't check.
 512   # Explicitly unset.
 513   LIBICONV=
 514 ])
 515
 516 if test "X$iri" != "Xno"; then
 517   if test "$libidn" != ""; then
 518     LDFLAGS="${LDFLAGS} -L$libidn/lib"
 519     CPPFLAGS="${CPPFLAGS} -I$libidn/include"
 520   fi
 521
 522   # If idna.h can't be found, check to see if it was installed under
 523   # /usr/include/idn (OpenSolaris, at least, places it there).
 524   # Check for idn-int.h in that case, because idna.h won't find
 525   # idn-int.h until we've decided to add -I/usr/include/idn.
 526   AC_CHECK_HEADER(idna.h, ,
 527     [AC_CHECK_HEADER(idn/idn-int.h,
 528                     [CPPFLAGS="${CPPFLAGS} -I/usr/include/idn"],
 529                     [iri=no])]
 530   )
 531
 532   if test "X$iri" != "Xno"; then
 533     AC_CHECK_LIB(idn, stringprep_check_version,
 534       [iri=yes LIBS="${LIBS} -lidn"], iri=no)
 535   fi
 536
 537   if test "X$iri" != "Xno" ; then
 538     AC_DEFINE([ENABLE_IRI], 1, [Define if IRI support is enabled.])
 539     AC_MSG_NOTICE([Enabling support for IRI.])
 540   else
 541     AC_MSG_WARN([Libidn not found])
 542   fi
 543 fi
 544
 545
 546 dnl Needed by src/Makefile.am
 547 AM_CONDITIONAL([IRI_IS_ENABLED], [test "X$iri" != "Xno"])
 548
 549
 550 dnl
 551 dnl Create output
 552 dnl
 553 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 554                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 555                  lib/Makefile md5/Makefile windows/Makefile])
 556 AC_CONFIG_HEADERS([src/config.h])
 557 AC_OUTPUT