sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007, 2008, 2009, 2010, 2011, 2012,
   3 dnl 2013, 2014 Free Software Foundation, Inc.
   4
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl Additional permission under GNU GPL version 3 section 7
  19
  20 dnl If you modify this program, or any covered work, by linking or
  21 dnl combining it with the OpenSSL project's OpenSSL library (or a
  22 dnl modified version of that library), containing parts covered by the
  23 dnl terms of the OpenSSL or SSLeay licenses, the Free Software Foundation
  24 dnl grants you additional permission to convey the resulting work.
  25 dnl Corresponding Source for a non-source form of such a combination
  26 dnl shall include the source code for the parts of OpenSSL used as well
  27 dnl as that of the covered work.
  28
  29 dnl
  30 dnl Process this file with autoconf to produce a configure script.
  31 dnl
  32
  33 AC_INIT([wget],
  34         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  35         [bug-wget@gnu.org])
  36 AC_PREREQ(2.61)
  37
  38 dnl
  39 dnl What version of Wget are we building?
  40 dnl
  41 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  42
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_AUX_DIR([build-aux])
  45
  46 AC_CONFIG_SRCDIR([src/wget.h])
  47
  48 dnl
  49 dnl Automake setup
  50 dnl
  51 AM_INIT_AUTOMAKE([1.9])
  52
  53 dnl
  54 dnl Get cannonical host
  55 dnl
  56 AC_CANONICAL_HOST
  57 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  58                    [Define to be the name of the operating system.])
  59
  60 dnl
  61 dnl Process features.
  62 dnl
  63
  64 AC_ARG_WITH(libpsl,
  65     AS_HELP_STRING([--without-libpsl],
  66                    [disable support for libpsl cookie checking.]))
  67
  68 AC_ARG_WITH(ssl,
  69 [[  --without-ssl           disable SSL autodetection
  70   --with-ssl={gnutls,openssl} specify the SSL backend.  GNU TLS is the default.]])
  71
  72 AC_ARG_WITH(zlib,
  73 [[  --without-zlib          disable zlib ]])
  74
  75 AC_ARG_ENABLE(opie,
  76 [  --disable-opie          disable support for opie or s/key FTP login],
  77 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  78 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  79    [Define if you want the Opie support for FTP compiled in.])
  80
  81 AC_ARG_ENABLE(digest,
  82 [  --disable-digest        disable support for HTTP digest authorization],
  83 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  84 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  85    [Define if you want the HTTP Digest Authorization compiled in.])
  86
  87 AC_ARG_ENABLE(ntlm,
  88 [  --disable-ntlm          disable support for NTLM authorization],
  89 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  90
  91 AC_ARG_ENABLE(debug,
  92 [  --disable-debug         disable support for debugging output],
  93 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  94 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  95    [Define if you want the debug output support compiled in.])
  96
  97 dnl
  98 dnl Find the compiler
  99 dnl
 100
 101 dnl We want these before the checks, so the checks can modify their values.
 102 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 103 test -z "$CC" && cc_specified=yes
 104
 105 AC_PROG_CC
 106 AM_PROG_CC_C_O
 107 AC_AIX
 108
 109 gl_EARLY
 110
 111 dnl
 112 dnl Gettext
 113 dnl
 114 AM_GNU_GETTEXT([external],[need-ngettext])
 115 AM_GNU_GETTEXT_VERSION([0.17])
 116
 117 AC_PROG_RANLIB
 118
 119 AC_PROG_LEX
 120
 121 dnl Turn on optimization by default.  Specifically:
 122 dnl
 123 dnl if the user hasn't specified CFLAGS, then
 124 dnl   if compiler is gcc, then
 125 dnl     use -O2 and some warning flags
 126 dnl   else
 127 dnl     use os-specific flags or -O
 128 if test -n "$auto_cflags"; then
 129   if test -n "$GCC"; then
 130     CFLAGS="$CFLAGS -O2 -Wall"
 131   else
 132     case "$host_os" in
 133       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 134       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 135       *)       CFLAGS="$CFLAGS -O" ;;
 136     esac
 137   fi
 138 fi
 139
 140 dnl
 141 dnl Checks for basic compiler characteristics.
 142 dnl
 143 AC_C_CONST
 144 AC_C_INLINE
 145 AC_C_VOLATILE
 146
 147 dnl Check for basic headers, even though we expect them to exist and
 148 dnl #include them unconditionally in the code.  Their detection is
 149 dnl still needed because test programs used by Autoconf macros check
 150 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 151 dnl Without the checks they will fail to be included in test programs,
 152 dnl which will subsequently fail.
 153 AC_HEADER_STDC
 154
 155 dnl Check for large file support.  This check needs to come fairly
 156 dnl early because it could (in principle) affect whether functions and
 157 dnl headers are available, whether they work, etc.
 158 AC_SYS_LARGEFILE
 159 AC_CHECK_SIZEOF(off_t)
 160
 161 dnl
 162 dnl Checks for system header files that might be missing.
 163 dnl
 164 AC_HEADER_STDBOOL
 165 AC_CHECK_HEADERS(unistd.h sys/time.h)
 166 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 167 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h wchar.h)
 168
 169 AC_CHECK_DECLS(h_errno,,,[#include <netdb.h>])
 170
 171 dnl
 172 dnl Check sizes of integer types.  These are used to find n-bit
 173 dnl integral types on older systems that fail to provide intN_t and
 174 dnl uintN_t typedefs.
 175 dnl
 176 AC_CHECK_SIZEOF([short])
 177 AC_CHECK_SIZEOF([int])
 178 AC_CHECK_SIZEOF([long])
 179 AC_CHECK_SIZEOF([long long])
 180 AC_CHECK_SIZEOF([void *])
 181
 182 dnl
 183 dnl Checks for non-universal or system-specific types.
 184 dnl
 185 AC_TYPE_SIZE_T
 186 AC_TYPE_PID_T
 187 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 188 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 189 #include <stdio.h>
 190 #include <sys/types.h>
 191 #if HAVE_INTTYPES_H
 192 # include <inttypes.h>
 193 #endif
 194 #include <signal.h>
 195 ])
 196
 197 # gnulib
 198 gl_INIT
 199
 200 dnl
 201 dnl Checks for library functions.
 202 dnl
 203 AC_FUNC_MMAP
 204 AC_FUNC_FSEEKO
 205 AC_CHECK_FUNCS(strptime timegm vsnprintf vasprintf drand48 pathconf)
 206 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr wcwidth mbtowc)
 207 AC_CHECK_FUNCS(sleep symlink utime)
 208
 209 if test x"$ENABLE_OPIE" = xyes; then
 210   AC_LIBOBJ([ftp-opie])
 211 fi
 212
 213 dnl We expect to have these functions on Unix-like systems configure
 214 dnl runs on.  The defines are provided to get them in config.h.in so
 215 dnl Wget can still be ported to non-Unix systems (such as Windows)
 216 dnl that lack some of these functions.
 217 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 218 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 219 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 220 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 221
 222 dnl
 223 dnl Call Wget-specific macros defined in aclocal.
 224 dnl
 225 WGET_STRUCT_UTIMBUF
 226 WGET_FNMATCH
 227 WGET_NANOSLEEP
 228 WGET_POSIX_CLOCK
 229 WGET_NSL_SOCKET
 230
 231 dnl Deal with specific hosts
 232 case $host_os in
 233   *mingw32* )
 234     LIBS+=' -lws2_32'
 235     AC_LIBOBJ([mswindows])
 236     ;;
 237 esac
 238
 239
 240 dnl
 241 dnl Checks for libraries.
 242 dnl
 243
 244 AS_IF([test x"$with_libpsl" != xno], [
 245   with_libpsl=yes
 246   AC_CHECK_LIB([psl], [psl_builtin])
 247 ])
 248
 249 AS_IF([test x"$with_zlib" != xno], [
 250   with_zlib=yes
 251   AC_CHECK_LIB(z, compress)
 252 ])
 253
 254 AS_IF([test x"$with_ssl" = xopenssl], [
 255   dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 256   dnl doesn't record its dependency on libdl, so we need to make sure
 257   dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 258   dnl dlopen(), but HP-UX uses shl_load().
 259   AC_CHECK_LIB(dl, dlopen, [], [
 260     AC_CHECK_LIB(dl, shl_load)
 261   ])
 262
 263   ssl_found=no
 264   case $host_os in
 265     *mingw32* )
 266       dnl prefer link to openssl dlls if possible. if not then fallback on static libs. if not then error
 267
 268       AC_CHECK_LIB(eay32, EVP_MD_CTX_init)
 269       if test x"$ac_cv_lib_eay32_EVP_MD_CTX_init" != xno
 270       then
 271         AC_CHECK_LIB(ssl32, SSL_connect, [
 272           ssl_found=yes
 273           AC_MSG_NOTICE([Enabling support for SSL via OpenSSL (shared)])
 274           AC_LIBOBJ([openssl])
 275           LIBS="${LIBS} -lssl32"
 276           AC_DEFINE([HAVE_LIBSSL32], [1], [Define to 1 if you have the `ssl32' library (-lssl32).])
 277         ],
 278         AC_MSG_ERROR([openssl not found: shared lib eay32 found but ssl32 not found]))
 279
 280       else
 281         LIBS+=' -lgdi32'
 282         dnl fallback and test static libs
 283       fi
 284       dnl add zdll lib as dep for above tests?
 285     ;;
 286   esac
 287
 288   AS_IF([test x$ssl_found != xyes], [
 289     dnl Now actually check for -lssl if it wasn't already found
 290     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 291 #include <openssl/ssl.h>
 292 #include <openssl/x509.h>
 293 #include <openssl/err.h>
 294 #include <openssl/rand.h>
 295 #include <openssl/des.h>
 296 #include <openssl/md4.h>
 297 #include <openssl/md5.h>
 298     ], [SSL_library_init ()])
 299     if test x"$LIBSSL" != x
 300     then
 301       ssl_found=yes
 302       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 303       AC_LIBOBJ([openssl])
 304       LIBS="$LIBSSL $LIBS"
 305     elif test x"$with_ssl" != x
 306     then
 307       AC_MSG_ERROR([--with-ssl=openssl was given, but SSL is not available.])
 308     fi
 309   ])
 310
 311 ], [
 312   # --with-ssl is not openssl: check if it's no
 313   AS_IF([test x"$with_ssl" != xno], [
 314     dnl default is -lgnutls
 315     with_ssl=gnutls
 316
 317     dnl Now actually check for -lgnutls
 318     AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 319 #include <gnutls/gnutls.h>
 320     ], [gnutls_global_init()])
 321     if test x"$LIBGNUTLS" != x
 322     then
 323       ssl_found=yes
 324       AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 325       AC_LIBOBJ([gnutls])
 326       LIBS="$LIBGNUTLS $LIBS"
 327     else
 328       AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 329     fi
 330
 331     AC_CHECK_FUNCS(gnutls_priority_set_direct)
 332   ]) # endif: --with-ssl != no?
 333 ]) # endif: --with-ssl == openssl?
 334
 335 dnl Enable NTLM if requested and if SSL is available.
 336 if test x"$LIBSSL" != x || test "$ac_cv_lib_ssl32_SSL_connect" = yes
 337 then
 338   if test x"$ENABLE_NTLM" != xno
 339   then
 340     ENABLE_NTLM=yes
 341     AC_DEFINE([ENABLE_NTLM], 1,
 342      [Define if you want the NTLM authorization support compiled in.])
 343     AC_LIBOBJ([http-ntlm])
 344   fi
 345 else
 346   AC_CHECK_LIB(nettle, nettle_md4_init, [HAVE_NETTLE=yes], [HAVE_NETTLE=no; AC_MSG_WARN(*** libnettle was not found. You will not be able to use NTLM)])
 347
 348   if test x"$HAVE_NETTLE" = xyes
 349   then
 350     AC_SUBST(NETTLE_LIBS, "-lnettle")
 351     AC_DEFINE([HAVE_NETTLE], [1], [Use libnettle])
 352     if test x"$ENABLE_NTLM" != xno
 353     then
 354       ENABLE_NTLM=yes
 355       AC_DEFINE([ENABLE_NTLM], 1,
 356        [Define if you want the NTLM authorization support compiled in.])
 357       AC_LIBOBJ([http-ntlm])
 358       LIBS="$NETTLE_LIBS $LIBS"
 359     fi
 360   else
 361     dnl If SSL is unavailable and the user explicitly requested NTLM,
 362     dnl abort.
 363     if test x"$ENABLE_NTLM" = xyes
 364     then
 365       AC_MSG_ERROR([NTLM authorization requested and SSL not enabled; aborting])
 366     fi
 367   fi
 368 fi
 369
 370
 371 dnl **********************************************************************
 372 dnl Checks for IPv6
 373 dnl **********************************************************************
 374
 375 dnl
 376 dnl We test for IPv6 by checking, in turn, for availability of
 377 dnl presence of the INET6 address/protocol family and the existence of
 378 dnl struct sockaddr_in6.  If any of them is missing, IPv6 is disabled,
 379 dnl and the code reverts to old-style gethostbyname.
 380 dnl
 381 dnl If --enable-ipv6 is explicitly specified on the configure command
 382 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 383 dnl is specified, we disable IPv6 and don't check for it.  The default
 384 dnl is to autodetect IPv6 and use it where available.
 385 dnl
 386
 387 AC_ARG_ENABLE(ipv6,
 388   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 389   [case "${enable_ipv6}" in
 390     no)
 391       AC_MSG_NOTICE([disabling IPv6 at user request])
 392       dnl Disable IPv6 checking
 393       ipv6=no
 394       ;;
 395     yes)
 396       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 397       ipv6=yes
 398       force_ipv6=yes
 399       ;;
 400     auto)
 401       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 402       ipv6=yes
 403       ;;
 404     *)
 405       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 406       ;;
 407     esac
 408   ], [
 409     dnl If nothing is specified, assume auto-detection.
 410     ipv6=yes
 411   ]
 412 )
 413
 414 if test "X$ipv6" = "Xyes"; then
 415   PROTO_INET6([], [
 416     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 417     ipv6=no
 418   ])
 419 fi
 420
 421 if test "X$ipv6" = "Xyes"; then
 422   TYPE_STRUCT_SOCKADDR_IN6([],[
 423     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 424     ipv6=no
 425   ])
 426   if test "X$ipv6" = "Xyes"; then
 427     WGET_STRUCT_SOCKADDR_STORAGE
 428     MEMBER_SIN6_SCOPE_ID
 429   fi
 430 fi
 431
 432 if test "X$ipv6" = "Xyes"; then
 433   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 434   AC_MSG_NOTICE([Enabling support for IPv6.])
 435 elif test "x$force_ipv6" = "xyes"; then
 436   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 437 fi
 438
 439 dnl
 440 dnl Find makeinfo.  We used to provide support for Emacs processing
 441 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 442 dnl unavailable, but that broke with the addition of makeinfo-specific
 443 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 444 dnl build the Info documentation.
 445 dnl
 446
 447 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 448
 449 dnl
 450 dnl Find perl and pod2man
 451 dnl
 452
 453 AC_PATH_PROGS(PERL, [perl5 perl], no)
 454 AC_PATH_PROG(POD2MAN, pod2man, no)
 455
 456 if test "x${POD2MAN}" = xno; then
 457   COMMENT_IF_NO_POD2MAN="# "
 458 else
 459   COMMENT_IF_NO_POD2MAN=
 460 fi
 461 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 462
 463
 464 dnl
 465 dnl Check for IDN/IRIs
 466 dnl
 467
 468 AC_ARG_ENABLE(iri,
 469   AC_HELP_STRING([--disable-iri],[disable IDN/IRIs support]),
 470   [case "${enable_iri}" in
 471     no)
 472       dnl Disable IRIs checking
 473       AC_MSG_NOTICE([disabling IRIs at user request])
 474       iri=no
 475       ;;
 476     yes)
 477       dnl IRIs explicitly enabled
 478       iri=yes
 479       force_iri=yes
 480       ;;
 481     auto)
 482       dnl Auto-detect IRI
 483       iri=yes
 484       ;;
 485     *)
 486       AC_MSG_ERROR([Invalid --enable-iri argument \`$enable_iri'])
 487       ;;
 488     esac
 489   ], [
 490     dnl If nothing is specified, assume auto-detection
 491     iri=yes
 492   ]
 493 )
 494
 495 AC_ARG_WITH(libidn, AC_HELP_STRING([--with-libidn=[DIR]],
 496                                    [Support IDN/IRIs (needs GNU Libidn)]),
 497                                    libidn=$withval, libidn="")
 498 AS_IF([test "X$iri" != "Xno"],[
 499   AM_ICONV
 500
 501   if test "X$am_cv_func_iconv" != "Xyes"; then
 502     iri=no
 503     if test "X$force_iri" = "Xyes"; then
 504       AC_MSG_ERROR([Libiconv is required for IRIs support])
 505     else
 506       AC_MSG_NOTICE([disabling IRIs because libiconv wasn't found])
 507     fi
 508   fi
 509 ],[  # else
 510   # For some reason, this seems to be set even when we don't check.
 511   # Explicitly unset.
 512   LIBICONV=
 513 ])
 514
 515 if test "X$iri" != "Xno"; then
 516   if test "$libidn" != ""; then
 517     LDFLAGS="${LDFLAGS} -L$libidn/lib"
 518     CPPFLAGS="${CPPFLAGS} -I$libidn/include"
 519   fi
 520
 521   # If idna.h can't be found, check to see if it was installed under
 522   # /usr/include/idn (OpenSolaris, at least, places it there).
 523   # Check for idn-int.h in that case, because idna.h won't find
 524   # idn-int.h until we've decided to add -I/usr/include/idn.
 525   AC_CHECK_HEADER(idna.h, ,
 526     [AC_CHECK_HEADER(idn/idn-int.h,
 527                     [CPPFLAGS="${CPPFLAGS} -I/usr/include/idn"],
 528                     [iri=no])]
 529   )
 530
 531   if test "X$iri" != "Xno"; then
 532     AC_CHECK_LIB(idn, stringprep_check_version,
 533       [iri=yes LIBS="${LIBS} -lidn"], iri=no)
 534   fi
 535
 536   if test "X$iri" != "Xno" ; then
 537     AC_DEFINE([ENABLE_IRI], 1, [Define if IRI support is enabled.])
 538     AC_MSG_NOTICE([Enabling support for IRI.])
 539   else
 540     AC_MSG_WARN([Libidn not found])
 541   fi
 542 fi
 543
 544 dnl
 545 dnl Check for UUID
 546 dnl
 547
 548 AC_CHECK_HEADER(uuid/uuid.h,
 549                 AC_CHECK_LIB(uuid, uuid_generate,
 550                   [LIBS="${LIBS} -luuid"
 551                    AC_DEFINE([HAVE_LIBUUID], 1,
 552                              [Define if libuuid is available.])
 553                   ])
 554 )
 555
 556 dnl
 557 dnl Check for PCRE
 558 dnl
 559
 560 AC_CHECK_HEADER(pcre.h,
 561                 AC_CHECK_LIB(pcre, pcre_compile,
 562                   [LIBS="${LIBS} -lpcre"
 563                    AC_DEFINE([HAVE_LIBPCRE], 1,
 564                              [Define if libpcre is available.])
 565                   ])
 566 )
 567
 568
 569 dnl Needed by src/Makefile.am
 570 AM_CONDITIONAL([IRI_IS_ENABLED], [test "X$iri" != "Xno"])
 571
 572
 573 dnl
 574 dnl Create output
 575 dnl
 576 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 577                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 578                  lib/Makefile])
 579 AC_CONFIG_HEADERS([src/config.h])
 580 AC_OUTPUT
 581
 582 AC_MSG_NOTICE([Summary of build options:
 583
 584   Version:           $PACKAGE_VERSION
 585   Host OS:           $host_os
 586   Install prefix:    $prefix
 587   Compiler:          $CC
 588   CFlags:            $CFLAGS $CPPFLAGS
 589   LDFlags:           $LDFLAGS
 590   Libs:              $LIBS
 591   SSL:               $with_ssl
 592   Zlib:              $with_zlib
 593   PSL:               $with_libpsl
 594   Digest:            $ENABLE_DIGEST
 595   NTLM:              $ENABLE_NTLM
 596   OPIE:              $ENABLE_OPIE
 597   Debugging:         $ENABLE_DEBUG
 598 ])