sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007, 2008, 2009, 2010 Free
   3 dnl Software Foundation, Inc.
   4
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl Additional permission under GNU GPL version 3 section 7
  19
  20 dnl If you modify this program, or any covered work, by linking or
  21 dnl combining it with the OpenSSL project's OpenSSL library (or a
  22 dnl modified version of that library), containing parts covered by the
  23 dnl terms of the OpenSSL or SSLeay licenses, the Free Software Foundation
  24 dnl grants you additional permission to convey the resulting work.
  25 dnl Corresponding Source for a non-source form of such a combination
  26 dnl shall include the source code for the parts of OpenSSL used as well
  27 dnl as that of the covered work.
  28
  29 dnl
  30 dnl Process this file with autoconf to produce a configure script.
  31 dnl
  32
  33 AC_INIT([wget],
  34   [m4_esyscmd([build-aux/bzr-version-gen])],
  35         [bug-wget@gnu.org])
  36 AC_PREREQ(2.61)
  37
  38 dnl
  39 dnl What version of Wget are we building?
  40 dnl
  41 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  42
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_AUX_DIR([build-aux])
  45
  46 AC_CONFIG_SRCDIR([src/wget.h])
  47
  48 dnl
  49 dnl Automake setup
  50 dnl
  51 AM_INIT_AUTOMAKE(dist-bzip2 dist-lzma 1.9)
  52
  53 dnl
  54 dnl Get cannonical host
  55 dnl
  56 AC_CANONICAL_HOST
  57 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  58                    [Define to be the name of the operating system.])
  59
  60 dnl
  61 dnl Process features.
  62 dnl
  63
  64 AC_ARG_WITH(ssl,
  65 [[  --without-ssl           disable SSL autodetection]])
  66
  67 AC_ARG_ENABLE(opie,
  68 [  --disable-opie          disable support for opie or s/key FTP login],
  69 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  70 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  71    [Define if you want the Opie support for FTP compiled in.])
  72
  73 AC_ARG_ENABLE(digest,
  74 [  --disable-digest        disable support for HTTP digest authorization],
  75 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  76 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  77    [Define if you want the HTTP Digest Authorization compiled in.])
  78
  79 AC_ARG_ENABLE(ntlm,
  80 [  --disable-ntlm          disable support for NTLM authorization],
  81 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  82
  83 AC_ARG_ENABLE(debug,
  84 [  --disable-debug         disable support for debugging output],
  85 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  86 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  87    [Define if you want the debug output support compiled in.])
  88
  89 dnl
  90 dnl Find the compiler
  91 dnl
  92
  93 dnl We want these before the checks, so the checks can modify their values.
  94 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
  95 test -z "$CC" && cc_specified=yes
  96
  97 AC_PROG_CC
  98 AM_PROG_CC_C_O
  99 AC_AIX
 100
 101 gl_EARLY
 102
 103 dnl
 104 dnl Gettext
 105 dnl
 106 AM_GNU_GETTEXT([external],[need-ngettext])
 107 AM_GNU_GETTEXT_VERSION([0.17])
 108
 109 AC_PROG_RANLIB
 110
 111 AC_PROG_LEX
 112
 113 dnl Turn on optimization by default.  Specifically:
 114 dnl
 115 dnl if the user hasn't specified CFLAGS, then
 116 dnl   if compiler is gcc, then
 117 dnl     use -O2 and some warning flags
 118 dnl   else
 119 dnl     use os-specific flags or -O
 120 if test -n "$auto_cflags"; then
 121   if test -n "$GCC"; then
 122     CFLAGS="$CFLAGS -O2 -Wall"
 123   else
 124     case "$host_os" in
 125       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 126       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 127       *)       CFLAGS="$CFLAGS -O" ;;
 128     esac
 129   fi
 130 fi
 131
 132 dnl
 133 dnl Checks for basic compiler characteristics.
 134 dnl
 135 AC_C_CONST
 136 AC_C_INLINE
 137 AC_C_VOLATILE
 138
 139 dnl Check for basic headers, even though we expect them to exist and
 140 dnl #include them unconditionally in the code.  Their detection is
 141 dnl still needed because test programs used by Autoconf macros check
 142 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 143 dnl Without the checks they will fail to be included in test programs,
 144 dnl which will subsequently fail.
 145 AC_HEADER_STDC
 146
 147 dnl Check for large file support.  This check needs to come fairly
 148 dnl early because it could (in principle) affect whether functions and
 149 dnl headers are available, whether they work, etc.
 150 AC_SYS_LARGEFILE
 151 AC_CHECK_SIZEOF(off_t)
 152
 153 dnl
 154 dnl Checks for system header files that might be missing.
 155 dnl
 156 AC_HEADER_STDBOOL
 157 AC_CHECK_HEADERS(unistd.h sys/time.h)
 158 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 159 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h wchar.h)
 160
 161 AC_CHECK_DECLS(h_errno,,,[#include <netdb.h>])
 162
 163 dnl
 164 dnl Check sizes of integer types.  These are used to find n-bit
 165 dnl integral types on older systems that fail to provide intN_t and
 166 dnl uintN_t typedefs.
 167 dnl
 168 AC_CHECK_SIZEOF(short)
 169 AC_CHECK_SIZEOF(int)
 170 AC_CHECK_SIZEOF(long)
 171 AC_CHECK_SIZEOF(long long)
 172 AC_CHECK_SIZEOF(void *)
 173
 174 dnl
 175 dnl Checks for non-universal or system-specific types.
 176 dnl
 177 AC_TYPE_SIZE_T
 178 AC_TYPE_PID_T
 179 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 180 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 181 #include <stdio.h>
 182 #include <sys/types.h>
 183 #if HAVE_INTTYPES_H
 184 # include <inttypes.h>
 185 #endif
 186 #include <signal.h>
 187 ])
 188
 189 # gnulib
 190 gl_INIT
 191
 192 dnl
 193 dnl Checks for library functions.
 194 dnl
 195 AC_FUNC_MMAP
 196 AC_FUNC_FSEEKO
 197 AC_CHECK_FUNCS(strptime timegm vsnprintf vasprintf drand48)
 198 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr wcwidth mbtowc)
 199 AC_CHECK_FUNCS(sleep symlink)
 200
 201 if test x"$ENABLE_OPIE" = xyes; then
 202   AC_LIBOBJ([ftp-opie])
 203 fi
 204
 205 dnl We expect to have these functions on Unix-like systems configure
 206 dnl runs on.  The defines are provided to get them in config.h.in so
 207 dnl Wget can still be ported to non-Unix systems (such as Windows)
 208 dnl that lack some of these functions.
 209 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 210 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 211 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 212 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 213
 214 dnl
 215 dnl Call Wget-specific macros defined in aclocal.
 216 dnl
 217 WGET_STRUCT_UTIMBUF
 218 WGET_FNMATCH
 219 WGET_NANOSLEEP
 220 WGET_POSIX_CLOCK
 221 WGET_NSL_SOCKET
 222
 223 dnl Deal with specific hosts
 224 case $host_os in
 225   *mingw32* )
 226     AC_SUBST(W32LIBS, '-lws2_32')
 227     AC_LIBOBJ([mswindows])
 228     ;;
 229 esac
 230
 231 dnl
 232 dnl Checks for libraries.
 233 dnl
 234
 235 AS_IF([test x"$with_ssl" = xgnutls], [
 236   dnl Now actually check for -lssl
 237   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 238 #include <gnutls/gnutls.h>
 239   ], [gnutls_global_init()])
 240   if test x"$LIBGNUTLS" != x
 241   then
 242     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 243     AC_LIBOBJ([gnutls])
 244   else
 245     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 246   fi
 247 ], [
 248   # --with-ssl is not gnutls: check if it's no
 249   AS_IF([test x"$with_ssl" != xno], [
 250     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 251     dnl doesn't record its dependency on libdl, so we need to make sure
 252     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 253     dnl dlopen(), but HP-UX uses shl_load().
 254     AC_CHECK_LIB(dl, dlopen, [], [
 255       AC_CHECK_LIB(dl, shl_load)
 256     ])
 257
 258     dnl Now actually check for -lssl
 259     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 260   #include <openssl/ssl.h>
 261   #include <openssl/x509.h>
 262   #include <openssl/err.h>
 263   #include <openssl/rand.h>
 264   #include <openssl/des.h>
 265   #include <openssl/md4.h>
 266   #include <openssl/md5.h>
 267     ], [SSL_library_init ()])
 268     if test x"$LIBSSL" != x
 269     then
 270       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 271       AC_LIBOBJ([openssl])
 272     elif test x"$with_ssl" != x
 273     then
 274       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 275     fi
 276   ]) # endif: --with-ssl == no?
 277 ]) # endif: --with-ssl == gnutls?
 278
 279
 280 dnl Enable NTLM if requested and if SSL is available.
 281 if test x"$LIBSSL" != x
 282 then
 283   if test x"$ENABLE_NTLM" != xno
 284   then
 285     AC_DEFINE([ENABLE_NTLM], 1,
 286      [Define if you want the NTLM authorization support compiled in.])
 287     AC_LIBOBJ([http-ntlm])
 288   fi
 289 else
 290   dnl If SSL is unavailable and the user explicitly requested NTLM,
 291   dnl abort.
 292   if test x"$ENABLE_NTLM" = xyes
 293   then
 294     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 295   fi
 296 fi
 297
 298 dnl **********************************************************************
 299 dnl Checks for IPv6
 300 dnl **********************************************************************
 301
 302 dnl
 303 dnl We test for IPv6 by checking, in turn, for availability of
 304 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 305 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 306 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 307 dnl
 308 dnl If --enable-ipv6 is explicitly specified on the configure command
 309 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 310 dnl is specified, we disable IPv6 and don't check for it.  The default
 311 dnl is to autodetect IPv6 and use it where available.
 312 dnl
 313
 314 AC_ARG_ENABLE(ipv6,
 315   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 316   [case "${enable_ipv6}" in
 317     no)
 318       AC_MSG_NOTICE([disabling IPv6 at user request])
 319       dnl Disable IPv6 checking
 320       ipv6=no
 321       ;;
 322     yes)
 323       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 324       ipv6=yes
 325       force_ipv6=yes
 326       ;;
 327     auto)
 328       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 329       ipv6=yes
 330       ;;
 331     *)
 332       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 333       ;;
 334     esac
 335   ], [
 336     dnl If nothing is specified, assume auto-detection.
 337     ipv6=yes
 338   ]
 339 )
 340
 341 if test "X$ipv6" = "Xyes"; then
 342   AC_CHECK_FUNCS(getaddrinfo, [], [
 343     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 344     ipv6=no
 345   ])
 346 fi
 347
 348 if test "X$ipv6" = "Xyes"; then
 349   PROTO_INET6([], [
 350     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 351     ipv6=no
 352   ])
 353 fi
 354
 355 if test "X$ipv6" = "Xyes"; then
 356   TYPE_STRUCT_SOCKADDR_IN6([],[
 357     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 358     ipv6=no
 359   ])
 360   if test "X$ipv6" = "Xyes"; then
 361     WGET_STRUCT_SOCKADDR_STORAGE
 362     MEMBER_SIN6_SCOPE_ID
 363   fi
 364 fi
 365
 366 if test "X$ipv6" = "Xyes"; then
 367   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 368   AC_MSG_NOTICE([Enabling support for IPv6.])
 369 elif test "x$force_ipv6" = "xyes"; then
 370   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 371 fi
 372
 373 dnl
 374 dnl Find makeinfo.  We used to provide support for Emacs processing
 375 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 376 dnl unavailable, but that broke with the addition of makeinfo-specific
 377 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 378 dnl build the Info documentation.
 379 dnl
 380
 381 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 382
 383 dnl
 384 dnl Find perl and pod2man
 385 dnl
 386
 387 AC_PATH_PROGS(PERL, [perl5 perl], no)
 388 AC_PATH_PROG(POD2MAN, pod2man, no)
 389
 390 if test "x${POD2MAN}" = xno; then
 391   COMMENT_IF_NO_POD2MAN="# "
 392 else
 393   COMMENT_IF_NO_POD2MAN=
 394 fi
 395 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 396
 397
 398 dnl
 399 dnl Check for IDN/IRIs
 400 dnl
 401
 402 AC_ARG_ENABLE(iri,
 403   AC_HELP_STRING([--disable-iri],[disable IDN/IRIs support]),
 404   [case "${enable_iri}" in
 405     no)
 406       dnl Disable IRIs checking
 407       AC_MSG_NOTICE([disabling IRIs at user request])
 408       iri=no
 409       ;;
 410     yes)
 411       dnl IRIs explicitly enabled
 412       iri=yes
 413       force_iri=yes
 414       ;;
 415     auto)
 416       dnl Auto-detect IRI
 417       iri=yes
 418       ;;
 419     *)
 420       AC_MSG_ERROR([Invalid --enable-iri argument \`$enable_iri'])
 421       ;;
 422     esac
 423   ], [
 424     dnl If nothing is specified, assume auto-detection
 425     iri=yes
 426   ]
 427 )
 428
 429 AC_ARG_WITH(libidn, AC_HELP_STRING([--with-libidn=[DIR]],
 430                                    [Support IDN/IRIs (needs GNU Libidn)]),
 431                                    libidn=$withval, libidn="")
 432 AS_IF([test "X$iri" != "Xno"],[
 433   AM_ICONV
 434
 435   if test "X$am_cv_func_iconv" != "Xyes"; then
 436     iri=no
 437     if test "X$force_iri" = "Xyes"; then
 438       AC_MSG_ERROR([Libiconv is required for IRIs support])
 439     else
 440       AC_MSG_NOTICE([disabling IRIs because libiconv wasn't found])
 441     fi
 442   fi
 443 ],[  # else
 444   # For some reason, this seems to be set even when we don't check.
 445   # Explicitly unset.
 446   LIBICONV=
 447 ])
 448
 449 if test "X$iri" != "Xno"; then
 450   if test "$libidn" != ""; then
 451     LDFLAGS="${LDFLAGS} -L$libidn/lib"
 452     CPPFLAGS="${CPPFLAGS} -I$libidn/include"
 453   fi
 454
 455   # If idna.h can't be found, check to see if it was installed under
 456   # /usr/include/idn (OpenSolaris, at least, places it there).
 457   # Check for idn-int.h in that case, because idna.h won't find
 458   # idn-int.h until we've decided to add -I/usr/include/idn.
 459   AC_CHECK_HEADER(idna.h, ,
 460     [AC_CHECK_HEADER(idn/idn-int.h,
 461                     [CPPFLAGS="${CPPFLAGS} -I/usr/include/idn"],
 462                     [iri=no])]
 463   )
 464
 465   if test "X$iri" != "Xno"; then
 466     AC_CHECK_LIB(idn, stringprep_check_version,
 467       [iri=yes LIBS="${LIBS} -lidn"], iri=no)
 468   fi
 469
 470   if test "X$iri" != "Xno" ; then
 471     AC_DEFINE([ENABLE_IRI], 1, [Define if IRI support is enabled.])
 472     AC_MSG_NOTICE([Enabling support for IRI.])
 473   else
 474     AC_MSG_WARN([Libidn not found])
 475   fi
 476 fi
 477
 478
 479 dnl Needed by src/Makefile.am
 480 AM_CONDITIONAL([IRI_IS_ENABLED], [test "X$iri" != "Xno"])
 481
 482
 483 dnl
 484 dnl Create output
 485 dnl
 486 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 487                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 488                  lib/Makefile windows/Makefile])
 489 AC_CONFIG_HEADERS([src/config.h])
 490 AC_OUTPUT