sjero.net Git - wget/blob - configure.ac

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007,
   3 dnl 2008 Free Software Foundation, Inc.
   4
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl Additional permission under GNU GPL version 3 section 7
  19
  20 dnl If you modify this program, or any covered work, by linking or
  21 dnl combining it with the OpenSSL project's OpenSSL library (or a
  22 dnl modified version of that library), containing parts covered by the
  23 dnl terms of the OpenSSL or SSLeay licenses, the Free Software Foundation
  24 dnl grants you additional permission to convey the resulting work.
  25 dnl Corresponding Source for a non-source form of such a combination
  26 dnl shall include the source code for the parts of OpenSSL used as well
  27 dnl as that of the covered work.
  28
  29 dnl
  30 dnl Process this file with autoconf to produce a configure script.
  31 dnl
  32
  33 AC_INIT([wget],
  34         [1.12-devel],
  35         [bug-wget@gnu.org])
  36 AC_PREREQ(2.61)
  37
  38 dnl
  39 dnl What version of Wget are we building?
  40 dnl
  41 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  42
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_AUX_DIR([.])
  45
  46 dnl
  47 dnl Automake setup
  48 dnl
  49 AM_INIT_AUTOMAKE(1.9)
  50
  51 dnl
  52 dnl Gettext
  53 dnl
  54 AM_GNU_GETTEXT([external],[need-ngettext])
  55 AM_GNU_GETTEXT_VERSION([0.16.1])
  56
  57 dnl
  58 dnl Get cannonical host
  59 dnl
  60 AC_CANONICAL_HOST
  61 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  62                    [Define to be the name of the operating system.])
  63
  64 dnl
  65 dnl Process features.
  66 dnl
  67
  68 AC_ARG_WITH(ssl,
  69 [[  --without-ssl           disable SSL autodetection]])
  70
  71 AC_ARG_ENABLE(opie,
  72 [  --disable-opie          disable support for opie or s/key FTP login],
  73 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  74 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  75    [Define if you want the Opie support for FTP compiled in.])
  76
  77 AC_ARG_ENABLE(digest,
  78 [  --disable-digest        disable support for HTTP digest authorization],
  79 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  80 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  81    [Define if you want the HTTP Digest Authorization compiled in.])
  82
  83 AC_ARG_ENABLE(ntlm,
  84 [  --disable-ntlm          disable support for NTLM authorization],
  85 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  86
  87 AC_ARG_ENABLE(debug,
  88 [  --disable-debug         disable support for debugging output],
  89 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  90 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  91    [Define if you want the debug output support compiled in.])
  92
  93 wget_need_md5=no
  94
  95 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  96 *yes*)
  97         wget_need_md5=yes
  98 esac
  99
 100 dnl
 101 dnl Find the compiler
 102 dnl
 103
 104 dnl We want these before the checks, so the checks can modify their values.
 105 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 106 test -z "$CC" && cc_specified=yes
 107
 108 AC_PROG_CC
 109 AM_PROG_CC_C_O
 110 AC_AIX
 111 gl_EARLY
 112 md5_EARLY
 113
 114 AC_PROG_RANLIB
 115
 116 AC_PROG_LEX
 117
 118 dnl Turn on optimization by default.  Specifically:
 119 dnl
 120 dnl if the user hasn't specified CFLAGS, then
 121 dnl   if compiler is gcc, then
 122 dnl     use -O2 and some warning flags
 123 dnl   else
 124 dnl     use os-specific flags or -O
 125 if test -n "$auto_cflags"; then
 126   if test -n "$GCC"; then
 127     CFLAGS="$CFLAGS -O2 -Wall"
 128   else
 129     case "$host_os" in
 130       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 131       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 132       *)       CFLAGS="$CFLAGS -O" ;;
 133     esac
 134   fi
 135 fi
 136
 137 dnl
 138 dnl Checks for basic compiler characteristics.
 139 dnl
 140 AC_C_CONST
 141 AC_C_INLINE
 142 AC_C_VOLATILE
 143
 144 dnl Check for basic headers, even though we expect them to exist and
 145 dnl #include them unconditionally in the code.  Their detection is
 146 dnl still needed because test programs used by Autoconf macros check
 147 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 148 dnl Without the checks they will fail to be included in test programs,
 149 dnl which will subsequently fail.
 150 AC_HEADER_STDC
 151
 152 dnl Check for large file support.  This check needs to come fairly
 153 dnl early because it could (in principle) affect whether functions and
 154 dnl headers are available, whether they work, etc.
 155 AC_SYS_LARGEFILE
 156 AC_CHECK_SIZEOF(off_t)
 157
 158 dnl
 159 dnl Checks for system header files that might be missing.
 160 dnl
 161 AC_HEADER_STDBOOL
 162 AC_CHECK_HEADERS(unistd.h sys/time.h)
 163 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 164 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h wchar.h)
 165
 166 AC_CHECK_DECLS(h_errno,,,[#include <netdb.h>])
 167
 168 dnl
 169 dnl Check sizes of integer types.  These are used to find n-bit
 170 dnl integral types on older systems that fail to provide intN_t and
 171 dnl uintN_t typedefs.
 172 dnl
 173 AC_CHECK_SIZEOF(short)
 174 AC_CHECK_SIZEOF(int)
 175 AC_CHECK_SIZEOF(long)
 176 AC_CHECK_SIZEOF(long long)
 177 AC_CHECK_SIZEOF(void *)
 178
 179 dnl
 180 dnl Checks for non-universal or system-specific types.
 181 dnl
 182 AC_TYPE_SIZE_T
 183 AC_TYPE_PID_T
 184 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 185 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 186 #include <stdio.h>
 187 #include <sys/types.h>
 188 #if HAVE_INTTYPES_H
 189 # include <inttypes.h>
 190 #endif
 191 #include <signal.h>
 192 ])
 193
 194 # gnulib
 195 gl_INIT
 196
 197 dnl
 198 dnl Checks for library functions.
 199 dnl
 200 AC_FUNC_MMAP
 201 AC_FUNC_FSEEKO
 202 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 203 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr wcwidth mbtowc)
 204
 205 if test x"$ENABLE_OPIE" = xyes; then
 206   AC_LIBOBJ([ftp-opie])
 207 fi
 208
 209 dnl We expect to have these functions on Unix-like systems configure
 210 dnl runs on.  The defines are provided to get them in config.h.in so
 211 dnl Wget can still be ported to non-Unix systems (such as Windows)
 212 dnl that lack some of these functions.
 213 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 214 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 215 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 216 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 217 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 218
 219 dnl
 220 dnl Call Wget-specific macros defined in aclocal.
 221 dnl
 222 WGET_STRUCT_UTIMBUF
 223 WGET_SOCKLEN_T
 224 WGET_FNMATCH
 225 WGET_NANOSLEEP
 226 WGET_POSIX_CLOCK
 227 WGET_NSL_SOCKET
 228
 229 dnl
 230 dnl Checks for libraries.
 231 dnl
 232
 233 AS_IF([test x"$with_ssl" = xgnutls], [
 234   dnl Now actually check for -lssl
 235   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 236 #include <gnutls/gnutls.h>
 237   ], [gnutls_global_init()])
 238   if test x"$LIBGNUTLS" != x
 239   then
 240     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 241     AC_LIBOBJ([gnutls])
 242   else
 243     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 244   fi
 245 ], [
 246   # --with-ssl is not gnutls: check if it's no
 247   AS_IF([test x"$with_ssl" != xno], [
 248     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 249     dnl doesn't record its dependency on libdl, so we need to make sure
 250     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 251     dnl dlopen(), but HP-UX uses shl_load().
 252     AC_CHECK_LIB(dl, dlopen, [], [
 253       AC_CHECK_LIB(dl, shl_load)
 254     ])
 255
 256     dnl Now actually check for -lssl
 257     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 258   #include <openssl/ssl.h>
 259   #include <openssl/x509.h>
 260   #include <openssl/err.h>
 261   #include <openssl/rand.h>
 262   #include <openssl/des.h>
 263   #include <openssl/md4.h>
 264   #include <openssl/md5.h>
 265     ], [SSL_library_init ()])
 266     if test x"$LIBSSL" != x
 267     then
 268       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 269       AC_LIBOBJ([openssl])
 270     elif test x"$with_ssl" != x
 271     then
 272       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 273     fi
 274   ]) # endif: --with-ssl == no?
 275 ]) # endif: --with-ssl == gnutls?
 276
 277
 278 dnl Enable NTLM if requested and if SSL is available.
 279 if test x"$LIBSSL" != x
 280 then
 281   if test x"$ENABLE_NTLM" != xno
 282   then
 283     AC_DEFINE([ENABLE_NTLM], 1,
 284      [Define if you want the NTLM authorization support compiled in.])
 285     AC_LIBOBJ([http-ntlm])
 286   fi
 287 else
 288   dnl If SSL is unavailable and the user explicitly requested NTLM,
 289   dnl abort.
 290   if test x"$ENABLE_NTLM" = xyes
 291   then
 292     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 293   fi
 294 fi
 295
 296 dnl
 297 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 298 dnl to use an existing library implementation to save on code size.
 299 dnl
 300
 301 if test x"$wget_need_md5" = xyes
 302 then
 303   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 304   dnl manipulate MD5_OBJ from the defun.
 305
 306   AC_LIBOBJ([gen-md5])
 307   found_md5=no
 308
 309   dnl Check for the system MD5 library on Solaris.  We don't check for
 310   dnl something simple like "MD5Update" because there are a number of
 311   dnl MD5 implementations that use that name, but have an otherwise
 312   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 313   dnl Solaris MD5 library.
 314   if test x"$found_md5" = xno; then
 315     AC_CHECK_LIB(md5, md5_calc, [
 316       dnl Some installations have bogus <md5.h> in the compiler's
 317       dnl include path, making the system md5 library useless.
 318       AC_MSG_CHECKING([for working md5.h])
 319       AC_COMPILE_IFELSE([#include <md5.h>
 320                         ], [
 321         AC_MSG_RESULT(yes)
 322         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 323         LIBS="-lmd5 $LIBS"
 324         found_md5=yes
 325         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 326       ], [AC_MSG_RESULT(no)])
 327     ])
 328   fi
 329
 330   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 331   dnl implementation.
 332   if test x"$found_md5" = xno; then
 333     if test x"$LIBSSL" != x; then
 334       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 335       found_md5=yes
 336       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 337     fi
 338   fi
 339
 340   dnl If none of the above worked, use the one we ship with Wget.
 341   if test x"$found_md5" = xno; then
 342     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 343     found_md5=yes
 344     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 345     AC_C_BIGENDIAN
 346
 347     AC_SUBST(MD5_CPPFLAGS, '-I $(top_srcdir)/md5')
 348     AC_SUBST(MD5_LDADD, '../md5/libmd5.a')
 349     AC_SUBST(MD5_SUBDIR, md5)
 350     md5_INIT
 351   fi
 352   AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 353 fi
 354
 355 dnl **********************************************************************
 356 dnl Checks for IPv6
 357 dnl **********************************************************************
 358
 359 dnl
 360 dnl We test for IPv6 by checking, in turn, for availability of
 361 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 362 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 363 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 364 dnl
 365 dnl If --enable-ipv6 is explicitly specified on the configure command
 366 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 367 dnl is specified, we disable IPv6 and don't check for it.  The default
 368 dnl is to autodetect IPv6 and use it where available.
 369 dnl
 370
 371 AC_ARG_ENABLE(ipv6,
 372   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 373   [case "${enable_ipv6}" in
 374     no)
 375       AC_MSG_NOTICE([disabling IPv6 at user request])
 376       dnl Disable IPv6 checking
 377       ipv6=no
 378       ;;
 379     yes)
 380       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 381       ipv6=yes
 382       force_ipv6=yes
 383       ;;
 384     auto)
 385       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 386       ipv6=yes
 387       ;;
 388     *)
 389       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 390       ;;
 391     esac
 392   ], [
 393     dnl If nothing is specified, assume auto-detection.
 394     ipv6=yes
 395   ]
 396 )
 397
 398 if test "X$ipv6" = "Xyes"; then
 399   AC_CHECK_FUNCS(getaddrinfo, [], [
 400     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 401     ipv6=no
 402   ])
 403 fi
 404
 405 if test "X$ipv6" = "Xyes"; then
 406   PROTO_INET6([], [
 407     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 408     ipv6=no
 409   ])
 410 fi
 411
 412 if test "X$ipv6" = "Xyes"; then
 413   TYPE_STRUCT_SOCKADDR_IN6([],[
 414     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 415     ipv6=no
 416   ])
 417   if test "X$ipv6" = "Xyes"; then
 418     WGET_STRUCT_SOCKADDR_STORAGE
 419     MEMBER_SIN6_SCOPE_ID
 420   fi
 421 fi
 422
 423 if test "X$ipv6" = "Xyes"; then
 424   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 425   AC_MSG_NOTICE([Enabling support for IPv6.])
 426 elif test "x$force_ipv6" = "xyes"; then
 427   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 428 fi
 429
 430
 431 dnl
 432 dnl Set of available languages.
 433 dnl
 434 dnl Originally this used to be static, looking like this:
 435 dnl     ALL_LINGUAS="cs de hr it ..."
 436 dnl The downside was that configure needed to be rebuilt whenever a
 437 dnl new language was added.
 438 dnl
 439 ALL_LINGUAS="en@quot en@boldquot en_US $(cd ${srcdir}/po && ls *.po | grep -v 'en@.*quot' | grep -v 'en_US\.po' | sed -e 's/\.po$//' | tr '\012' ' ')"
 440
 441 dnl
 442 dnl Find makeinfo.  We used to provide support for Emacs processing
 443 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 444 dnl unavailable, but that broke with the addition of makeinfo-specific
 445 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 446 dnl build the Info documentation.
 447 dnl
 448
 449 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 450
 451 dnl
 452 dnl Find perl and pod2man
 453 dnl
 454
 455 AC_PATH_PROGS(PERL, [perl5 perl], no)
 456 AC_PATH_PROG(POD2MAN, pod2man, no)
 457
 458 if test "x${POD2MAN}" = xno; then
 459   COMMENT_IF_NO_POD2MAN="# "
 460 else
 461   COMMENT_IF_NO_POD2MAN=
 462 fi
 463 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 464
 465
 466 dnl
 467 dnl Check for IDN/IRIs
 468 dnl
 469
 470 AC_ARG_ENABLE(iri,
 471   AC_HELP_STRING([--disable-iri],[disable IDN/IRIs support]),
 472   [case "${enable_iri}" in
 473     no)
 474       dnl Disable IRIs checking
 475       AC_MSG_NOTICE([disabling IRIs at user request])
 476       iri=no
 477       ;;
 478     yes)
 479       dnl IRIs explicitly enabled
 480       iri=yes
 481       force_iri=yes
 482       ;;
 483     auto)
 484       dnl Auto-detect IRI
 485       iri=yes
 486       ;;
 487     *)
 488       AC_MSG_ERROR([Invalid --enable-iri argument \`$enable_iri'])
 489       ;;
 490     esac
 491   ], [
 492     dnl If nothing is specified, assume auto-detection
 493     iri=yes
 494   ]
 495 )
 496
 497 AC_ARG_WITH(libidn, AC_HELP_STRING([--with-libidn=[DIR]],
 498                                    [Support IDN/IRIs (needs GNU Libidn)]),
 499                                    libidn=$withval, libidn="")
 500 AS_IF([test "X$iri" != "Xno"],[
 501   AM_ICONV
 502
 503   if test "X$am_cv_func_iconv" != "Xyes"; then
 504     iri=no
 505     if test "X$force_iri" = "Xyes"; then
 506       AC_MSG_ERROR([Libiconv is required for IRIs support])
 507     else
 508       AC_MSG_NOTICE([disabling IRIs because libiconv wasn't found])
 509     fi
 510   fi
 511 ],[  # else
 512   # For some reason, this seems to be set even when we don't check.
 513   # Explicitly unset.
 514   LIBICONV=
 515 ])
 516
 517 if test "X$iri" != "Xno"; then
 518   if test "$libidn" != ""; then
 519     LDFLAGS="${LDFLAGS} -L$libidn/lib"
 520     CPPFLAGS="${CPPFLAGS} -I$libidn/include"
 521   fi
 522   AC_CHECK_HEADER(idna.h,
 523     AC_CHECK_LIB(idn, stringprep_check_version,
 524       [iri=yes LIBS="${LIBS} -lidn"], iri=no),
 525     iri=no)
 526
 527   if test "X$iri" != "Xno" ; then
 528     AC_DEFINE(ENABLE_IRI, 1, [Define if IRI support is enabled.])
 529     AC_MSG_NOTICE([Enabling support for IRI.])
 530   else
 531     AC_MSG_WARN([Libidn not found])
 532   fi
 533 fi
 534
 535
 536 dnl Needed by src/Makefile.am
 537 AM_CONDITIONAL([IRI_IS_ENABLED], [test "X$iri" != "Xno"])
 538
 539
 540 dnl
 541 dnl Create output
 542 dnl
 543 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 544                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 545                  lib/Makefile md5/Makefile windows/Makefile])
 546 AC_CONFIG_HEADERS([src/config.h])
 547 AC_OUTPUT