sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 3 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 dnl In addition, as a special exception, the Free Software Foundation
  18 dnl gives permission to link the code of its release of Wget with the
  19 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  20 dnl that use the same license as the "OpenSSL" library), and distribute
  21 dnl the linked executables.  You must obey the GNU General Public License
  22 dnl in all respects for all of the code used other than "OpenSSL".  If you
  23 dnl modify this file, you may extend this exception to your version of the
  24 dnl file, but you are not obligated to do so.  If you do not wish to do
  25 dnl so, delete this exception statement from your version.
  26
  27 dnl
  28 dnl Process this file with autoconf to produce a configure script.
  29 dnl
  30
  31 AC_INIT([wget],
  32         [1.12-devel],
  33         [bug-wget@gnu.org])
  34 AC_PREREQ(2.61)
  35
  36 dnl
  37 dnl What version of Wget are we building?
  38 dnl
  39 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_AUX_DIR([.])
  43
  44 dnl
  45 dnl Automake setup
  46 dnl
  47 AM_INIT_AUTOMAKE(1.9)
  48
  49 dnl
  50 dnl Gettext
  51 dnl
  52 AM_GNU_GETTEXT([external],[need-ngettext])
  53 AM_GNU_GETTEXT_VERSION([0.16.1])
  54
  55 dnl
  56 dnl Get cannonical host
  57 dnl
  58 AC_CANONICAL_HOST
  59 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  60                    [Define to be the name of the operating system.])
  61
  62 dnl
  63 dnl Process features.
  64 dnl
  65
  66 AC_ARG_WITH(ssl,
  67 [[  --without-ssl           disable SSL autodetection]])
  68
  69 AC_ARG_ENABLE(opie,
  70 [  --disable-opie          disable support for opie or s/key FTP login],
  71 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  72 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  73    [Define if you want the Opie support for FTP compiled in.])
  74
  75 AC_ARG_ENABLE(digest,
  76 [  --disable-digest        disable support for HTTP digest authorization],
  77 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  78 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  79    [Define if you want the HTTP Digest Authorization compiled in.])
  80
  81 AC_ARG_ENABLE(ntlm,
  82 [  --disable-ntlm          disable support for NTLM authorization],
  83 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  84
  85 AC_ARG_ENABLE(debug,
  86 [  --disable-debug         disable support for debugging output],
  87 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  88 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  89    [Define if you want the debug output support compiled in.])
  90
  91 wget_need_md5=no
  92
  93 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  94 *yes*)
  95         wget_need_md5=yes
  96 esac
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107 AM_PROG_CC_C_O
 108 AC_AIX
 109 gl_EARLY
 110
 111 AC_PROG_RANLIB
 112
 113 dnl Turn on optimization by default.  Specifically:
 114 dnl
 115 dnl if the user hasn't specified CFLAGS, then
 116 dnl   if compiler is gcc, then
 117 dnl     use -O2 and some warning flags
 118 dnl   else
 119 dnl     use os-specific flags or -O
 120 if test -n "$auto_cflags"; then
 121   if test -n "$GCC"; then
 122     CFLAGS="$CFLAGS -O2 -Wall"
 123   else
 124     case "$host_os" in
 125       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 126       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 127       *)       CFLAGS="$CFLAGS -O" ;;
 128     esac
 129   fi
 130 fi
 131
 132 dnl
 133 dnl Checks for basic compiler characteristics.
 134 dnl
 135 AC_C_CONST
 136 AC_C_INLINE
 137 AC_C_VOLATILE
 138
 139 dnl Check for basic headers, even though we expect them to exist and
 140 dnl #include them unconditionally in the code.  Their detection is
 141 dnl still needed because test programs used by Autoconf macros check
 142 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 143 dnl Without the checks they will fail to be included in test programs,
 144 dnl which will subsequently fail.
 145 AC_HEADER_STDC
 146
 147 dnl Check for large file support.  This check needs to come fairly
 148 dnl early because it could (in principle) affect whether functions and
 149 dnl headers are available, whether they work, etc.
 150 AC_SYS_LARGEFILE
 151 AC_CHECK_SIZEOF(off_t)
 152
 153 dnl
 154 dnl Checks for system header files that might be missing.
 155 dnl
 156 AC_HEADER_STDBOOL
 157 AC_CHECK_HEADERS(unistd.h sys/time.h)
 158 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 159 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h)
 160
 161 dnl
 162 dnl Check sizes of integer types.  These are used to find n-bit
 163 dnl integral types on older systems that fail to provide intN_t and
 164 dnl uintN_t typedefs.
 165 dnl
 166 AC_CHECK_SIZEOF(short)
 167 AC_CHECK_SIZEOF(int)
 168 AC_CHECK_SIZEOF(long)
 169 AC_CHECK_SIZEOF(long long)
 170 AC_CHECK_SIZEOF(void *)
 171
 172 dnl
 173 dnl Checks for non-universal or system-specific types.
 174 dnl
 175 AC_TYPE_SIZE_T
 176 AC_TYPE_PID_T
 177 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 178 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 179 #include <stdio.h>
 180 #include <sys/types.h>
 181 #if HAVE_INTTYPES_H
 182 # include <inttypes.h>
 183 #endif
 184 #include <signal.h>
 185 ])
 186
 187 # gnulib
 188 gl_INIT
 189
 190 dnl
 191 dnl Checks for library functions.
 192 dnl
 193 AC_FUNC_ALLOCA
 194 AC_FUNC_MMAP
 195 AC_FUNC_FSEEKO
 196 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 197 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr)
 198
 199 if test x"$ENABLE_OPIE" = xyes; then
 200   AC_LIBOBJ([ftp-opie])
 201 fi
 202
 203 dnl We expect to have these functions on Unix-like systems configure
 204 dnl runs on.  The defines are provided to get them in config.h.in so
 205 dnl Wget can still be ported to non-Unix systems (such as Windows)
 206 dnl that lack some of these functions.
 207 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 208 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 209 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 210 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 211 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 212
 213 dnl
 214 dnl Call Wget-specific macros defined in aclocal.
 215 dnl
 216 WGET_STRUCT_UTIMBUF
 217 WGET_SOCKLEN_T
 218 WGET_FNMATCH
 219 WGET_NANOSLEEP
 220 WGET_POSIX_CLOCK
 221 WGET_NSL_SOCKET
 222
 223 dnl
 224 dnl Checks for libraries.
 225 dnl
 226
 227 AS_IF([test x"$with_ssl" = xgnutls], [
 228   dnl Now actually check for -lssl
 229   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 230 #include <gnutls/gnutls.h>
 231   ], [gnutls_global_init()])
 232   if test x"$LIBGNUTLS" != x
 233   then
 234     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 235     AC_LIBOBJ([gnutls])
 236   else
 237     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 238   fi
 239 ], [
 240   # --with-ssl is not gnutls: check if it's no
 241   AS_IF([test x"$with_ssl" != xno], [
 242     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 243     dnl doesn't record its dependency on libdl, so we need to make sure
 244     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 245     dnl dlopen(), but HP-UX uses shl_load().
 246     AC_CHECK_LIB(dl, dlopen, [], [
 247       AC_CHECK_LIB(dl, shl_load)
 248     ])
 249
 250     dnl Now actually check for -lssl
 251     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 252   #include <openssl/ssl.h>
 253   #include <openssl/x509.h>
 254   #include <openssl/err.h>
 255   #include <openssl/rand.h>
 256   #include <openssl/des.h>
 257   #include <openssl/md4.h>
 258   #include <openssl/md5.h>
 259     ], [SSL_library_init ()])
 260     if test x"$LIBSSL" != x
 261     then
 262       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 263       AC_LIBOBJ([openssl])
 264     elif test x"$with_ssl" != x
 265     then
 266       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 267     fi
 268   ]) # endif: --with-ssl == no?
 269 ]) # endif: --with-ssl == gnutls?
 270
 271
 272 dnl Enable NTLM if requested and if SSL is available.
 273 if test x"$LIBSSL" != x
 274 then
 275   if test x"$ENABLE_NTLM" != xno
 276   then
 277     AC_DEFINE([ENABLE_NTLM], 1,
 278      [Define if you want the NTLM authorization support compiled in.])
 279     AC_LIBOBJ([http-ntlm])
 280   fi
 281 else
 282   dnl If SSL is unavailable and the user explicitly requested NTLM,
 283   dnl abort.
 284   if test x"$ENABLE_NTLM" = xyes
 285   then
 286     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 287   fi
 288 fi
 289
 290 dnl
 291 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 292 dnl to use an existing library implementation to save on code size.
 293 dnl
 294
 295 if test x"$wget_need_md5" = xyes
 296 then
 297   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 298   dnl manipulate MD5_OBJ from the defun.
 299
 300   AC_LIBOBJ([gen-md5])
 301   found_md5=no
 302
 303   dnl Check for the system MD5 library on Solaris.  We don't check for
 304   dnl something simple like "MD5Update" because there are a number of
 305   dnl MD5 implementations that use that name, but have an otherwise
 306   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 307   dnl Solaris MD5 library.
 308   if test x"$found_md5" = xno; then
 309     AC_CHECK_LIB(md5, md5_calc, [
 310       dnl Some installations have bogus <md5.h> in the compiler's
 311       dnl include path, making the system md5 library useless.
 312       AC_MSG_CHECKING([for working md5.h])
 313       AC_COMPILE_IFELSE([#include <md5.h>
 314                         ], [
 315         AC_MSG_RESULT(yes)
 316         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 317         LIBS="-lmd5 $LIBS"
 318         found_md5=yes
 319         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 320       ], [AC_MSG_RESULT(no)])
 321     ])
 322   fi
 323
 324   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 325   dnl implementation.
 326   if test x"$found_md5" = xno; then
 327     if test x"$LIBSSL" != x; then
 328       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 329       found_md5=yes
 330       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 331     fi
 332   fi
 333
 334   dnl If none of the above worked, use the one we ship with Wget.
 335   if test x"$found_md5" = xno; then
 336     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 337     found_md5=yes
 338     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 339     AC_C_BIGENDIAN
 340   fi
 341 fi
 342 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 343
 344 dnl **********************************************************************
 345 dnl Checks for IPv6
 346 dnl **********************************************************************
 347
 348 dnl
 349 dnl We test for IPv6 by checking, in turn, for availability of
 350 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 351 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 352 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 353 dnl
 354 dnl If --enable-ipv6 is explicitly specified on the configure command
 355 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 356 dnl is specified, we disable IPv6 and don't check for it.  The default
 357 dnl is to autodetect IPv6 and use it where available.
 358 dnl
 359
 360 AC_ARG_ENABLE(ipv6,
 361   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 362   [case "${enable_ipv6}" in
 363     no)
 364       AC_MSG_NOTICE([disabling IPv6 at user request])
 365       dnl Disable IPv6 checking
 366       ipv6=no
 367       ;;
 368     yes)
 369       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 370       ipv6=yes
 371       force_ipv6=yes
 372       ;;
 373     auto)
 374       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 375       ipv6=yes
 376       ;;
 377     *)
 378       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 379       ;;
 380     esac
 381   ], [
 382     dnl If nothing is specified, assume auto-detection.
 383     ipv6=yes
 384   ]
 385 )
 386
 387 if test "X$ipv6" = "Xyes"; then
 388   AC_CHECK_FUNCS(getaddrinfo, [], [
 389     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 390     ipv6=no
 391   ])
 392 fi
 393
 394 if test "X$ipv6" = "Xyes"; then
 395   PROTO_INET6([], [
 396     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 397     ipv6=no
 398   ])
 399 fi
 400
 401 if test "X$ipv6" = "Xyes"; then
 402   TYPE_STRUCT_SOCKADDR_IN6([],[
 403     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 404     ipv6=no
 405   ])
 406   if test "X$ipv6" = "Xyes"; then
 407     WGET_STRUCT_SOCKADDR_STORAGE
 408     MEMBER_SIN6_SCOPE_ID
 409   fi
 410 fi
 411
 412 if test "X$ipv6" = "Xyes"; then
 413   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 414   AC_MSG_NOTICE([Enabling support for IPv6.])
 415 elif test "x$force_ipv6" = "xyes"; then
 416   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 417 fi
 418
 419
 420 dnl
 421 dnl Set of available languages.
 422 dnl
 423 dnl Originally this used to be static, looking like this:
 424 dnl     ALL_LINGUAS="cs de hr it ..."
 425 dnl The downside was that configure needed to be rebuilt whenever a
 426 dnl new language was added.
 427 dnl
 428 ALL_LINGUAS="en@quot en@boldquot $(cd ${srcdir}/po && ls *.po | grep -v 'en@.*quot' | sed -e 's/\.po$//' | tr '\012' ' ')"
 429
 430 dnl
 431 dnl Find makeinfo.  We used to provide support for Emacs processing
 432 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 433 dnl unavailable, but that broke with the addition of makeinfo-specific
 434 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 435 dnl build the Info documentation.
 436 dnl
 437
 438 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 439
 440 dnl
 441 dnl Find perl and pod2man
 442 dnl
 443
 444 AC_PATH_PROGS(PERL, [perl5 perl], no)
 445 AC_PATH_PROG(POD2MAN, pod2man, no)
 446
 447 if test "x${POD2MAN}" = xno; then
 448   COMMENT_IF_NO_POD2MAN="# "
 449 else
 450   COMMENT_IF_NO_POD2MAN=
 451 fi
 452 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 453
 454 dnl
 455 dnl Create output
 456 dnl
 457 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 458                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 459                  lib/Makefile windows/Makefile])
 460 AC_CONFIG_HEADERS([src/config.h])
 461 AC_OUTPUT