sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007,
   3 dnl 2008 Free Software Foundation, Inc.
   4
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl Additional permission under GNU GPL version 3 section 7
  19
  20 dnl If you modify this program, or any covered work, by linking or
  21 dnl combining it with the OpenSSL project's OpenSSL library (or a
  22 dnl modified version of that library), containing parts covered by the
  23 dnl terms of the OpenSSL or SSLeay licenses, the Free Software Foundation
  24 dnl grants you additional permission to convey the resulting work.
  25 dnl Corresponding Source for a non-source form of such a combination
  26 dnl shall include the source code for the parts of OpenSSL used as well
  27 dnl as that of the covered work.
  28
  29 dnl
  30 dnl Process this file with autoconf to produce a configure script.
  31 dnl
  32
  33 AC_INIT([wget],
  34         [1.12-devel],
  35         [bug-wget@gnu.org])
  36 AC_PREREQ(2.61)
  37
  38 dnl
  39 dnl What version of Wget are we building?
  40 dnl
  41 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  42
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_AUX_DIR([.])
  45
  46 dnl
  47 dnl Automake setup
  48 dnl
  49 AM_INIT_AUTOMAKE(1.9)
  50
  51 dnl
  52 dnl Gettext
  53 dnl
  54 AM_GNU_GETTEXT([external],[need-ngettext])
  55 AM_GNU_GETTEXT_VERSION([0.16.1])
  56
  57 dnl
  58 dnl Get cannonical host
  59 dnl
  60 AC_CANONICAL_HOST
  61 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  62                    [Define to be the name of the operating system.])
  63
  64 dnl
  65 dnl Process features.
  66 dnl
  67
  68 AC_ARG_WITH(ssl,
  69 [[  --without-ssl           disable SSL autodetection]])
  70
  71 AC_ARG_ENABLE(opie,
  72 [  --disable-opie          disable support for opie or s/key FTP login],
  73 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  74 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  75    [Define if you want the Opie support for FTP compiled in.])
  76
  77 AC_ARG_ENABLE(digest,
  78 [  --disable-digest        disable support for HTTP digest authorization],
  79 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  80 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  81    [Define if you want the HTTP Digest Authorization compiled in.])
  82
  83 AC_ARG_ENABLE(ntlm,
  84 [  --disable-ntlm          disable support for NTLM authorization],
  85 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  86
  87 AC_ARG_ENABLE(debug,
  88 [  --disable-debug         disable support for debugging output],
  89 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  90 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  91    [Define if you want the debug output support compiled in.])
  92
  93 wget_need_md5=no
  94
  95 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  96 *yes*)
  97         wget_need_md5=yes
  98 esac
  99
 100 dnl
 101 dnl Find the compiler
 102 dnl
 103
 104 dnl We want these before the checks, so the checks can modify their values.
 105 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 106 test -z "$CC" && cc_specified=yes
 107
 108 AC_PROG_CC
 109 AM_PROG_CC_C_O
 110 AC_AIX
 111 gl_EARLY
 112 md5_EARLY
 113
 114 AC_PROG_RANLIB
 115
 116 AC_PROG_LEX
 117
 118 dnl Turn on optimization by default.  Specifically:
 119 dnl
 120 dnl if the user hasn't specified CFLAGS, then
 121 dnl   if compiler is gcc, then
 122 dnl     use -O2 and some warning flags
 123 dnl   else
 124 dnl     use os-specific flags or -O
 125 if test -n "$auto_cflags"; then
 126   if test -n "$GCC"; then
 127     CFLAGS="$CFLAGS -O2 -Wall"
 128   else
 129     case "$host_os" in
 130       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 131       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 132       *)       CFLAGS="$CFLAGS -O" ;;
 133     esac
 134   fi
 135 fi
 136
 137 dnl
 138 dnl Checks for basic compiler characteristics.
 139 dnl
 140 AC_C_CONST
 141 AC_C_INLINE
 142 AC_C_VOLATILE
 143
 144 dnl Check for basic headers, even though we expect them to exist and
 145 dnl #include them unconditionally in the code.  Their detection is
 146 dnl still needed because test programs used by Autoconf macros check
 147 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 148 dnl Without the checks they will fail to be included in test programs,
 149 dnl which will subsequently fail.
 150 AC_HEADER_STDC
 151
 152 dnl Check for large file support.  This check needs to come fairly
 153 dnl early because it could (in principle) affect whether functions and
 154 dnl headers are available, whether they work, etc.
 155 AC_SYS_LARGEFILE
 156 AC_CHECK_SIZEOF(off_t)
 157
 158 dnl
 159 dnl Checks for system header files that might be missing.
 160 dnl
 161 AC_HEADER_STDBOOL
 162 AC_CHECK_HEADERS(unistd.h sys/time.h)
 163 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 164 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h wchar.h)
 165
 166 dnl
 167 dnl Check sizes of integer types.  These are used to find n-bit
 168 dnl integral types on older systems that fail to provide intN_t and
 169 dnl uintN_t typedefs.
 170 dnl
 171 AC_CHECK_SIZEOF(short)
 172 AC_CHECK_SIZEOF(int)
 173 AC_CHECK_SIZEOF(long)
 174 AC_CHECK_SIZEOF(long long)
 175 AC_CHECK_SIZEOF(void *)
 176
 177 dnl
 178 dnl Checks for non-universal or system-specific types.
 179 dnl
 180 AC_TYPE_SIZE_T
 181 AC_TYPE_PID_T
 182 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 183 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 184 #include <stdio.h>
 185 #include <sys/types.h>
 186 #if HAVE_INTTYPES_H
 187 # include <inttypes.h>
 188 #endif
 189 #include <signal.h>
 190 ])
 191
 192 # gnulib
 193 gl_INIT
 194
 195 dnl
 196 dnl Checks for library functions.
 197 dnl
 198 AC_FUNC_MMAP
 199 AC_FUNC_FSEEKO
 200 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 201 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr wcwidth mbtowc)
 202
 203 if test x"$ENABLE_OPIE" = xyes; then
 204   AC_LIBOBJ([ftp-opie])
 205 fi
 206
 207 dnl We expect to have these functions on Unix-like systems configure
 208 dnl runs on.  The defines are provided to get them in config.h.in so
 209 dnl Wget can still be ported to non-Unix systems (such as Windows)
 210 dnl that lack some of these functions.
 211 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 212 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 213 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 214 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 215 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 216
 217 dnl
 218 dnl Call Wget-specific macros defined in aclocal.
 219 dnl
 220 WGET_STRUCT_UTIMBUF
 221 WGET_SOCKLEN_T
 222 WGET_FNMATCH
 223 WGET_NANOSLEEP
 224 WGET_POSIX_CLOCK
 225 WGET_NSL_SOCKET
 226
 227 dnl
 228 dnl Checks for libraries.
 229 dnl
 230
 231 AS_IF([test x"$with_ssl" = xgnutls], [
 232   dnl Now actually check for -lssl
 233   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 234 #include <gnutls/gnutls.h>
 235   ], [gnutls_global_init()])
 236   if test x"$LIBGNUTLS" != x
 237   then
 238     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 239     AC_LIBOBJ([gnutls])
 240   else
 241     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 242   fi
 243 ], [
 244   # --with-ssl is not gnutls: check if it's no
 245   AS_IF([test x"$with_ssl" != xno], [
 246     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 247     dnl doesn't record its dependency on libdl, so we need to make sure
 248     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 249     dnl dlopen(), but HP-UX uses shl_load().
 250     AC_CHECK_LIB(dl, dlopen, [], [
 251       AC_CHECK_LIB(dl, shl_load)
 252     ])
 253
 254     dnl Now actually check for -lssl
 255     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 256   #include <openssl/ssl.h>
 257   #include <openssl/x509.h>
 258   #include <openssl/err.h>
 259   #include <openssl/rand.h>
 260   #include <openssl/des.h>
 261   #include <openssl/md4.h>
 262   #include <openssl/md5.h>
 263     ], [SSL_library_init ()])
 264     if test x"$LIBSSL" != x
 265     then
 266       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 267       AC_LIBOBJ([openssl])
 268     elif test x"$with_ssl" != x
 269     then
 270       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 271     fi
 272   ]) # endif: --with-ssl == no?
 273 ]) # endif: --with-ssl == gnutls?
 274
 275
 276 dnl Enable NTLM if requested and if SSL is available.
 277 if test x"$LIBSSL" != x
 278 then
 279   if test x"$ENABLE_NTLM" != xno
 280   then
 281     AC_DEFINE([ENABLE_NTLM], 1,
 282      [Define if you want the NTLM authorization support compiled in.])
 283     AC_LIBOBJ([http-ntlm])
 284   fi
 285 else
 286   dnl If SSL is unavailable and the user explicitly requested NTLM,
 287   dnl abort.
 288   if test x"$ENABLE_NTLM" = xyes
 289   then
 290     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 291   fi
 292 fi
 293
 294 dnl
 295 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 296 dnl to use an existing library implementation to save on code size.
 297 dnl
 298
 299 if test x"$wget_need_md5" = xyes
 300 then
 301   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 302   dnl manipulate MD5_OBJ from the defun.
 303
 304   AC_LIBOBJ([gen-md5])
 305   found_md5=no
 306
 307   dnl Check for the system MD5 library on Solaris.  We don't check for
 308   dnl something simple like "MD5Update" because there are a number of
 309   dnl MD5 implementations that use that name, but have an otherwise
 310   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 311   dnl Solaris MD5 library.
 312   if test x"$found_md5" = xno; then
 313     AC_CHECK_LIB(md5, md5_calc, [
 314       dnl Some installations have bogus <md5.h> in the compiler's
 315       dnl include path, making the system md5 library useless.
 316       AC_MSG_CHECKING([for working md5.h])
 317       AC_COMPILE_IFELSE([#include <md5.h>
 318                         ], [
 319         AC_MSG_RESULT(yes)
 320         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 321         LIBS="-lmd5 $LIBS"
 322         found_md5=yes
 323         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 324       ], [AC_MSG_RESULT(no)])
 325     ])
 326   fi
 327
 328   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 329   dnl implementation.
 330   if test x"$found_md5" = xno; then
 331     if test x"$LIBSSL" != x; then
 332       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 333       found_md5=yes
 334       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 335     fi
 336   fi
 337
 338   dnl If none of the above worked, use the one we ship with Wget.
 339   if test x"$found_md5" = xno; then
 340     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 341     found_md5=yes
 342     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 343     AC_C_BIGENDIAN
 344
 345     AC_SUBST(MD5_CPPFLAGS, '-I $(top_srcdir)/md5')
 346     AC_SUBST(MD5_LDADD, '../md5/libmd5.a')
 347     AC_SUBST(MD5_SUBDIR, md5)
 348     md5_INIT
 349   fi
 350   AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 351 fi
 352
 353 dnl **********************************************************************
 354 dnl Checks for IPv6
 355 dnl **********************************************************************
 356
 357 dnl
 358 dnl We test for IPv6 by checking, in turn, for availability of
 359 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 360 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 361 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 362 dnl
 363 dnl If --enable-ipv6 is explicitly specified on the configure command
 364 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 365 dnl is specified, we disable IPv6 and don't check for it.  The default
 366 dnl is to autodetect IPv6 and use it where available.
 367 dnl
 368
 369 AC_ARG_ENABLE(ipv6,
 370   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 371   [case "${enable_ipv6}" in
 372     no)
 373       AC_MSG_NOTICE([disabling IPv6 at user request])
 374       dnl Disable IPv6 checking
 375       ipv6=no
 376       ;;
 377     yes)
 378       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 379       ipv6=yes
 380       force_ipv6=yes
 381       ;;
 382     auto)
 383       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 384       ipv6=yes
 385       ;;
 386     *)
 387       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 388       ;;
 389     esac
 390   ], [
 391     dnl If nothing is specified, assume auto-detection.
 392     ipv6=yes
 393   ]
 394 )
 395
 396 if test "X$ipv6" = "Xyes"; then
 397   AC_CHECK_FUNCS(getaddrinfo, [], [
 398     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 399     ipv6=no
 400   ])
 401 fi
 402
 403 if test "X$ipv6" = "Xyes"; then
 404   PROTO_INET6([], [
 405     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 406     ipv6=no
 407   ])
 408 fi
 409
 410 if test "X$ipv6" = "Xyes"; then
 411   TYPE_STRUCT_SOCKADDR_IN6([],[
 412     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 413     ipv6=no
 414   ])
 415   if test "X$ipv6" = "Xyes"; then
 416     WGET_STRUCT_SOCKADDR_STORAGE
 417     MEMBER_SIN6_SCOPE_ID
 418   fi
 419 fi
 420
 421 if test "X$ipv6" = "Xyes"; then
 422   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 423   AC_MSG_NOTICE([Enabling support for IPv6.])
 424 elif test "x$force_ipv6" = "xyes"; then
 425   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 426 fi
 427
 428
 429 dnl
 430 dnl Set of available languages.
 431 dnl
 432 dnl Originally this used to be static, looking like this:
 433 dnl     ALL_LINGUAS="cs de hr it ..."
 434 dnl The downside was that configure needed to be rebuilt whenever a
 435 dnl new language was added.
 436 dnl
 437 ALL_LINGUAS="en@quot en@boldquot en_US $(cd ${srcdir}/po && ls *.po | grep -v 'en@.*quot' | grep -v 'en_US\.po' | sed -e 's/\.po$//' | tr '\012' ' ')"
 438
 439 dnl
 440 dnl Find makeinfo.  We used to provide support for Emacs processing
 441 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 442 dnl unavailable, but that broke with the addition of makeinfo-specific
 443 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 444 dnl build the Info documentation.
 445 dnl
 446
 447 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 448
 449 dnl
 450 dnl Find perl and pod2man
 451 dnl
 452
 453 AC_PATH_PROGS(PERL, [perl5 perl], no)
 454 AC_PATH_PROG(POD2MAN, pod2man, no)
 455
 456 if test "x${POD2MAN}" = xno; then
 457   COMMENT_IF_NO_POD2MAN="# "
 458 else
 459   COMMENT_IF_NO_POD2MAN=
 460 fi
 461 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 462
 463
 464 dnl
 465 dnl Check for IDN/IRIs
 466 dnl
 467
 468 AC_ARG_ENABLE(iri,
 469   AC_HELP_STRING([--disable-iri],[disable IDN/IRIs support]),
 470   [case "${enable_iri}" in
 471     no)
 472       dnl Disable IRIs checking
 473       AC_MSG_NOTICE([disabling IRIs at user request])
 474       iri=no
 475       ;;
 476     yes)
 477       dnl IRIs explicitly enabled
 478       iri=yes
 479       force_iri=yes
 480       ;;
 481     auto)
 482       dnl Auto-detect IRI
 483       iri=yes
 484       ;;
 485     *)
 486       AC_MSG_ERROR([Invalid --enable-iri argument \`$enable_iri'])
 487       ;;
 488     esac
 489   ], [
 490     dnl If nothing is specified, assume auto-detection
 491     iri=yes
 492   ]
 493 )
 494
 495 AC_ARG_WITH(libidn, AC_HELP_STRING([--with-libidn=[DIR]],
 496                                    [Support IDN/IRIs (needs GNU Libidn)]),
 497                                    libidn=$withval, libidn="")
 498 if test "X$iri" != "Xno"; then
 499   AM_ICONV
 500
 501   if test "X$am_cv_func_iconv" != "Xyes"; then
 502     iri=no
 503     if test "X$force_iri" = "Xyes"; then
 504       AC_MSG_ERROR([Libiconv is required for IRIs support])
 505     else
 506       AC_MSG_NOTICE([disabling IRIs because libiconv wasn't found])
 507     fi
 508   fi
 509 fi
 510
 511 if test "X$iri" != "Xno"; then
 512   if test "$libidn" != ""; then
 513     LDFLAGS="${LDFLAGS} -L$libidn/lib"
 514     CPPFLAGS="${CPPFLAGS} -I$libidn/include"
 515   fi
 516   AC_CHECK_HEADER(idna.h,
 517     AC_CHECK_LIB(idn, stringprep_check_version,
 518       [iri=yes LIBS="${LIBS} -lidn"], iri=no),
 519     iri=no)
 520
 521   if test "X$iri" != "Xno" ; then
 522     AC_DEFINE(ENABLE_IRI, 1, [Define if IRI support is enabled.])
 523     AC_MSG_NOTICE([Enabling support for IRI.])
 524   else
 525     AC_MSG_WARN([Libidn not found])
 526   fi
 527 fi
 528
 529
 530 dnl Needed by src/Makefile.am
 531 AM_CONDITIONAL([IRI_IS_ENABLED], [test "X$iri" != "Xno"])
 532
 533
 534 dnl
 535 dnl Create output
 536 dnl
 537 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 538                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 539                  lib/Makefile md5/Makefile windows/Makefile])
 540 AC_CONFIG_HEADERS([src/config.h])
 541 AC_OUTPUT