sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007, 2008, 2009, 2010, 2011
   3 dnl Free Software Foundation, Inc.
   4
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl Additional permission under GNU GPL version 3 section 7
  19
  20 dnl If you modify this program, or any covered work, by linking or
  21 dnl combining it with the OpenSSL project's OpenSSL library (or a
  22 dnl modified version of that library), containing parts covered by the
  23 dnl terms of the OpenSSL or SSLeay licenses, the Free Software Foundation
  24 dnl grants you additional permission to convey the resulting work.
  25 dnl Corresponding Source for a non-source form of such a combination
  26 dnl shall include the source code for the parts of OpenSSL used as well
  27 dnl as that of the covered work.
  28
  29 dnl
  30 dnl Process this file with autoconf to produce a configure script.
  31 dnl
  32
  33 AC_INIT([wget],
  34   [m4_esyscmd([build-aux/bzr-version-gen])],
  35         [bug-wget@gnu.org])
  36 AC_PREREQ(2.61)
  37
  38 dnl
  39 dnl What version of Wget are we building?
  40 dnl
  41 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  42
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_AUX_DIR([build-aux])
  45
  46 AC_CONFIG_SRCDIR([src/wget.h])
  47
  48 dnl
  49 dnl Automake setup
  50 dnl
  51 AM_INIT_AUTOMAKE([1.9])
  52
  53 dnl
  54 dnl Get cannonical host
  55 dnl
  56 AC_CANONICAL_HOST
  57 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  58                    [Define to be the name of the operating system.])
  59
  60 dnl
  61 dnl Process features.
  62 dnl
  63
  64 AC_ARG_WITH(ssl,
  65 [[  --without-ssl           disable SSL autodetection
  66   --with-ssl={gnutls,openssl} specify the SSL backend.  GNU TLS is the default.]])
  67
  68 AC_ARG_ENABLE(opie,
  69 [  --disable-opie          disable support for opie or s/key FTP login],
  70 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  71 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  72    [Define if you want the Opie support for FTP compiled in.])
  73
  74 AC_ARG_ENABLE(digest,
  75 [  --disable-digest        disable support for HTTP digest authorization],
  76 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  77 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  78    [Define if you want the HTTP Digest Authorization compiled in.])
  79
  80 AC_ARG_ENABLE(ntlm,
  81 [  --disable-ntlm          disable support for NTLM authorization],
  82 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  83
  84 AC_ARG_ENABLE(debug,
  85 [  --disable-debug         disable support for debugging output],
  86 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  87 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  88    [Define if you want the debug output support compiled in.])
  89
  90 dnl
  91 dnl Find the compiler
  92 dnl
  93
  94 dnl We want these before the checks, so the checks can modify their values.
  95 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
  96 test -z "$CC" && cc_specified=yes
  97
  98 AC_PROG_CC
  99 AM_PROG_CC_C_O
 100 AC_AIX
 101
 102 gl_EARLY
 103
 104 dnl
 105 dnl Gettext
 106 dnl
 107 AM_GNU_GETTEXT([external],[need-ngettext])
 108 AM_GNU_GETTEXT_VERSION([0.17])
 109
 110 AC_PROG_RANLIB
 111
 112 AC_PROG_LEX
 113
 114 dnl Turn on optimization by default.  Specifically:
 115 dnl
 116 dnl if the user hasn't specified CFLAGS, then
 117 dnl   if compiler is gcc, then
 118 dnl     use -O2 and some warning flags
 119 dnl   else
 120 dnl     use os-specific flags or -O
 121 if test -n "$auto_cflags"; then
 122   if test -n "$GCC"; then
 123     CFLAGS="$CFLAGS -O2 -Wall"
 124   else
 125     case "$host_os" in
 126       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 127       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 128       *)       CFLAGS="$CFLAGS -O" ;;
 129     esac
 130   fi
 131 fi
 132
 133 dnl
 134 dnl Checks for basic compiler characteristics.
 135 dnl
 136 AC_C_CONST
 137 AC_C_INLINE
 138 AC_C_VOLATILE
 139
 140 dnl Check for basic headers, even though we expect them to exist and
 141 dnl #include them unconditionally in the code.  Their detection is
 142 dnl still needed because test programs used by Autoconf macros check
 143 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 144 dnl Without the checks they will fail to be included in test programs,
 145 dnl which will subsequently fail.
 146 AC_HEADER_STDC
 147
 148 dnl Check for large file support.  This check needs to come fairly
 149 dnl early because it could (in principle) affect whether functions and
 150 dnl headers are available, whether they work, etc.
 151 AC_SYS_LARGEFILE
 152 AC_CHECK_SIZEOF(off_t)
 153
 154 dnl
 155 dnl Checks for system header files that might be missing.
 156 dnl
 157 AC_HEADER_STDBOOL
 158 AC_CHECK_HEADERS(unistd.h sys/time.h)
 159 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 160 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h wchar.h)
 161
 162 AC_CHECK_DECLS(h_errno,,,[#include <netdb.h>])
 163
 164 dnl
 165 dnl Check sizes of integer types.  These are used to find n-bit
 166 dnl integral types on older systems that fail to provide intN_t and
 167 dnl uintN_t typedefs.
 168 dnl
 169 AC_CHECK_SIZEOF([short])
 170 AC_CHECK_SIZEOF([int])
 171 AC_CHECK_SIZEOF([long])
 172 AC_CHECK_SIZEOF([long long])
 173 AC_CHECK_SIZEOF([void *])
 174
 175 dnl
 176 dnl Checks for non-universal or system-specific types.
 177 dnl
 178 AC_TYPE_SIZE_T
 179 AC_TYPE_PID_T
 180 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 181 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 182 #include <stdio.h>
 183 #include <sys/types.h>
 184 #if HAVE_INTTYPES_H
 185 # include <inttypes.h>
 186 #endif
 187 #include <signal.h>
 188 ])
 189
 190 # gnulib
 191 gl_INIT
 192
 193 dnl
 194 dnl Checks for library functions.
 195 dnl
 196 AC_FUNC_MMAP
 197 AC_FUNC_FSEEKO
 198 AC_CHECK_FUNCS(strptime timegm vsnprintf vasprintf drand48)
 199 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr wcwidth mbtowc)
 200 AC_CHECK_FUNCS(sleep symlink utime)
 201
 202 if test x"$ENABLE_OPIE" = xyes; then
 203   AC_LIBOBJ([ftp-opie])
 204 fi
 205
 206 dnl We expect to have these functions on Unix-like systems configure
 207 dnl runs on.  The defines are provided to get them in config.h.in so
 208 dnl Wget can still be ported to non-Unix systems (such as Windows)
 209 dnl that lack some of these functions.
 210 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 211 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 212 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 213 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 214
 215 dnl
 216 dnl Call Wget-specific macros defined in aclocal.
 217 dnl
 218 WGET_STRUCT_UTIMBUF
 219 WGET_FNMATCH
 220 WGET_NANOSLEEP
 221 WGET_POSIX_CLOCK
 222 WGET_NSL_SOCKET
 223
 224 dnl Deal with specific hosts
 225 case $host_os in
 226   *mingw32* )
 227     LIBS+=' -lws2_32'
 228     AC_LIBOBJ([mswindows])
 229     ;;
 230 esac
 231
 232
 233 dnl
 234 dnl Checks for libraries.
 235 dnl
 236
 237 AS_IF([test x"$with_ssl" = xopenssl], [
 238     dnl some versions of openssl use zlib compression
 239     AC_CHECK_LIB(z, compress)
 240
 241     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 242     dnl doesn't record its dependency on libdl, so we need to make sure
 243     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 244     dnl dlopen(), but HP-UX uses shl_load().
 245     AC_CHECK_LIB(dl, dlopen, [], [
 246       AC_CHECK_LIB(dl, shl_load)
 247     ])
 248
 249     case $host_os in
 250       *mingw32* )
 251         dnl prefer link to openssl dlls if possible. if not then fallback on static libs. if not then error
 252
 253         AC_CHECK_LIB(eay32, EVP_MD_CTX_init)
 254         if test x"$ac_cv_lib_eay32_EVP_MD_CTX_init" != xno
 255         then
 256           AC_CHECK_LIB(ssl32, SSL_connect,,
 257                     AC_MSG_ERROR([openssl not found: shared lib eay32 found but ssl32 not found]))
 258           AC_MSG_NOTICE([Enabling support for SSL via OpenSSL (shared)])
 259
 260         else
 261           LIBS+=' -lgdi32'
 262           dnl fallback and test static libs
 263         fi
 264         dnl add zdll lib as dep for above tests?
 265       ;;
 266     esac
 267
 268     dnl Now actually check for -lssl
 269     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 270   #include <openssl/ssl.h>
 271   #include <openssl/x509.h>
 272   #include <openssl/err.h>
 273   #include <openssl/rand.h>
 274   #include <openssl/des.h>
 275   #include <openssl/md4.h>
 276   #include <openssl/md5.h>
 277     ], [SSL_library_init ()])
 278     if test x"$LIBSSL" != x
 279     then
 280       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 281       AC_LIBOBJ([openssl])
 282       LIBS="$LIBSSL $LIBS"
 283     elif test x"$with_ssl" != x
 284     then
 285       AC_MSG_ERROR([--with-ssl=openssl was given, but SSL is not available.])
 286     fi
 287
 288     AC_LIBOBJ([openssl])
 289 ], [
 290   # --with-ssl is not gnutls: check if it's no
 291   AS_IF([test x"$with_ssl" != xno], [
 292     dnl Now actually check for -lssl
 293
 294     AC_CHECK_LIB(z, compress)
 295     AC_CHECK_LIB(gpg-error, gpg_err_init)
 296     AC_CHECK_LIB(gcrypt, gcry_control)
 297
 298   dnl Now actually check for -lssl
 299   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 300 #include <gnutls/gnutls.h>
 301   ], [gnutls_global_init()])
 302   if test x"$LIBGNUTLS" != x
 303   then
 304     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 305     AC_LIBOBJ([gnutls])
 306     LIBS="$LIBGNUTLS $LIBS"
 307   else
 308     AC_MSG_ERROR([--with-ssl was given, but GNUTLS is not available.])
 309   fi
 310
 311   AC_CHECK_FUNCS(gnutls_priority_set_direct)
 312   ]) # endif: --with-ssl == no?
 313 ]) # endif: --with-ssl == openssl?
 314
 315
 316 dnl Enable NTLM if requested and if SSL is available.
 317 if test x"$LIBSSL" != x
 318 then
 319   if test x"$ENABLE_NTLM" != xno
 320   then
 321     AC_DEFINE([ENABLE_NTLM], 1,
 322      [Define if you want the NTLM authorization support compiled in.])
 323     AC_LIBOBJ([http-ntlm])
 324   fi
 325 else
 326   dnl If SSL is unavailable and the user explicitly requested NTLM,
 327   dnl abort.
 328   if test x"$ENABLE_NTLM" = xyes
 329   then
 330     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 331   fi
 332 fi
 333
 334 dnl **********************************************************************
 335 dnl Checks for IPv6
 336 dnl **********************************************************************
 337
 338 dnl
 339 dnl We test for IPv6 by checking, in turn, for availability of
 340 dnl presence of the INET6 address/protocol family and the existence of
 341 dnl struct sockaddr_in6.  If any of them is missing, IPv6 is disabled,
 342 dnl and the code reverts to old-style gethostbyname.
 343 dnl
 344 dnl If --enable-ipv6 is explicitly specified on the configure command
 345 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 346 dnl is specified, we disable IPv6 and don't check for it.  The default
 347 dnl is to autodetect IPv6 and use it where available.
 348 dnl
 349
 350 AC_ARG_ENABLE(ipv6,
 351   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 352   [case "${enable_ipv6}" in
 353     no)
 354       AC_MSG_NOTICE([disabling IPv6 at user request])
 355       dnl Disable IPv6 checking
 356       ipv6=no
 357       ;;
 358     yes)
 359       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 360       ipv6=yes
 361       force_ipv6=yes
 362       ;;
 363     auto)
 364       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 365       ipv6=yes
 366       ;;
 367     *)
 368       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 369       ;;
 370     esac
 371   ], [
 372     dnl If nothing is specified, assume auto-detection.
 373     ipv6=yes
 374   ]
 375 )
 376
 377 if test "X$ipv6" = "Xyes"; then
 378   PROTO_INET6([], [
 379     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 380     ipv6=no
 381   ])
 382 fi
 383
 384 if test "X$ipv6" = "Xyes"; then
 385   TYPE_STRUCT_SOCKADDR_IN6([],[
 386     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 387     ipv6=no
 388   ])
 389   if test "X$ipv6" = "Xyes"; then
 390     WGET_STRUCT_SOCKADDR_STORAGE
 391     MEMBER_SIN6_SCOPE_ID
 392   fi
 393 fi
 394
 395 if test "X$ipv6" = "Xyes"; then
 396   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 397   AC_MSG_NOTICE([Enabling support for IPv6.])
 398 elif test "x$force_ipv6" = "xyes"; then
 399   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 400 fi
 401
 402 dnl
 403 dnl Find makeinfo.  We used to provide support for Emacs processing
 404 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 405 dnl unavailable, but that broke with the addition of makeinfo-specific
 406 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 407 dnl build the Info documentation.
 408 dnl
 409
 410 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 411
 412 dnl
 413 dnl Find perl and pod2man
 414 dnl
 415
 416 AC_PATH_PROGS(PERL, [perl5 perl], no)
 417 AC_PATH_PROG(POD2MAN, pod2man, no)
 418
 419 if test "x${POD2MAN}" = xno; then
 420   COMMENT_IF_NO_POD2MAN="# "
 421 else
 422   COMMENT_IF_NO_POD2MAN=
 423 fi
 424 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 425
 426
 427 dnl
 428 dnl Check for IDN/IRIs
 429 dnl
 430
 431 AC_ARG_ENABLE(iri,
 432   AC_HELP_STRING([--disable-iri],[disable IDN/IRIs support]),
 433   [case "${enable_iri}" in
 434     no)
 435       dnl Disable IRIs checking
 436       AC_MSG_NOTICE([disabling IRIs at user request])
 437       iri=no
 438       ;;
 439     yes)
 440       dnl IRIs explicitly enabled
 441       iri=yes
 442       force_iri=yes
 443       ;;
 444     auto)
 445       dnl Auto-detect IRI
 446       iri=yes
 447       ;;
 448     *)
 449       AC_MSG_ERROR([Invalid --enable-iri argument \`$enable_iri'])
 450       ;;
 451     esac
 452   ], [
 453     dnl If nothing is specified, assume auto-detection
 454     iri=yes
 455   ]
 456 )
 457
 458 AC_ARG_WITH(libidn, AC_HELP_STRING([--with-libidn=[DIR]],
 459                                    [Support IDN/IRIs (needs GNU Libidn)]),
 460                                    libidn=$withval, libidn="")
 461 AS_IF([test "X$iri" != "Xno"],[
 462   AM_ICONV
 463
 464   if test "X$am_cv_func_iconv" != "Xyes"; then
 465     iri=no
 466     if test "X$force_iri" = "Xyes"; then
 467       AC_MSG_ERROR([Libiconv is required for IRIs support])
 468     else
 469       AC_MSG_NOTICE([disabling IRIs because libiconv wasn't found])
 470     fi
 471   fi
 472 ],[  # else
 473   # For some reason, this seems to be set even when we don't check.
 474   # Explicitly unset.
 475   LIBICONV=
 476 ])
 477
 478 if test "X$iri" != "Xno"; then
 479   if test "$libidn" != ""; then
 480     LDFLAGS="${LDFLAGS} -L$libidn/lib"
 481     CPPFLAGS="${CPPFLAGS} -I$libidn/include"
 482   fi
 483
 484   # If idna.h can't be found, check to see if it was installed under
 485   # /usr/include/idn (OpenSolaris, at least, places it there).
 486   # Check for idn-int.h in that case, because idna.h won't find
 487   # idn-int.h until we've decided to add -I/usr/include/idn.
 488   AC_CHECK_HEADER(idna.h, ,
 489     [AC_CHECK_HEADER(idn/idn-int.h,
 490                     [CPPFLAGS="${CPPFLAGS} -I/usr/include/idn"],
 491                     [iri=no])]
 492   )
 493
 494   if test "X$iri" != "Xno"; then
 495     AC_CHECK_LIB(idn, stringprep_check_version,
 496       [iri=yes LIBS="${LIBS} -lidn"], iri=no)
 497   fi
 498
 499   if test "X$iri" != "Xno" ; then
 500     AC_DEFINE([ENABLE_IRI], 1, [Define if IRI support is enabled.])
 501     AC_MSG_NOTICE([Enabling support for IRI.])
 502   else
 503     AC_MSG_WARN([Libidn not found])
 504   fi
 505 fi
 506
 507
 508 dnl Needed by src/Makefile.am
 509 AM_CONDITIONAL([IRI_IS_ENABLED], [test "X$iri" != "Xno"])
 510
 511
 512 dnl
 513 dnl Create output
 514 dnl
 515 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 516                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 517                  lib/Makefile])
 518 AC_CONFIG_HEADERS([src/config.h])
 519 AC_OUTPUT