sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007, 2008, 2009 Free Software
   3 dnl Foundation, Inc.
   4
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl Additional permission under GNU GPL version 3 section 7
  19
  20 dnl If you modify this program, or any covered work, by linking or
  21 dnl combining it with the OpenSSL project's OpenSSL library (or a
  22 dnl modified version of that library), containing parts covered by the
  23 dnl terms of the OpenSSL or SSLeay licenses, the Free Software Foundation
  24 dnl grants you additional permission to convey the resulting work.
  25 dnl Corresponding Source for a non-source form of such a combination
  26 dnl shall include the source code for the parts of OpenSSL used as well
  27 dnl as that of the covered work.
  28
  29 dnl
  30 dnl Process this file with autoconf to produce a configure script.
  31 dnl
  32
  33 AC_INIT([wget],
  34         [1.12.1-devel],
  35         [bug-wget@gnu.org])
  36 AC_PREREQ(2.61)
  37
  38 dnl
  39 dnl What version of Wget are we building?
  40 dnl
  41 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  42
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_AUX_DIR([build-aux])
  45
  46 dnl
  47 dnl Automake setup
  48 dnl
  49 AM_INIT_AUTOMAKE(dist-bzip2 dist-lzma 1.9)
  50
  51 dnl
  52 dnl Get cannonical host
  53 dnl
  54 AC_CANONICAL_HOST
  55 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  56                    [Define to be the name of the operating system.])
  57
  58 dnl
  59 dnl Process features.
  60 dnl
  61
  62 AC_ARG_WITH(ssl,
  63 [[  --without-ssl           disable SSL autodetection]])
  64
  65 AC_ARG_ENABLE(opie,
  66 [  --disable-opie          disable support for opie or s/key FTP login],
  67 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  68 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  69    [Define if you want the Opie support for FTP compiled in.])
  70
  71 AC_ARG_ENABLE(digest,
  72 [  --disable-digest        disable support for HTTP digest authorization],
  73 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  74 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  75    [Define if you want the HTTP Digest Authorization compiled in.])
  76
  77 AC_ARG_ENABLE(ntlm,
  78 [  --disable-ntlm          disable support for NTLM authorization],
  79 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  80
  81 AC_ARG_ENABLE(debug,
  82 [  --disable-debug         disable support for debugging output],
  83 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  84 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  85    [Define if you want the debug output support compiled in.])
  86
  87 wget_need_md5=no
  88
  89 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  90 *yes*)
  91         wget_need_md5=yes
  92 esac
  93
  94 dnl
  95 dnl Find the compiler
  96 dnl
  97
  98 dnl We want these before the checks, so the checks can modify their values.
  99 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 100 test -z "$CC" && cc_specified=yes
 101
 102 AC_PROG_CC
 103 AM_PROG_CC_C_O
 104 AC_AIX
 105
 106 gl_EARLY
 107 md5_EARLY
 108
 109 dnl
 110 dnl Gettext
 111 dnl
 112 AM_GNU_GETTEXT([external],[need-ngettext])
 113 AM_GNU_GETTEXT_VERSION([0.17])
 114
 115 AC_PROG_RANLIB
 116
 117 AC_PROG_LEX
 118
 119 dnl Turn on optimization by default.  Specifically:
 120 dnl
 121 dnl if the user hasn't specified CFLAGS, then
 122 dnl   if compiler is gcc, then
 123 dnl     use -O2 and some warning flags
 124 dnl   else
 125 dnl     use os-specific flags or -O
 126 if test -n "$auto_cflags"; then
 127   if test -n "$GCC"; then
 128     CFLAGS="$CFLAGS -O2 -Wall"
 129   else
 130     case "$host_os" in
 131       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 132       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 133       *)       CFLAGS="$CFLAGS -O" ;;
 134     esac
 135   fi
 136 fi
 137
 138 dnl
 139 dnl Checks for basic compiler characteristics.
 140 dnl
 141 AC_C_CONST
 142 AC_C_INLINE
 143 AC_C_VOLATILE
 144
 145 dnl Check for basic headers, even though we expect them to exist and
 146 dnl #include them unconditionally in the code.  Their detection is
 147 dnl still needed because test programs used by Autoconf macros check
 148 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 149 dnl Without the checks they will fail to be included in test programs,
 150 dnl which will subsequently fail.
 151 AC_HEADER_STDC
 152
 153 dnl Check for large file support.  This check needs to come fairly
 154 dnl early because it could (in principle) affect whether functions and
 155 dnl headers are available, whether they work, etc.
 156 AC_SYS_LARGEFILE
 157 AC_CHECK_SIZEOF(off_t)
 158
 159 dnl
 160 dnl Checks for system header files that might be missing.
 161 dnl
 162 AC_HEADER_STDBOOL
 163 AC_CHECK_HEADERS(unistd.h sys/time.h)
 164 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 165 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h wchar.h)
 166
 167 AC_CHECK_DECLS(h_errno,,,[#include <netdb.h>])
 168
 169 dnl
 170 dnl Check sizes of integer types.  These are used to find n-bit
 171 dnl integral types on older systems that fail to provide intN_t and
 172 dnl uintN_t typedefs.
 173 dnl
 174 AC_CHECK_SIZEOF(short)
 175 AC_CHECK_SIZEOF(int)
 176 AC_CHECK_SIZEOF(long)
 177 AC_CHECK_SIZEOF(long long)
 178 AC_CHECK_SIZEOF(void *)
 179
 180 dnl
 181 dnl Checks for non-universal or system-specific types.
 182 dnl
 183 AC_TYPE_SIZE_T
 184 AC_TYPE_PID_T
 185 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 186 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 187 #include <stdio.h>
 188 #include <sys/types.h>
 189 #if HAVE_INTTYPES_H
 190 # include <inttypes.h>
 191 #endif
 192 #include <signal.h>
 193 ])
 194
 195 # gnulib
 196 gl_INIT
 197
 198 dnl
 199 dnl Checks for library functions.
 200 dnl
 201 AC_FUNC_MMAP
 202 AC_FUNC_FSEEKO
 203 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 204 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr wcwidth mbtowc)
 205 AC_CHECK_FUNCS(sleep symlink)
 206
 207 if test x"$ENABLE_OPIE" = xyes; then
 208   AC_LIBOBJ([ftp-opie])
 209 fi
 210
 211 dnl We expect to have these functions on Unix-like systems configure
 212 dnl runs on.  The defines are provided to get them in config.h.in so
 213 dnl Wget can still be ported to non-Unix systems (such as Windows)
 214 dnl that lack some of these functions.
 215 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 216 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 217 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 218 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 219
 220 dnl
 221 dnl Call Wget-specific macros defined in aclocal.
 222 dnl
 223 WGET_STRUCT_UTIMBUF
 224 WGET_SOCKLEN_T
 225 WGET_FNMATCH
 226 WGET_NANOSLEEP
 227 WGET_POSIX_CLOCK
 228 WGET_NSL_SOCKET
 229
 230 dnl Deal with specific hosts
 231 case $host_os in
 232   *mingw32* )
 233     AC_SUBST(W32LIBS, '-lwsock32')
 234     AC_LIBOBJ([mswindows])
 235     ;;
 236 esac
 237
 238 dnl
 239 dnl Checks for libraries.
 240 dnl
 241
 242 AS_IF([test x"$with_ssl" = xgnutls], [
 243   dnl Now actually check for -lssl
 244   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 245 #include <gnutls/gnutls.h>
 246   ], [gnutls_global_init()])
 247   if test x"$LIBGNUTLS" != x
 248   then
 249     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 250     AC_LIBOBJ([gnutls])
 251   else
 252     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 253   fi
 254 ], [
 255   # --with-ssl is not gnutls: check if it's no
 256   AS_IF([test x"$with_ssl" != xno], [
 257     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 258     dnl doesn't record its dependency on libdl, so we need to make sure
 259     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 260     dnl dlopen(), but HP-UX uses shl_load().
 261     AC_CHECK_LIB(dl, dlopen, [], [
 262       AC_CHECK_LIB(dl, shl_load)
 263     ])
 264
 265     dnl Now actually check for -lssl
 266     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 267   #include <openssl/ssl.h>
 268   #include <openssl/x509.h>
 269   #include <openssl/err.h>
 270   #include <openssl/rand.h>
 271   #include <openssl/des.h>
 272   #include <openssl/md4.h>
 273   #include <openssl/md5.h>
 274     ], [SSL_library_init ()])
 275     if test x"$LIBSSL" != x
 276     then
 277       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 278       AC_LIBOBJ([openssl])
 279     elif test x"$with_ssl" != x
 280     then
 281       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 282     fi
 283   ]) # endif: --with-ssl == no?
 284 ]) # endif: --with-ssl == gnutls?
 285
 286
 287 dnl Enable NTLM if requested and if SSL is available.
 288 if test x"$LIBSSL" != x
 289 then
 290   if test x"$ENABLE_NTLM" != xno
 291   then
 292     AC_DEFINE([ENABLE_NTLM], 1,
 293      [Define if you want the NTLM authorization support compiled in.])
 294     AC_LIBOBJ([http-ntlm])
 295   fi
 296 else
 297   dnl If SSL is unavailable and the user explicitly requested NTLM,
 298   dnl abort.
 299   if test x"$ENABLE_NTLM" = xyes
 300   then
 301     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 302   fi
 303 fi
 304
 305 dnl
 306 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 307 dnl to use an existing library implementation to save on code size.
 308 dnl
 309
 310 if test x"$wget_need_md5" = xyes
 311 then
 312   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 313   dnl manipulate MD5_OBJ from the defun.
 314
 315   AC_LIBOBJ([gen-md5])
 316   found_md5=no
 317
 318   dnl Check for the system MD5 library on Solaris.  We don't check for
 319   dnl something simple like "MD5Update" because there are a number of
 320   dnl MD5 implementations that use that name, but have an otherwise
 321   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 322   dnl Solaris MD5 library.
 323   if test x"$found_md5" = xno; then
 324     AC_CHECK_LIB(md5, md5_calc, [
 325       dnl Some installations have bogus <md5.h> in the compiler's
 326       dnl include path, making the system md5 library useless.
 327       AC_MSG_CHECKING([for working md5.h])
 328       AC_COMPILE_IFELSE([#include <md5.h>
 329                         ], [
 330         AC_MSG_RESULT(yes)
 331         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 332         LIBS="-lmd5 $LIBS"
 333         found_md5=yes
 334         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 335       ], [AC_MSG_RESULT(no)])
 336     ])
 337   fi
 338
 339   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 340   dnl implementation.
 341   if test x"$found_md5" = xno; then
 342     if test x"$LIBSSL" != x; then
 343       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 344       found_md5=yes
 345       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 346     fi
 347   fi
 348
 349   dnl If none of the above worked, use the one we ship with Wget.
 350   if test x"$found_md5" = xno; then
 351     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 352     found_md5=yes
 353     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 354     AC_C_BIGENDIAN
 355
 356     AC_SUBST(MD5_CPPFLAGS, '-I $(top_srcdir)/md5')
 357     AC_SUBST(MD5_LDADD, '../md5/libmd5.a')
 358     AC_SUBST(MD5_SUBDIR, md5)
 359     md5_INIT
 360   fi
 361   AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 362 fi
 363
 364 dnl **********************************************************************
 365 dnl Checks for IPv6
 366 dnl **********************************************************************
 367
 368 dnl
 369 dnl We test for IPv6 by checking, in turn, for availability of
 370 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 371 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 372 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 373 dnl
 374 dnl If --enable-ipv6 is explicitly specified on the configure command
 375 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 376 dnl is specified, we disable IPv6 and don't check for it.  The default
 377 dnl is to autodetect IPv6 and use it where available.
 378 dnl
 379
 380 AC_ARG_ENABLE(ipv6,
 381   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 382   [case "${enable_ipv6}" in
 383     no)
 384       AC_MSG_NOTICE([disabling IPv6 at user request])
 385       dnl Disable IPv6 checking
 386       ipv6=no
 387       ;;
 388     yes)
 389       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 390       ipv6=yes
 391       force_ipv6=yes
 392       ;;
 393     auto)
 394       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 395       ipv6=yes
 396       ;;
 397     *)
 398       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 399       ;;
 400     esac
 401   ], [
 402     dnl If nothing is specified, assume auto-detection.
 403     ipv6=yes
 404   ]
 405 )
 406
 407 if test "X$ipv6" = "Xyes"; then
 408   AC_CHECK_FUNCS(getaddrinfo, [], [
 409     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 410     ipv6=no
 411   ])
 412 fi
 413
 414 if test "X$ipv6" = "Xyes"; then
 415   PROTO_INET6([], [
 416     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 417     ipv6=no
 418   ])
 419 fi
 420
 421 if test "X$ipv6" = "Xyes"; then
 422   TYPE_STRUCT_SOCKADDR_IN6([],[
 423     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 424     ipv6=no
 425   ])
 426   if test "X$ipv6" = "Xyes"; then
 427     WGET_STRUCT_SOCKADDR_STORAGE
 428     MEMBER_SIN6_SCOPE_ID
 429   fi
 430 fi
 431
 432 if test "X$ipv6" = "Xyes"; then
 433   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 434   AC_MSG_NOTICE([Enabling support for IPv6.])
 435 elif test "x$force_ipv6" = "xyes"; then
 436   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 437 fi
 438
 439
 440 dnl
 441 dnl Set of available languages.
 442 dnl
 443 dnl Originally this used to be static, looking like this:
 444 dnl     ALL_LINGUAS="cs de hr it ..."
 445 dnl The downside was that configure needed to be rebuilt whenever a
 446 dnl new language was added.
 447 dnl
 448 ALL_LINGUAS="en@quot en@boldquot en_US $(cd ${srcdir}/po && ls *.po | grep -v 'en@.*quot' | grep -v 'en_US\.po' | sed -e 's/\.po$//' | tr '\012' ' ')"
 449
 450 dnl
 451 dnl Find makeinfo.  We used to provide support for Emacs processing
 452 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 453 dnl unavailable, but that broke with the addition of makeinfo-specific
 454 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 455 dnl build the Info documentation.
 456 dnl
 457
 458 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 459
 460 dnl
 461 dnl Find perl and pod2man
 462 dnl
 463
 464 AC_PATH_PROGS(PERL, [perl5 perl], no)
 465 AC_PATH_PROG(POD2MAN, pod2man, no)
 466
 467 if test "x${POD2MAN}" = xno; then
 468   COMMENT_IF_NO_POD2MAN="# "
 469 else
 470   COMMENT_IF_NO_POD2MAN=
 471 fi
 472 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 473
 474
 475 dnl
 476 dnl Check for IDN/IRIs
 477 dnl
 478
 479 AC_ARG_ENABLE(iri,
 480   AC_HELP_STRING([--disable-iri],[disable IDN/IRIs support]),
 481   [case "${enable_iri}" in
 482     no)
 483       dnl Disable IRIs checking
 484       AC_MSG_NOTICE([disabling IRIs at user request])
 485       iri=no
 486       ;;
 487     yes)
 488       dnl IRIs explicitly enabled
 489       iri=yes
 490       force_iri=yes
 491       ;;
 492     auto)
 493       dnl Auto-detect IRI
 494       iri=yes
 495       ;;
 496     *)
 497       AC_MSG_ERROR([Invalid --enable-iri argument \`$enable_iri'])
 498       ;;
 499     esac
 500   ], [
 501     dnl If nothing is specified, assume auto-detection
 502     iri=yes
 503   ]
 504 )
 505
 506 AC_ARG_WITH(libidn, AC_HELP_STRING([--with-libidn=[DIR]],
 507                                    [Support IDN/IRIs (needs GNU Libidn)]),
 508                                    libidn=$withval, libidn="")
 509 AS_IF([test "X$iri" != "Xno"],[
 510   AM_ICONV
 511
 512   if test "X$am_cv_func_iconv" != "Xyes"; then
 513     iri=no
 514     if test "X$force_iri" = "Xyes"; then
 515       AC_MSG_ERROR([Libiconv is required for IRIs support])
 516     else
 517       AC_MSG_NOTICE([disabling IRIs because libiconv wasn't found])
 518     fi
 519   fi
 520 ],[  # else
 521   # For some reason, this seems to be set even when we don't check.
 522   # Explicitly unset.
 523   LIBICONV=
 524 ])
 525
 526 if test "X$iri" != "Xno"; then
 527   if test "$libidn" != ""; then
 528     LDFLAGS="${LDFLAGS} -L$libidn/lib"
 529     CPPFLAGS="${CPPFLAGS} -I$libidn/include"
 530   fi
 531
 532   # If idna.h can't be found, check to see if it was installed under
 533   # /usr/include/idn (OpenSolaris, at least, places it there).
 534   # Check for idn-int.h in that case, because idna.h won't find
 535   # idn-int.h until we've decided to add -I/usr/include/idn.
 536   AC_CHECK_HEADER(idna.h, ,
 537     [AC_CHECK_HEADER(idn/idn-int.h,
 538                     [CPPFLAGS="${CPPFLAGS} -I/usr/include/idn"],
 539                     [iri=no])]
 540   )
 541
 542   if test "X$iri" != "Xno"; then
 543     AC_CHECK_LIB(idn, stringprep_check_version,
 544       [iri=yes LIBS="${LIBS} -lidn"], iri=no)
 545   fi
 546
 547   if test "X$iri" != "Xno" ; then
 548     AC_DEFINE([ENABLE_IRI], 1, [Define if IRI support is enabled.])
 549     AC_MSG_NOTICE([Enabling support for IRI.])
 550   else
 551     AC_MSG_WARN([Libidn not found])
 552   fi
 553 fi
 554
 555
 556 dnl Needed by src/Makefile.am
 557 AM_CONDITIONAL([IRI_IS_ENABLED], [test "X$iri" != "Xno"])
 558
 559
 560 dnl
 561 dnl Create output
 562 dnl
 563 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 564                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 565                  lib/Makefile md5/Makefile windows/Makefile])
 566 AC_CONFIG_HEADERS([src/config.h])
 567 AC_OUTPUT