sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 3 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 dnl In addition, as a special exception, the Free Software Foundation
  18 dnl gives permission to link the code of its release of Wget with the
  19 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  20 dnl that use the same license as the "OpenSSL" library), and distribute
  21 dnl the linked executables.  You must obey the GNU General Public License
  22 dnl in all respects for all of the code used other than "OpenSSL".  If you
  23 dnl modify this file, you may extend this exception to your version of the
  24 dnl file, but you are not obligated to do so.  If you do not wish to do
  25 dnl so, delete this exception statement from your version.
  26
  27 dnl
  28 dnl Process this file with autoconf to produce a configure script.
  29 dnl
  30
  31 AC_INIT([wget],
  32         [1.12-devel],
  33         [bug-wget@gnu.org])
  34 AC_PREREQ(2.61)
  35
  36 dnl
  37 dnl What version of Wget are we building?
  38 dnl
  39 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_AUX_DIR([.])
  43
  44 dnl
  45 dnl Automake setup
  46 dnl
  47 AM_INIT_AUTOMAKE(1.9)
  48
  49 dnl
  50 dnl Gettext
  51 dnl
  52 AM_GNU_GETTEXT([external],[need-ngettext])
  53 AM_GNU_GETTEXT_VERSION([0.16.1])
  54
  55 dnl
  56 dnl Get cannonical host
  57 dnl
  58 AC_CANONICAL_HOST
  59 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  60                    [Define to be the name of the operating system.])
  61
  62 dnl
  63 dnl Process features.
  64 dnl
  65
  66 AC_ARG_WITH(ssl,
  67 [[  --without-ssl           disable SSL autodetection]])
  68
  69 AC_ARG_ENABLE(opie,
  70 [  --disable-opie          disable support for opie or s/key FTP login],
  71 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  72 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  73    [Define if you want the Opie support for FTP compiled in.])
  74
  75 AC_ARG_ENABLE(digest,
  76 [  --disable-digest        disable support for HTTP digest authorization],
  77 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  78 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  79    [Define if you want the HTTP Digest Authorization compiled in.])
  80
  81 AC_ARG_ENABLE(ntlm,
  82 [  --disable-ntlm          disable support for NTLM authorization],
  83 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  84
  85 AC_ARG_ENABLE(debug,
  86 [  --disable-debug         disable support for debugging output],
  87 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  88 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  89    [Define if you want the debug output support compiled in.])
  90
  91 wget_need_md5=no
  92
  93 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  94 *yes*)
  95         wget_need_md5=yes
  96 esac
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107 AM_PROG_CC_C_O
 108 AC_AIX
 109
 110 AC_PROG_RANLIB
 111
 112 dnl Turn on optimization by default.  Specifically:
 113 dnl
 114 dnl if the user hasn't specified CFLAGS, then
 115 dnl   if compiler is gcc, then
 116 dnl     use -O2 and some warning flags
 117 dnl   else
 118 dnl     use os-specific flags or -O
 119 if test -n "$auto_cflags"; then
 120   if test -n "$GCC"; then
 121     CFLAGS="$CFLAGS -O2 -Wall"
 122   else
 123     case "$host_os" in
 124       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 125       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 126       *)       CFLAGS="$CFLAGS -O" ;;
 127     esac
 128   fi
 129 fi
 130
 131 dnl
 132 dnl Checks for basic compiler characteristics.
 133 dnl
 134 AC_C_CONST
 135 AC_C_INLINE
 136 AC_C_VOLATILE
 137
 138 dnl Check for basic headers, even though we expect them to exist and
 139 dnl #include them unconditionally in the code.  Their detection is
 140 dnl still needed because test programs used by Autoconf macros check
 141 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 142 dnl Without the checks they will fail to be included in test programs,
 143 dnl which will subsequently fail.
 144 AC_HEADER_STDC
 145
 146 dnl Check for large file support.  This check needs to come fairly
 147 dnl early because it could (in principle) affect whether functions and
 148 dnl headers are available, whether they work, etc.
 149 AC_SYS_LARGEFILE
 150 AC_CHECK_SIZEOF(off_t)
 151
 152 dnl
 153 dnl Checks for system header files that might be missing.
 154 dnl
 155 AC_HEADER_STDBOOL
 156 AC_CHECK_HEADERS(unistd.h sys/time.h)
 157 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 158 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h)
 159
 160 dnl
 161 dnl Check sizes of integer types.  These are used to find n-bit
 162 dnl integral types on older systems that fail to provide intN_t and
 163 dnl uintN_t typedefs.
 164 dnl
 165 AC_CHECK_SIZEOF(short)
 166 AC_CHECK_SIZEOF(int)
 167 AC_CHECK_SIZEOF(long)
 168 AC_CHECK_SIZEOF(long long)
 169 AC_CHECK_SIZEOF(void *)
 170
 171 dnl
 172 dnl Checks for non-universal or system-specific types.
 173 dnl
 174 AC_TYPE_SIZE_T
 175 AC_TYPE_PID_T
 176 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 177 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 178 #include <stdio.h>
 179 #include <sys/types.h>
 180 #if HAVE_INTTYPES_H
 181 # include <inttypes.h>
 182 #endif
 183 #include <signal.h>
 184 ])
 185
 186 dnl
 187 dnl Checks for library functions.
 188 dnl
 189 AC_FUNC_ALLOCA
 190 AC_FUNC_MMAP
 191 AC_FUNC_FSEEKO
 192 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 193 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr)
 194
 195 if test x"$ENABLE_OPIE" = xyes; then
 196   AC_LIBOBJ([ftp-opie])
 197 fi
 198
 199 dnl We expect to have these functions on Unix-like systems configure
 200 dnl runs on.  The defines are provided to get them in config.h.in so
 201 dnl Wget can still be ported to non-Unix systems (such as Windows)
 202 dnl that lack some of these functions.
 203 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 204 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 205 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 206 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 207 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 208
 209 dnl
 210 dnl Call Wget-specific macros defined in aclocal.
 211 dnl
 212 WGET_STRUCT_UTIMBUF
 213 WGET_SOCKLEN_T
 214 WGET_FNMATCH
 215 WGET_NANOSLEEP
 216 WGET_POSIX_CLOCK
 217 WGET_NSL_SOCKET
 218
 219 dnl
 220 dnl Check if we need to compile in getopt.c.
 221 dnl
 222 AC_CHECK_FUNC(getopt_long, [], [
 223   AC_LIBOBJ([getopt])
 224 ])
 225
 226 dnl
 227 dnl Checks for libraries.
 228 dnl
 229
 230 AS_IF([test x"$with_ssl" = xgnutls], [
 231   dnl Now actually check for -lssl
 232   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 233 #include <gnutls/gnutls.h>
 234   ], [gnutls_global_init()])
 235   if test x"$LIBGNUTLS" != x
 236   then
 237     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 238     AC_LIBOBJ([gnutls])
 239   else
 240     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 241   fi
 242 ], [
 243   # --with-ssl is not gnutls: check if it's no
 244   AS_IF([test x"$with_ssl" != xno], [
 245     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 246     dnl doesn't record its dependency on libdl, so we need to make sure
 247     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 248     dnl dlopen(), but HP-UX uses shl_load().
 249     AC_CHECK_LIB(dl, dlopen, [], [
 250       AC_CHECK_LIB(dl, shl_load)
 251     ])
 252
 253     dnl Now actually check for -lssl
 254     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 255   #include <openssl/ssl.h>
 256   #include <openssl/x509.h>
 257   #include <openssl/err.h>
 258   #include <openssl/rand.h>
 259   #include <openssl/des.h>
 260   #include <openssl/md4.h>
 261   #include <openssl/md5.h>
 262     ], [SSL_library_init ()])
 263     if test x"$LIBSSL" != x
 264     then
 265       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 266       AC_LIBOBJ([openssl])
 267     elif test x"$with_ssl" != x
 268     then
 269       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 270     fi
 271   ]) # endif: --with-ssl == no?
 272 ]) # endif: --with-ssl == gnutls?
 273
 274
 275 dnl Enable NTLM if requested and if SSL is available.
 276 if test x"$LIBSSL" != x
 277 then
 278   if test x"$ENABLE_NTLM" != xno
 279   then
 280     AC_DEFINE([ENABLE_NTLM], 1,
 281      [Define if you want the NTLM authorization support compiled in.])
 282     AC_LIBOBJ([http-ntlm])
 283   fi
 284 else
 285   dnl If SSL is unavailable and the user explicitly requested NTLM,
 286   dnl abort.
 287   if test x"$ENABLE_NTLM" = xyes
 288   then
 289     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 290   fi
 291 fi
 292
 293 dnl
 294 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 295 dnl to use an existing library implementation to save on code size.
 296 dnl
 297
 298 if test x"$wget_need_md5" = xyes
 299 then
 300   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 301   dnl manipulate MD5_OBJ from the defun.
 302
 303   AC_LIBOBJ([gen-md5])
 304   found_md5=no
 305
 306   dnl Check for the system MD5 library on Solaris.  We don't check for
 307   dnl something simple like "MD5Update" because there are a number of
 308   dnl MD5 implementations that use that name, but have an otherwise
 309   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 310   dnl Solaris MD5 library.
 311   if test x"$found_md5" = xno; then
 312     AC_CHECK_LIB(md5, md5_calc, [
 313       dnl Some installations have bogus <md5.h> in the compiler's
 314       dnl include path, making the system md5 library useless.
 315       AC_MSG_CHECKING([for working md5.h])
 316       AC_COMPILE_IFELSE([#include <md5.h>
 317                         ], [
 318         AC_MSG_RESULT(yes)
 319         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 320         LIBS="-lmd5 $LIBS"
 321         found_md5=yes
 322         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 323       ], [AC_MSG_RESULT(no)])
 324     ])
 325   fi
 326
 327   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 328   dnl implementation.
 329   if test x"$found_md5" = xno; then
 330     if test x"$LIBSSL" != x; then
 331       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 332       found_md5=yes
 333       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 334     fi
 335   fi
 336
 337   dnl If none of the above worked, use the one we ship with Wget.
 338   if test x"$found_md5" = xno; then
 339     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 340     AC_LIBOBJ([gnu-md5])
 341     found_md5=yes
 342     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 343     AC_C_BIGENDIAN
 344   fi
 345 fi
 346 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 347
 348 dnl **********************************************************************
 349 dnl Checks for IPv6
 350 dnl **********************************************************************
 351
 352 dnl
 353 dnl We test for IPv6 by checking, in turn, for availability of
 354 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 355 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 356 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 357 dnl
 358 dnl If --enable-ipv6 is explicitly specified on the configure command
 359 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 360 dnl is specified, we disable IPv6 and don't check for it.  The default
 361 dnl is to autodetect IPv6 and use it where available.
 362 dnl
 363
 364 AC_ARG_ENABLE(ipv6,
 365   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 366   [case "${enable_ipv6}" in
 367     no)
 368       AC_MSG_NOTICE([disabling IPv6 at user request])
 369       dnl Disable IPv6 checking
 370       ipv6=no
 371       ;;
 372     yes)
 373       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 374       ipv6=yes
 375       force_ipv6=yes
 376       ;;
 377     auto)
 378       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 379       ipv6=yes
 380       ;;
 381     *)
 382       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 383       ;;
 384     esac
 385   ], [
 386     dnl If nothing is specified, assume auto-detection.
 387     ipv6=yes
 388   ]
 389 )
 390
 391 if test "X$ipv6" = "Xyes"; then
 392   AC_CHECK_FUNCS(getaddrinfo, [], [
 393     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 394     ipv6=no
 395   ])
 396 fi
 397
 398 if test "X$ipv6" = "Xyes"; then
 399   PROTO_INET6([], [
 400     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 401     ipv6=no
 402   ])
 403 fi
 404
 405 if test "X$ipv6" = "Xyes"; then
 406   TYPE_STRUCT_SOCKADDR_IN6([],[
 407     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 408     ipv6=no
 409   ])
 410   if test "X$ipv6" = "Xyes"; then
 411     WGET_STRUCT_SOCKADDR_STORAGE
 412     MEMBER_SIN6_SCOPE_ID
 413   fi
 414 fi
 415
 416 if test "X$ipv6" = "Xyes"; then
 417   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 418   AC_MSG_NOTICE([Enabling support for IPv6.])
 419 elif test "x$force_ipv6" = "xyes"; then
 420   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 421 fi
 422
 423
 424 dnl
 425 dnl Set of available languages.
 426 dnl
 427 dnl Originally this used to be static, looking like this:
 428 dnl     ALL_LINGUAS="cs de hr it ..."
 429 dnl The downside was that configure needed to be rebuilt whenever a
 430 dnl new language was added.
 431 dnl
 432 ALL_LINGUAS="en@quot en@boldquot $(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')"
 433
 434 dnl
 435 dnl Find makeinfo.  We used to provide support for Emacs processing
 436 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 437 dnl unavailable, but that broke with the addition of makeinfo-specific
 438 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 439 dnl build the Info documentation.
 440 dnl
 441
 442 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 443
 444 dnl
 445 dnl Find perl and pod2man
 446 dnl
 447
 448 AC_PATH_PROGS(PERL, [perl5 perl], no)
 449 AC_PATH_PROG(POD2MAN, pod2man, no)
 450
 451 if test "x${POD2MAN}" = xno; then
 452   COMMENT_IF_NO_POD2MAN="# "
 453 else
 454   COMMENT_IF_NO_POD2MAN=
 455 fi
 456 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 457
 458 dnl
 459 dnl Create output
 460 dnl
 461 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 462                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 463                  windows/Makefile])
 464 AC_CONFIG_HEADERS([src/config.h])
 465 AH_BOTTOM([
 466 #include "config-post.h"
 467 ])
 468 AC_OUTPUT